ContextMenuItem  - AS3

Paket	flash.ui
Klasse	public final class ContextMenuItem
Vererbung	ContextMenuItem NativeMenuItem EventDispatcher Object

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0, Flash Player 9

Die ContextMenuItem-Klasse stellt ein Element im Kontextmenü dar. Jedes ContextMenuItem-Objekt verfügt über einen Anzeigetext, der im Kontextmenü angezeigt wird. Wenn Sie einem Kontextmenü ein neues Element hinzufügen möchten, fügen Sie es dem customItems-Array eines ContextMenu-Objekts hinzu.

In den Eigenschaften der ContextMenuItem-Klasse können Sie bestimmte Menüeinträge aktivieren oder deaktivieren sowie einblenden oder ausblenden.

Um einem Menüeintrag bei Auswahl durch den Benutzer zusätzliche Funktionen hinzuzufügen, müssen Sie eine Ereignisprozedur für das menuItemSelect-Ereignis erstellen.

Benutzerdefinierte Menüelemente werden im jeweiligen Kontextmenü oben über den integrierten Elementen angezeigt und durch eine Trennlinie von integrierten Menüelementen getrennt. In AIR gibt es keine integrierten Elemente und die folgenden Einschränkungen gelten nicht für den Inhalt in der AIR-Anwendungs-Sandbox.

Einschränkungen:

• Einem Kontextmenü können maximal 15 benutzerdefinierte Menüelemente hinzugefügt werden.
• Jeder Anzeigetext muss mindestens ein sichtbares Zeichen enthalten.
• Steuerzeichen, Zeilenvorschübe und andere Leerraumzeichen werden ignoriert.
• Der Anzeigetext darf nicht mehr als 100 Zeichen lang sein.
• Anzeigetexte mit demselben Text wie integrierte oder andere benutzerdefinierte Menüelemente werden ignoriert, unabhängig davon, ob das andere Element sichtbar ist. Beim Vergleich der Anzeigetexte mit dem Text integrierter oder vorhandener benutzerdefinierter Menüelemente werden Groß- und Kleinschreibung, Satzzeichen und Leerraumzeichen nicht berücksichtigt.
• Die folgenden Anzeigetexte sind nicht zulässig, die einzelnen Wörter können jedoch in Zusammensetzungen mit anderen Wörtern verwendet werden (z. B. ist "100%" unzulässig, "100% Zufriedenheit" jedoch zulässig):

   Save
   Zoom In
   Zoom Out
   100%
   Show All
   Quality
   Play
   Loop
   Rewind
   Forward
   Back
   Movie not loaded
   About
   Print
   Show Redraw Regions
   Debugger
   Undo
   Cut
   Copy
   Paste
   Delete
   Select All
   Open
   Open in new window
   Copy link
   

• Die folgenden Begriffe dürfen in benutzerdefinierten Anzeigetexten weder alleinstehend noch in Zusammensetzungen verwendet werden:

   Adobe
   Macromedia
   Flash Player
   Settings
   

Hinweis: Wenn der Player auf einem nicht englischsprachigen System ausgeführt wird, erfolgt der Vergleich der Anzeigetexte sowohl mit der englischen Liste als auch mit den lokalisierten Entsprechungen.

Beispiele anzeigen

Verwandte API-Elemente

---

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}