| Paket | flashx.textLayout.elements |
| Sınıf | public final class ParagraphElement |
| Miras Alma | ParagraphElement  ParagraphFormattedElement FlowGroupElement FlowElement Object |
| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Varsayılan MXML ÖzelliğimxmlChildren
İlgili API Öğeleri
Miras Alınan Genel Özellikleri Gizle
Miras Alınan Genel Özellikleri GösterGenel Yöntemler
| Yöntem | Tanımlayan: | ||
|---|---|---|---|
Constructor - metin akışındaki bir paragrafı temsil eder. | ParagraphElement | ||
 |
Bir FlowElement alt nesnesini ekler. | FlowGroupElement | |
|
Belirtilen dizin konumuna bir FlowElement alt nesnesi ekler. | FlowGroupElement | |
| styleProp parametresi tarafından belirtilen stili bu FlowElement nesnesinden temizler. | FlowElement | |
|
Tüm alt öğeleri içererek, belirtilen iki karakter konumu arasında içeriği kopyalayarak ve kopyayı bir FlowElement nesnesi olarak döndürerek bu FlowElement nesnesinin kapsamlı bir kopyasını oluşturur. | FlowElement | |
| Bunun userStyles öğesini otherElement öğesinin userStyles öğesi ile karşılaştırın. | FlowElement | |
|
Belirli bir göreceli metin konumu verildiğinde, göreceli konumu içeren birinci FlowElement alt öğesinin dizinini bulur. | FlowGroupElement | |
|
Belirli bir metin konumu verildiğinde, konumu içeren yaprak öğesini bulur. | FlowGroupElement | |
Sonraki atom metnindeki konumu bulmak için sağlanan konumdan ileriye doğru tarama yapar ve dizini döndürür. | ParagraphElement | ||
Metinde sonraki sözcük sınırının dizinini döndürür. | ParagraphElement | ||
Önceki atom metnindeki konumu bulmak için sağlanan konumdan geriye doğru tarama yapar ve dizini döndürür. | ParagraphElement | ||
Metinde önceki sözcük sınırının dizinini döndürür. | ParagraphElement | ||
|
Metin akışındaki öğenin başlangıç konumunu mutlak bir dizin olarak döndürür. | FlowElement | |
|
Bu FlowElement nesnesiyle göreceli olarak, belirtilen konumdaki karakteri döndürür. | FlowElement | |
| Bu FlowElement nesnesiyle göreceli olarak, belirtilen konumdaki karakter kodunu döndürür. | FlowElement | |
|
Belirtilen dizindeki FlowElement alt öğesini döndürür. | FlowGroupElement | |
|
Alt öğelerde, belirtilen FlowElement nesnesini arar ve bu nesnenin dizin konumunu döndürür. | FlowGroupElement | |
|
Bu öğenin, bir üst üst öğeyle göreceli başlangıcını döndürür. | FlowElement | |
|
Bu grubun birinci FlowLeafElement alt alt öğesini döndürür. | FlowGroupElement | |
|
Bu grubun son FlowLeafElement alt alt öğesini döndürür. | FlowGroupElement | |
Bundan sonra gelen paragrafı veya başka paragraf yoksa null değerini döndürür. | ParagraphElement | ||
| Metin akışı hiyerarşisinde sonraki FlowElement eş öğesini döndürür. | FlowElement | |
|
Bu öğeyle ilişkilendirilmiş ParagraphElement nesnesini döndürür. | FlowElement | |
Bundan önce gelen paragrafı veya bu paragraf TextFlow içindeki birinci paragrafsa null değerini döndürür. | ParagraphElement | ||
| Metin akışı hiyerarşisinde önceki FlowElement eş öğesini döndürür. | FlowElement | |
| Stil adını belirten styleProp parametresinin belirttiği stilin değerini döndürür ve herhangi bir kullanıcı stili adını içerebilir. | FlowElement | |
| [geçersiz kıl] | FlowGroupElement | |
|
Öğenin kök TextFlow nesnesini döndürmek için metin akışı hiyerarşisinde tırmanır. | FlowElement | |
|
Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir. | Object | |
| Uygulama nesnesi oluşturulup MXML etiketinde belirtilen tüm özellikler başlatıldıktan sonra MXML nesneleri için çağrılır. | FlowElement | |
|
Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir. | Object | |
|
Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir. | Object | |
|
Belirtilen FlowElement alt nesnesini gruptan kaldırır. | FlowGroupElement | |
|
Belirtilen dizin konumundaki FlowElement alt nesnesini kaldırır. | FlowGroupElement | |
|
Gruptaki alt öğeleri, belirtilen yeni öğelerle değiştirir. | FlowGroupElement | |
|
Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar. | Object | |
| styleProp parametresi tarafından belirtilen stili, newValue parametresi tarafından belirtilen değere ayarlar. | FlowElement | |
|
Belirtilen iki karakter konumu arasındaki içeriği kopyalayarak bu FlowElement nesnesinin bir kopyasını oluşturur. | FlowElement | |
|
childIndex parametresinin belirttiği konumda bu nesneyi böler. | FlowGroupElement | |
|
Bu öğenin metnindeki göreceli bir konum olan relativePosition parametresinin belirttiği konumda bu FlowElement nesnesini böler. | FlowElement | |
|
Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür. | Object | |
|
Belirtilen nesnenin dize olarak temsil edilen halini döndürür. | Object | |
|
Belirtilen nesnenin temel değerini döndürür. | Object | |
Yapıcı Ayrıntı
ParagraphElement | () | Yapıcı |
public function ParagraphElement()| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Constructor - metin akışındaki bir paragrafı temsil eder.
Yöntem Ayrıntısı
findNextAtomBoundary | () | yöntem |
public function findNextAtomBoundary(relativePosition:int):int| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Sonraki atom metnindeki konumu bulmak için sağlanan konumdan ileriye doğru tarama yapar ve dizini döndürür. Atom terimi, bir metin satırını oluşturan bölünemez varlıklar olan grafik öğeleri ve karakterlerini (birleşen karakterler grubu dahil) ifade eder.
Parametreler
relativePosition:int — metinde 0'dan itibaren sayılan başlangıç konumu
|
int — sonraki atom metnindeki dizin
|
İlgili API Öğeleri
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek, belirli uzaklıklardan, bir paragrafta sonraki atom sınırlarını bulur.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextAtomBoundary extends Sprite
{
public function ParagraphElement_findNextAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next atom boundaries from offsets 5 and 10
var atomBoundary:int = paragraph.findNextAtomBoundary(4);
trace(atomBoundary); // 5
atomBoundary = paragraph.findNextAtomBoundary(10);
trace(atomBoundary); // 11
}
}
}
findNextWordBoundary | () | yöntem |
public function findNextWordBoundary(relativePosition:int):int| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Metinde sonraki sözcük sınırının dizinini döndürür.
Metinde bir sözcüğün başladığı veya bittiği sonraki konumu bulmak için, sağlanan konumdan ileriye doğru tarama yapar.
Parametreler
relativePosition:int — metinde 0'dan itibaren sayılan başlangıç konumu
|
int — metinde sonraki sözcük sınırının dizini
|
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek, belirli uzaklıklardan, bir paragrafta sonraki sözcük sınırlarını bulur.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextWordBoundary extends Sprite
{
public function ParagraphElement_findNextWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findNextWordBoundary(0);
trace(wordBoundary); // 5
wordBoundary = paragraph.findNextWordBoundary(12);
trace(wordBoundary); // 13
}
}
}
findPreviousAtomBoundary | () | yöntem |
public function findPreviousAtomBoundary(relativePosition:int):int| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Önceki atom metnindeki konumu bulmak için sağlanan konumdan geriye doğru tarama yapar ve dizini döndürür. Atom terimi, bir metin satırını oluşturan bölünemez varlıklar olan grafik öğeleri ve karakterlerini (birleşen karakterler grubu dahil) ifade eder.
Parametreler
relativePosition:int — metinde 0'dan itibaren sayılan başlangıç konumu
|
int — önceki küme metnindeki dizin
|
İlgili API Öğeleri
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek, belirli uzaklıklardan, bir paragrafta önceki atom sınırlarını bulur.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousAtomBoundary extends Sprite
{
public function ParagraphElement_findPreviousAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous atom boundaries from offsets 6 and 13
var atomBoundary:int = paragraph.findPreviousAtomBoundary(6);
trace(atomBoundary); // 5
atomBoundary = paragraph.findPreviousAtomBoundary(13);
trace(atomBoundary); // 12
}
}
}
findPreviousWordBoundary | () | yöntem |
public function findPreviousWordBoundary(relativePosition:int):int| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Metinde önceki sözcük sınırının dizinini döndürür.
Metinde bir sözcüğün başladığı veya bittiği önceki konumu bulmak için, sağlanan konumdan geriye doğru tarama yapar.
Parametreler
relativePosition:int — metinde 0'dan itibaren sayılan başlangıç konumu
|
int — metinde önceki sözcük sınırının dizini
|
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek, belirli uzaklıklardan, bir paragrafta önceki sözcük sınırlarını bulur.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousWordBoundary extends Sprite
{
public function ParagraphElement_findPreviousWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findPreviousWordBoundary(22);
trace(wordBoundary); // 17
wordBoundary = paragraph.findPreviousWordBoundary(11);
trace(wordBoundary); // 6
}
}
}
getNextParagraph | () | yöntem |
public function getNextParagraph():ParagraphElement| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Bundan sonra gelen paragrafı veya başka paragraf yoksa null değerini döndürür.
DöndürürParagraphElement — sonraki paragraf veya başka paragraf yoksa null değeri.
|
İlgili API Öğeleri
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek, xml işaretlemesinden üç metin paragrafını içe aktarır, getChildAtIndex(0) kullanarak birinci paragrafa erişir ve ikinci paragrafa erişmek için getNextParagraph() öğesini kullanır.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getNextParagraph extends Sprite
{
public function ParagraphElement_getNextParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get first paragraph
var p:ParagraphElement = textFlow.getChildAt(0) as ParagraphElement;
// get next paragraph and display its content
var nextParagraph:ParagraphElement = p.getNextParagraph();
trace("nextParagraph.text is: " + nextParagraph.getText());
}
}
}
getPreviousParagraph | () | yöntem |
public function getPreviousParagraph():ParagraphElement| Dil Sürümü: | ActionScript 3.0 |
| Çalışma Zamanı Sürümleri: | Flash Player 10, AIR 1.5 |
Bundan önce gelen paragrafı veya bu paragraf TextFlow içindeki birinci paragrafsa null değerini döndürür.
DöndürürParagraphElement |
İlgili API Öğeleri
Örnek ( Bu örnek nasıl kullanılır? )
Bu örnek, xml işaretlemesinden üç metin paragrafını içe aktarır, getChildAtIndex(1) kullanarak ikinci paragrafa erişir ve birinci paragrafa erişmek için getPreviousParagraph() öğesini kullanır.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getPreviousParagraph extends Sprite
{
public function ParagraphElement_getPreviousParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get second paragraph (first = 0)
var p:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
// get previous paragraph and display its content
var prevParagraph:ParagraphElement = p.getPreviousParagraph();
trace("prevParagraph.text is: " + prevParagraph.getText());
}
}
}
Örnekler Bu örnek nasıl kullanılır?
ParagraphElementExample.as
Bu örnek, üç metin paragrafı oluşturur ve biçimlendirir.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flash.text.engine.FontPosture;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.formats.TextLayoutFormat;
public class ParagraphElementExample extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// Create Strings of text for the paragraphs
private var para1String:String = "In the first paragraph of a "
private var para1String2:String = "cheap"
private var para1String3:String ="Western novel, a cowboy meets a saloon girl.";
private var para2String:String = "In the middle of the cheap novel a really bad guy, "+
"who is having a relationship with the saloon girl, sees the cowboy help "+
"her onto her horse as she smiles at him warmly."
private var para3String:String = "In the last paragraph of the cheap novel, the cowboy kills "+
"the really bad guy in a shootout in the middle of main street and "+
"then rides into the sunset with the saloon girl on the back of his horse.";
public function ParagraphElementExample()
{
// create a TextLayoutFormat object to use in formatting the paragraphs
var textLayoutFormat:TextLayoutFormat = new TextLayoutFormat();
var paragraph1:ParagraphElement = new ParagraphElement();
// create the ParagraphElement objects
var paragraph2:ParagraphElement = new ParagraphElement();
var paragraph3:ParagraphElement = new ParagraphElement();
// create the SpanElement objects to hold the content of the paragraphs
var p1Span1:SpanElement = new SpanElement();
var p1Span2:SpanElement = new SpanElement();
var p1Span3:SpanElement = new SpanElement();
var p2Span:SpanElement = new SpanElement();
var p3Span:SpanElement = new SpanElement();
// assign the strings of text for the 1st paragraph to spans
p1Span1.text = para1String;
p1Span2.text = para1String2;
p1Span2.fontStyle = FontPosture.ITALIC; // italicize 'cheap'
p1Span3.text = para1String3;
// add spans to first paragraph
paragraph1.addChild(p1Span1);
paragraph1.addChild(p1Span2);
paragraph1.addChild(p1Span3);
// assign the string of text for the 2nd paragraph to a span
// and add the span to the second paragraph
p2Span.text = para2String;
paragraph2.addChild(p2Span);
// assign the string of text for the 3rd paragraph to a span
// and add the span to the third paragraph
p3Span.text = para3String;
paragraph3.addChild(p3Span);
// add the paragraphs to the TextFlow
textFlow.addChild(paragraph1);
textFlow.addChild(paragraph2);
textFlow.addChild(paragraph3);
// set the text formatting properties
textLayoutFormat.fontSize = 14;
textLayoutFormat.textIndent = 15;
textLayoutFormat.paragraphSpaceAfter = 15;
textLayoutFormat.paddingTop = 4;
textLayoutFormat.paddingLeft = 4;
// assign the format object to the TextFlow
textFlow.hostFormat = textLayoutFormat;
// assign a controller to the stage and update it to compose and
// display the text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
ParagraphElementExample2.as
Bu örnek, xml işaretlemesini bir TextFlow nesnesine içe aktarır. xml işaretlemesi, önceki örnekte olduğu gibi, metnin aynı üç paragrafını ve bunların biçimlendirmesini tanımlar.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
public class ParagraphElementExample2 extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// xml markup that defines the attributes and contents of a text flow
private var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>In the first paragraph of a </flow:span>"+
"<flow:span fontStyle=\"italic\">cheap</flow:span>"+
"<flow:span> Western novel, a cowboy meets a saloon girl.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the middle of the cheap novel a really bad guy, </flow:span>"+
"<flow:span>who is having a relationship with the saloon girl, sees the cowboy help </flow:span>"+
"<flow:span>her onto her horse as she smiles at him warmly.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the last paragraph of the cheap novel, the cowboy kills the really </flow:span>"+
"<flow:span> bad guy in a shootout in the middle of main street and then rides into the sunset with </flow:span>"+
"<flow:span>the saloon girl on the back of his horse.</flow:span>" +
"</flow:p>"+
"</flow:TextFlow>";
public function ParagraphElementExample2()
{
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
Tue Jun 12 2018, 01:09 PM Z