ContextMenu  - AS3

Eine Instanz der ContextMenuBuiltInItems-Klasse mit den folgenden Eigenschaften: forwardAndBack, loop, play, print, quality, rewind, save und zoom. Wenn diese Eigenschaften auf false gesetzt werden, führt dies zum Entfernen der entsprechenden Menüelemente aus dem angegebenen ContextMenu-Objekt. Diese Eigenschaften sind aufzählbar und standardmäßig auf true gesetzt.

Hinweis: In AIR besitzen Kontextmenüs keine integrierten Elemente.

Verwandte API-Elemente

Eine Instanz der ContextMenuClipboardItems-Klasse mit den folgenden Eigenschaften: cut, copy, paste, delete, selectAll. Wenn eine dieser Eigenschaften auf false gesetzt wird, wird das entsprechende Element im Zwischenablagemenü deaktiviert.

Verwandte API-Elemente

package {
    import flash.ui.ContextMenu;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;

    public class ContextMenuClipboardItemsExample extends Sprite {
        public function ContextMenuClipboardItemsExample() {
            var myContextMenu:ContextMenu = new ContextMenu();
            myContextMenu.clipboardMenu = true;
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);
            var rc:Sprite = new Sprite();
            rc.graphics.beginFill(0xDDDDDD);
            rc.graphics.drawRect(0,0,100,30);
            addChild(rc);
            rc.contextMenu = myContextMenu;
        }
        function menuSelectHandler(event:ContextMenuEvent):void {
            event.contextMenuOwner.contextMenu.clipboardItems.copy = true;
            event.contextMenuOwner.contextMenu.clipboardItems.paste = true;
        }
    }
}

Gibt an, ob das Zwischenablagemenü benutzt werden soll. Wenn dieser Wert true ist, bestimmt die clipboardItems-Eigenschaft, welche Elemente im Zwischenablagemenü aktiviert bzw. deaktiviert sind.

Wenn die link-Eigenschaft nicht Null ist, wird diese clipBoardMenu-Eigenschaft ignoriert.

Ein Array von ContextMenuItem-Objekten. Jedes Objekt im Array steht für ein von Ihnen definiertes Kontextmenüelement. Mit dieser Eigenschaft können Sie die benutzerdefinierten Menüelemente hinzufügen, entfernen und ändern.

Wenn Sie neue Menüelemente hinzufügen möchten, erstellen Sie ein ContextMenuItem-Objekt und fügen dieses dem customItems-Array hinzu (beispielsweise mithilfe von Array.push()). Weitere Informationen zum Erstellen von Menüelementen finden Sie im Abschnitt zur ContextMenuItem-Klasse.

Verwandte API-Elemente

Die isSupported-Eigenschaft hat den Wert true, wenn die ContextMenu-Klasse von der aktuellen Plattform unterstützt wird, andernfalls hat sie den Wert false.

Das Array der benutzerdefinierten Elemente in diesem Menü.

Diese Eigenschaft bewirkt von der Funktion her das gleiche wie die customItems-Eigenschaft. Das Array wird in der Anzeigereihenfolge sortiert.

Der URLRequest des Links. Wenn diese Eigenschaft null ist, wird ein normales Kontextmenü angezeigt. Wenn diese Eigenschaft nicht Null ist, wird das Kontextmenü „Link“ angezeigt, und es wird die angegebene URL verwendet.

Wenn ein Link angegeben wurde, wird die clipboardMenu-Eigenschaft ignoriert.

Der Standardwert ist null.

Die Anzahl der Elemente in diesem Menü.

Erstellt ein ContextMenu-Objekt.

Verwandte API-Elemente

Fügt am Ende des Menüs ein Menüelement hinzu.

Beim Erstellen eines Kontextmenüs können Sie entweder NativeMenuItem- oder ContextMenuItem-Objekte hinzufügen. Es wird jedoch empfohlen, dass Sie in einem Kontextmenü nur einen Objekttyp verwenden, damit alle Menüelemente über dieselben Eigenschaften verfügen.

