Mouse  - AS3

El nombre de cursor nativo.

Indica si el equipo o el dispositivo muestra un cursor persistente.

La propiedad supportsCursor es true en la mayoría de equipos de sobremesa y false en la mayoría de dispositivos móviles.

Nota: los eventos Mouse se pueden distribuir sea o no esta propiedad true. Sin embargo, los eventos de ratón se comportan de distinta manera en función de las características físicas del dispositivo de señalización.

Elementos de API relacionados

import flash.events.*;
import flash.display.*;
import flash.ui.Mouse;
import flash.text.TextField;

var supportsCursorTxt:TextField = new TextField();
supportsCursorTxt.width = 200;
supportsCursorTxt.border = true;
addChild(supportsCursorTxt);

addEventListener (MouseEvent.CLICK, getScreenKeyboardType);

function getScreenKeyboardType(e:MouseEvent):void{
    supportsCursorTxt.text= "Supports Cursor is : " + String(flash.ui.Mouse.supportsCursor);

}

if(Mouse.supportsCursor) {
    //Game acts as before
} else {
    if(Capabilities.touchscreenType == TouchscreenType.STYLUS ){
        //The Game has to change so that the character is chasing the location of the stylus as 
        //it's dragged around. Some of the animations will have to change
    }else if(Capabilities.touchscreenType = TouchscreenType.FINGER){
        //Same as above, except that the hit-area is larger for a finger.
    }else{
        //There's no pointing device at all. The developer designs some sort of custom cursor to 
        //be controlled with key presses or similar input
    }
}

Indica si la configuración actual admite cursores nativos.

Oculta el puntero. El puntero está visible de manera predeterminada.

Nota:sólo es necesario llamar a Mouse.hide() una vez, independientemente del número de llamadas previas realizadas a Mouse.show().

Elementos de API relacionados

Registra un cursor nativo con un nombre dado y unos datos determinados.

Parámetros

Muestra el puntero. El puntero está visible de manera predeterminada.

Nota: sólo es necesario llamar a Mouse.show() una vez, independientemente del número de llamadas previas realizadas a Mouse.hide().

Elementos de API relacionados

Anula el registro del cursor nativo con el nombre dado.

Parámetros

1. Declare las propiedades de instancia siguientes: cursor de tipo CustomCursor, child de tipo CustomButton y gutter de tipo uint.
2. Asigne child a una nueva instancia de CustomButton, defina sus coordenadas x e y en 10 píxeles cada una y, a continuación, añada la instancia a la lista de visualización. La clase CustomButton sustituye a las propiedades downState, upState, overState y hitTestState de SimpleButton. Cada una de estas propiedades crea una instancia de un objeto ButtonDisplayState, que dibuja un cuadrado diferente en función del estado de la instancia child.
3. La instancia child se utiliza para añadir un detector de eventos MOUSE_OVER y el método detector mouseOverHandler(), junto a un detector de eventos MOUSE_OUT y el método mouseOutHandler() asociado.
4. Los detectores de eventos funcionan del modo siguiente:
   • mouseOverHandler: oculta el puntero "normal" y añade un detector MOUSE_MOVE, que procesa los movimientos del ratón a través del controlador mouseMoveHandler() descrito a continuación.
   • mouseOutHandler: cuando el ratón se desplaza fuera del botón personalizado, se muestra el puntero "normal", se elimina el detector de eventos MOUSE_MOVE y la visibilidad del cursor personalizado se define como false.
   • mouseMoveHandler: desplaza el cursor personalizado donde va el puntero y define la visibilidad del cursor personalizado en true.
5. De nuevo en el constructor MouseExample, la propiedad del cursor se asigna a un nuevo objeto CustomCursor y luego se añade a la lista de visualización a través del elemento addChild(). La clase CustomCursor dibuja un pequeño cuadrado casi negro en lugar del puntero "normal" siempre que el ratón está sobre child.
6. Se añade un cuarto detector de eventos de tipo MOUSE_LEAVE, con el método mouseLeaveHandler() asociado. En este método (al que se llama si el ratón deja el escenario), se pasa al objeto mouseOutHandler() un nuevo objeto detector mouseMove que, básicamente, elimina el puntero para que no quede en el escenario.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.ui.Mouse;
    import flash.events.*;

    public class MouseExample extends Sprite {
         private var cursor:CustomCursor;
         private var child:CustomButton;
         private var gutter:uint = 10;

        public function MouseExample() {
            child = new CustomButton();
            child.x = gutter;
            child.y = gutter;
            addChild(child);

            child.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            child.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);

            cursor = new CustomCursor();
            addChild(cursor);

            stage.addEventListener(Event.MOUSE_LEAVE, mouseLeaveHandler);
        }

        private function mouseOverHandler(event:MouseEvent):void {
            trace("mouseOverHandler");
            Mouse.hide();
            child.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseOutHandler(event:MouseEvent):void {
            trace("mouseOutHandler");
            Mouse.show();
            child.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            cursor.visible = false;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            cursor.x = event.localX;
            cursor.y = event.localY;
            event.updateAfterEvent();
            cursor.visible = true;
        }

        private function mouseLeaveHandler(event:Event):void {
            trace("mouseLeaveHandler");
            mouseOutHandler(new MouseEvent(MouseEvent.MOUSE_MOVE));
        }
    }
}

import flash.display.Shape;
import flash.display.SimpleButton;
    
class CustomButton extends SimpleButton {
    var upColor:uint = 0xFFCC00;
    var overColor:uint = 0xCCFF00;
    var downColor:uint = 0x00CCFF;
    var size:uint = 80;
    
    public function CustomButton() {
        downState = new ButtonDisplayState(downColor, size+10);
        overState = new ButtonDisplayState(overColor, size);
        upState = new ButtonDisplayState(upColor, size);
        hitTestState = new ButtonDisplayState(upColor, size);
    }
}

class ButtonDisplayState extends Shape {
    var bgColor:uint;
    var size:uint;
    
    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size = size;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}
    
class CustomCursor extends Shape {
    var bgColor:uint = 0x333333;
    var size:uint = 10;
    
    public function CustomCursor() {
        visible = false;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}