DataGridEvent  - AS3 Flash

Obtiene o define el nombre del campo o propiedad de los datos asociados a la columna.

Obtiene el procesador de elementos para el elemento que se está editando o procesador de encabezados que se está cambiando de tamaño o en el que se está haciendo clic.

Obtiene el motivo por el que se distribuyó el evento itemEditEnd. Esta propiedad sólo es válida para eventos del tipo DataGridEvent.ITEM_EDIT_END.

Los valores posibles se definen en la clase DataGridEventReason.

Elementos de API relacionados

Crea un nuevo objeto DataGridEvent con los parámetros especificados.

Elementos de API relacionados

Crea una copia del objeto DataGridEvent y define el valor de cada propiedad para que coincida con el original.

Devuelve una cadena con todas las propiedades del objeto DataGridEvent. La cadena tiene el siguiente formato:

[DataGridEvent type=value bubbles=value cancelable=value columnIndex=value rowIndex=value itemRenderer=value dataField=value reason=value]

La constante DataGridEvent.COLUMN_STRETCH define el valor de la propiedad type para un objeto de evento columnStretch.

Este evento tiene las propiedades siguientes:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

La constante DataGridEvent.HEADER_RELEASE define el valor de la propiedad type para un objeto de evento headerRelease.

Este evento tiene las propiedades siguientes:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

La constante DataGridEvent.ITEM_EDIT_BEGIN define el valor de la propiedad type para un objeto de evento itemEditBegin.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

La constante DataGridEvent.ITEM__EDIT_BEGINNING define el valor de la propiedad type para un objeto de evento itemEditBeginning.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

La constante DataGridEvent.ITEM_EDIT_END define el valor de la propiedad type para un objeto de evento itemEditEnd.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

La constante DataGridEvent.ITEM_FOCUS_IN define el valor de la propiedad type para un objeto de evento itemFocusIn.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

La constante DataGridEvent.ITEM_FOCUS_OUT define el valor de la propiedad type para un objeto de evento itemFocusOut.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Para realizar el ejemplo, siga estos pasos:

1. Añada el componente DataGrid a la biblioteca.
2. Guarde este código como DataGridEventExample.as en el mismo directorio que el archivo FLA.
3. Defina la clase Document como DataGridEventExample en el archivo FLA.

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}