Parameter

Erstellt eine Kopie des angegebenen ContextMenu-Objekts. Die Kopie übernimmt alle Eigenschaften des Originalmenüobjekts.

Gibt an, ob dieses Menü das angegebene Menüelement enthält.

Parameter

Blendet dieses Menü an der angegebenen Position ein.

Hinweis: In Flash Player wird diese Methode nicht unterstützt.

Parameter

Ruft das Menüelement am angegebenen Index ab.

Parameter

Ruft die Position des angegebenen Elements ab.

Parameter

Blendet alle integrierten Menüelemente im angegebenen ContextMenu-Objekt aus (außer „Einstellungen“). In der Debugger-Version von Flash Player wird das Menüelement „Debuggen“ angezeigt. In SWF-Dateien ohne aktiviertes Remote-Debuggen ist es jedoch abgeblendet.

Mit dieser Methode werden nur Menüelemente aus dem Standardkontextmenü ausgeblendet. Sie wirkt sich nicht auf Elemente des Bearbeitungs- oder Fehlermenüs aus.

Bei dieser Methode werden alle booleschen Elemente von my_cm.builtInItems auf false gesetzt. Sie können bestimmte integrierte Elemente sichtbar machen, indem Sie den entsprechenden Eintrag in my_cm.builtInItems auf true setzen.

Hinweis: In AIR besitzen Kontextmenüs keine integrierten Elemente. Wenn diese Methode aufgerufen wird, passiert nichts.

Verwandte API-Elemente

Entfernt alle Elemente aus dem Menü.

Bewirkt, dass das Menüelement am angegebenen Index entfernt und zurückgegeben wird.

Parameter

Wird ausgelöst, wenn ein Benutzer ein Kontextmenü zum ersten Mal erzeugt, jedoch bevor der Inhalt des Kontextmenüs angezeigt wird. Auf diese Weise können in Ihrem Programm die Kontextmenüelemente bearbeitet werden, bevor das Menü angezeigt wird. Das Kontextmenü wird durch einen Rechtsklick mit dem Zeigegerät erzeugt.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

1. Die Eigenschaft myContextMenu wird deklariert und anschließend einem neuen ContextMenu-Objekt zugewiesen, und die Eigenschaft redRectangle vom Typ „Sprite“ wird deklariert.
2. Die removeDefaultItems()-Methode wird aufgerufen, bei der alle integrierten Kontextmenüelemente mit Ausnahme der Option zum Drucken entfernt werden.
3. Die addCustomMenuItems()-Methode wird aufgerufen, bei der ein Menüelement mit der Bezeichnung Red to Black im defaultItems-Array platziert wird, indem die push()-Methode des Arrays verwendet wird. Ein menuItemSelect-Ereignis-Listener wird dem ContextMenuItem-Objekt hinzugefügt. Die verknüpfte Methode ist menuItemSelectHandler(). Bei dieser Methode werden einige trace()-Anweisungen gedruckt, wenn auf das Kontextmenü zugegriffen und die Option Red to Black ausgewählt wird. Darüber hinaus wird das rote Quadrat entfernt und durch ein schwarzes ersetzt.
4. Ein menuSelect-Ereignis-Listener mit der verknüpften Methode menuSelectHandler() wird hinzugefügt. Hiermit werden drei trace()-Anweisungen gedruckt, wenn ein Element im Kontextmenü ausgewählt wird.
5. Durch addChildren() wird anschließend ein rotes Quadrat gezeichnet und der Anzeigeliste hinzugefügt, in der dieses umgehend angezeigt wird.
6. Zum Schluss wird myContextMenu dem Kontextmenü des Sprite redRectangle zugewiesen, sodass das benutzerdefinierte Kontextmenü nur angezeigt wird, wenn sich der Mauszeiger über dem Quadrat befindet.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}