PrintJob  - AS3

Bir yazdırma işinin o sırada etkin olup olmadığını gösterir. Bir yazdırma işi, aşağıdaki durumlardan birinde etkin olur (özellik değeri true olur):

• Bir Sayfa Yapısı veya Yazdırma iletişim kutusu görüntüleniyor.
• start() veya start2() yöntemi bir true döndürme değeri ile çağırılmıştır ve send() veya terminate() yöntemi çağırılmamıştır.

Bu özellik true ise ve showPageSetupDialog(), start() veya start2() yöntemini çağırırsanız, çalışma zamanı bir istisna atar.

İlgili API Öğeleri

Yazdırma işine sonradan eklenen herhangi bir sayfanın yazdırma sistemi tarafından yazdırılan kopya sayısı. Bu değer, işletim sisteminin Yazdırma iletişim kutusunda kullanıcı tarafından girilen kopya sayısıdır. Kopya sayısı yazdırma iletişim kutusunda görüntülenmediyse veya iletişim kutusu kullanıcıya sunulmadıysa, değer 1 olur (uygulama kodu tarafından değiştirilmediği sürece).

İşletim sisteminin Yazdırma iletişim kutusunda kullanıcı tarafından girilen aralığın birinci sayfasının sayfa numarası. Kullanıcı tüm sayfaların yazdırılmasını isterse, sayfa aralığı Yazdırma iletişim kutusunda görüntülenmediyse, veya Yazdırma iletişim kutusu kullanıcıya sunulmamışsa özellik sıfır olur.

O sırada seçili olup ve geçerli yazdırma ayarlarına sahip olan yazıcının renkli ayar mı (true) yoksa gri tonlamalı ayar mı (false) kullandığını belirtir.

Renkli veya gri tonlamalı bir değer belirlenemiyorsa, değer true olur.

PrintJob sınıfının geçerli platformda desteklenip (true) desteklenmediğini (false) belirtir.

Yazdırma işinin adı veya başlığı. İş adı, genelde işletim sistemi tarafından yazdırma sırasındaki işin başlığı olarak veya dosyaya yazdırılan bir işin varsayılan adı olarak kullanılır.

start() veya start2() öğelerini çağırmadıysanız ve özellik için bir değer ayarlamadıysanız, bu özelliğin değeri null olur.

Bir PrintJob örneğiyle çalıştırdığınız her yazdırma işi için, start() veya start2() yöntemini çağırmadan önce bu özelliği ayarlayın.

Varsayılan değer şudur null.

İşletim sisteminin Yazdırma iletişim kutusunda kullanıcı tarafından girilen aralığın son sayfasının sayfa numarası. Kullanıcı tüm sayfaların yazdırılmasını isterse, sayfa aralığı Yazdırma iletişim kutusunda görüntülenmediyse, veya Yazdırma iletişim kutusu kullanıcıya sunulmamışsa özellik sıfır olur.

Seçili yazıcının fiziksel çözünürlüğü, piksel/inç cinsinden. Değer, işletim sistemi tarafından bildirildiği şekilde geçerli yazdırma ayarlarına göre hesaplanır.

Çözünürlük belirlenemiyorsa, değer standart bir varsayılan değer olur. Varsayılan değer Linux'ta 600 ppi ve Mac OS işletim sisteminde 360 ppi'dir. Windows'ta, yazıcı çözünürlüğü her zaman mevcuttur, bu yüzden bir varsayılan değere ihtiyaç duyulmaz.

Yazdırma için görüntü yönlendirmesi. Kabul edilebilir değerler PrintJobOrientation sınıfında sabitler olarak tanımlanır.

Not: AIR 2 veya sonrasında, Sayfa Yapısı ve Yazdırma iletişim kutularındaki varsayılan yönlendirmeyi ayarlamak için bir yazdırma işini başlatmadan önce bu özelliği ayarlayın. Özelliği bir yazdırma işi ilerleme durumundayken ayarlayın (İş dahilindeki sayfa aralığının yönlendirmesini ayarlamak için start() veya start2() öğelerini çağırdıktan sonra.

İlgili API Öğeleri

Sayfadaki asıl yazdırılabilir alanda ortalanabilen en büyük alanın yüksekliği, nokta cinsinden. Kullanıcı tarafından ayarlanmış kenar boşlukları yok sayılır. Bu özellik yalnızca PrintJob.start() yöntemine çağrı yapıldıktan sonra kullanılabilir.

Not: AIR 2 veya sonrası için, bu özellik kabul edilmez. Onun yerine yazdırılabilir alanı kesirli nokta cinsinden ölçen ve merkezde olmayan yazdırılabilir alanları tam olarak tanımlayan printableArea öğesini kullanın.

İlgili API Öğeleri

Sayfadaki asıl yazdırılabilir alanda ortalanabilen en büyük alanın genişliği, nokta cinsinden. Kullanıcı tarafından ayarlanmış kenar boşlukları yok sayılır. Bu özellik yalnızca PrintJob.start() yöntemine çağrı yapıldıktan sonra kullanılabilir.

Not: AIR 2 veya sonrası için, bu özellik kabul edilmez. Onun yerine yazdırılabilir alanı kesirli nokta cinsinden ölçen ve merkezde olmayan yazdırılabilir alanları tam olarak tanımlayan printableArea öğesini kullanın.

İlgili API Öğeleri

Nokta cinsinden yazıcı medyasının sınırları. Bu değer, sonraki addPage() çağrıları için kullanılan koordinat sisteminin aynısını kullanır.

Kağıdın nokta olarak tam yüksekliği. Bu özellik yalnızca PrintJob.start() yöntemine çağrı yapıldıktan sonra kullanılabilir.

Not: AIR 2 veya sonrası için, bu özellik kabul edilmez. Kağıt boyutlarını kesirli nokta cinsinden ölçen paperArea öğesini kullanın.

İlgili API Öğeleri

Kağıdın nokta olarak tam genişliği. Bu özellik yalnızca PrintJob.start() yöntemine çağrı yapıldıktan sonra kullanılabilir.

Not: AIR 2 veya sonrası için, bu özellik kabul edilmez. Kağıt boyutlarını kesirli nokta cinsinden ölçen paperArea öğesini kullanın.

İlgili API Öğeleri

Yazıcı medyasının yazdırılabilir alanının nokta cinsinden sınırları. Bu değer, sonraki addPage() çağrıları için kullanılan koordinat sisteminin aynısını kullanır.

Geçerli yazdırma işlemi için kullanılacak yazıcıyı alır veya ayarlar. Ayarlayıcıya iletilen ve alıcıya döndürülen dize, printers() yöntemi tarafından döndürülen Dizideki dizelerden biriyle eşleşmelidir. Varsayılan yazıcının kullanılması gerektiğini belirtmek için, değeri null olarak ayarlayın. Varsayılan yazıcının belirlenemeyeceği işletim sistemlerinde, bu özelliğin değeri null olur.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.printer = "HP_LaserJet_1";
     myPrintJob.start();
     

Bu özelliğin değerini ayarlamak, yazıcının hemen seçilmesine neden olur. Yazıcı seçimi başarısız olursa, bu özelliğin değeri önceki değerine sıfırlanır. Yazıcı değerinin ayarlanmasının başarılı olup olmadığını, değeri ayarlamaya çalıştıktan sonra okuyarak ve onun ayarlanan değerle eşleştiğini doğrulayarak anlayabilirsiniz.

Etkin bir yazıcı işinin printer özelliği değiştirilemez. Onu start() veya start2() yöntemini başarıyla çağırdıktan sonra ve send() veya terminate() öğesini çağırmadan önce değiştirmeye çalışmak başarısız bir sonuç verir.

Dize adı değerleri olarak mevcut yazıcıların bir listesini sağlar. Listenin ön hesaplaması yapılmaz; liste işlev çağrıldığında oluşturulur. Mevcut bir yazıcı yoksa veya sistem yazdırmayı desteklemiyorsa, değer null olur. Sistem yazdırmayı destekliyorsa ancak bir yazıcı listesi döndüremiyorsa, değer tek öğeli bir Vektördür (onun length özelliği 1'dir). Bu durumda, tek olan eleman asıl yazıcı adına sahiptir veya geçerli yazıcı adı belirlenemiyorsa bir varsayılan ada sahiptir.

Flash çalışma zamanı ortamının ayrı bir Sayfa Yapısı iletişim kutusunu destekleyip desteklemediğini gösterir. Bu özelliğin değeri true ise, işletim sisteminin sayfa yapısı iletişim kutusunu görüntülemek için showPageSetupDialog() yöntemini çağırabilirsiniz.

İlgili API Öğeleri

Bir veya daha fazla sayfa yazdırmak için kullanabileceğiniz bir PrintJob nesnesi oluşturur. Bir PrintJob nesnesi oluşturduktan sonra, yazdırma işini yazıcıya göndermek için (şu sıraya uygun olarak) PrintJob.start(), PrintJob.addPage() ve ardından PrintJob.send() yöntemlerini kullanmanız gerekir.

Örneğin, myPrintJob.addPage() yöntem çağrılarına yönelik [params] yer tutucu metnini aşağıdaki kodda gösterildiği şekilde özel parametrelerle değiştirebilirsiniz:

 // create PrintJob object
 var myPrintJob:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (myPrintJob.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      myPrintJob.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    myPrintJob.send();
 }
 

AIR 2 veya sonrasında, birden fazla PrintJob örneği oluşturup kullanabilirsiniz. PrintJob örneğinde ayarlanan özellikler yazdırma bittikten sonra korunur. Bu, PrintJob örneğini yeniden kullanmanıza ve bir kullanıcıya uygulamanızdaki diğer içerikler için farklı yazdırma tercihleri sunarken onun seçili yazdırma tercihlerini korumanıza olanak verir. 2. sürümden önceki Flash Player ve AIR'deki içerik için, birinci PrintJob nesnesi hala etkinken ikincisini oluşturamazsınız. İlk PrintJob nesnesi hala etkinken ikinci bir PrintJob nesnesi oluşturursanız (new PrintJob() öğesini çağırarak) ikinci PrintJob nesnesi oluşturulamaz. Bu nedenle, ikinci bir PrintJob oluşturmadan önce myPrintJob değerini kontrol edebilirsiniz.

İlgili API Öğeleri

Belirtilen Sprite nesnesini tek bir sayfa olarak yazıcı kuyruğuna gönderir. Bu yöntemi kullanmadan önce, bir PrintJob nesnesi oluşturun ve ardından start() veya start2() öğesini kullanın. Ardından, bir yazdırma işi için addPage() öğesini bir veya daha fazla kez çağırdıktan sonra, sıralanmış sayfaları yazıcıya göndermek için PrintJob.send() öğesini kullanın. Başka bir deyişle, bir PrintJob nesnesi oluşturduktan sonra, yazdırma işini yazıcıya göndermek için start() veya start2(), addPage() ve ardından send() yöntemlerini (aşağıdaki sırada) kullanmanız gerekir. Bir yazdırma işindeki birden fazla sayfayı yazdırmak için start() öğesine yapılan tek bir çağrıdan sonra addPage() öğesini birden fazla defa çağırabilirsiniz.

addPage(), Flash Player'ın bir istisna atmasına yol açarsa (örneğin, start() öğesini çağırmadıysanız veya kullanıcı yazdırma işini iptal ederse), addPage() öğesine yapılan sonraki çağrılar başarısız olur. Ancak addPage() öğesine yapılan önceki çağrılar başarılı olursa, ortaya çıkan send() komutu başarıyla sıralanan sayfaları yazıcıya gönderir.

Yazdırma işi sırasında addPage() işleminin tamamlanması 15 saniyeden uzun sürerse, Flash Player bir sonraki addPage() çağrısında bir istisna atar.

printArea parametresi için bir değer iletirseniz, printArea Dikdörtgeninin x ve y koordinatları sayfa üzerindeki yazdırılabilir alanın sol üst köşesiyle (0,0 koordinatları) eşleşir. pageHeight ve pageWidth salt okunur özellikleri start() öğesi tarafından ayarlanan yazdırılabilir alanı tanımlar. Çıktı, sayfa üzerindeki yazdırılabilir alanın sol üst köşesiyle hizalandığı için, printArea öğesinde tanımlanan alan, sayfa üzerindeki yazdırılabilir alandan daha büyük olduğunda, çıktı, printArea öğesi tarafından tanımlanan sağ veya alt bölüme kadar kırpılır. Flash Professional'da, printArea için bir değer iletmezseniz ve Sahne Alanı, yazdırılabilir alandan daha büyükse aynı kırpma işlemi gerçekleşir. Flex veya Flash Builder'da, printArea için bir değer iletmezseniz ve ekran yazdırılabilir alandan daha büyükse aynı kırpma işlemi gerçekleşir.

Bir Sprite nesnesini yazdırmadan önce ölçeklemek isterseniz, bu yöntemi çağırmadan önce ölçek özelliklerini ayarlayın (bkz. flash.display.DisplayObject.scaleX ve flash.display.DisplayObject.scaleY) ve yazdırma işleminden önce orijinal değerlerine geri döndürün. Sprite nesnesinin ölçeğinin printArea öğesiyle bir ilişkisi yoktur. Yani, 50 x 50 piksellik bir yazdırma alanı belirtirseniz 2500 piksellik bir alan yazdırılır. Sprite nesnesini ölçeklerseniz, aynı 2500 piksellik alan yazdırılır, ancak Sprite nesnesi ölçeklenen boyutta yazdırılır.

Flash Player yazdırma özelliği, PostScript ve PostScript olmayan yazıcıları destekler. PostScript olmayan yazıcılar, vektörleri bitmap'lere dönüştürür.

Parametreler

İlgili API Öğeleri

Sayfa boyutunu ayarlar. paperSize parametresi için kabul edilebilir değerler PaperSize sınıfındaki sabitlerdir. Bu yöntemi çağırmak, yazdırma ayarlarını kullanıcı Sayfa Yapısı veya Yazdırma iletişim kutularında bir kağıt boyutu seçiyormuş gibi etkiler.

Bu yöntemi istediğiniz zaman çağırabilirsiniz. Bu yöntemi bir iş başlatmadan önce, Sayfa Yapısı ve Yazdırma iletişim kutularındaki varsayılan sayfa boyutunu ayarlamak için çağırın. Bu yöntemi yazdırma işi sürerken iş dahilindeki sayfa aralığının kağıt boyutunu ayarlamak için çağırın.

     import flash.printing.PrintJob;
     import flash.printing.PaperSize;
     
     var myPrintJob:PrintJob = new PrintJob();
     myPrintJob.selectPaperSize(PaperSize.ENV_10);
     

Parametreler

İlgili API Öğeleri

start() veya start2() ve addPage() yöntemlerine yapılan başarılı çağrılardan sonra sıraya konmuş sayfaları yazıcıya gönderir.

Bu yöntem, start() veya start2() yöntemine yapılan çağrı başarısız olursa veya addPage() yöntemine yapılan bir çağrı bir istisna atarsa başarısız olur. Bir hata oluşmasını önlemek için, bu yöntemi çağırmadan önce start() veya start2() yönteminin true değerini döndürdüğünden emin olun ve olası addPage() istisnalarını yakalayın. Aşağıdaki örnek bu yöntem çağırılmadan önce hataların nasıl düzgün bir biçimde kontrol edileceğini gösterir:

     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.start()) {
       try {
         myPrintJob.addPage([params]);
       }
       catch(e:Error) {
          // handle error 
       }
     
       myPrintJob.send();
     }
     

İlgili API Öğeleri

Geçerli medya bunu desteklerse, işletim sisteminin Sayfa Yapısı'nı görüntüler. Sayfa Yapısının desteklenip desteklenmediğini belirlemek için supportsPageSetupDialog özelliğini kullanın.

     import flash.printing.PrintJob;
     
     var myPrintJob:PrintJob = new PrintJob();
     if (myPrintJob.supportsPageSetupDialog)
     {
         myPrintJob.showPageSetupDialog();
     }
     

İlgili API Öğeleri

İşletim sisteminin Yazdırma iletişim kutusunu görüntüler ve sıraya almayı başlatır. Yazdırma iletişim kutusu, kullanıcının yazdırma ayarlarını değiştirmesini sağlar. PrintJob.start() yöntemi başarılı dönüş yaptığında (kullanıcı, Yazdırma iletişim kutusunda Tamam'ı tıklatır), kullanıcının seçili yazdırma ayarlarını temsil eden aşağıdaki özellikler doldurulur:

Not: Kullanıcı, Yazdırma iletişim kutusunu iptal ederse özellikler toplanmaz.

Kullanıcı, Yazdırma iletişim kutusunda Tamam'ı tıklattıktan sonra Flash Player, işletim sisteminde bir yazdırma işi sıralamaya başlar. İşletim sisteminde kullanıcı için yazdırma işlemi hakkındaki bilgiler görüntülendiğinden, sayfaları kuyruğa göndermek için en kısa zamanda PrintJob.addPage() ve PrintJob.send() çağrılarını çağırmalısınız. Çıktıyı biçimlendirmek için, bu yöntemle doldurulan salt okunur yükseklik, genişlik ve yönlendirme özelliklerini kullanabilirsiniz.

PrintJob.addPage() ve PrintJob.send() öğelerine sonradan herhangi bir çağrı yapılmadan önce bu yöntemin true değerini döndürüp döndürmediğini test edin (kullanıcı, işletim sisteminin Yazdırma iletişim kutusunda Tamam'ı tıklattığında):

     var myPrintJob:PrintJob = new PrintJob();
        if(myPrintJob.start()) {
          // addPage() and send() statements here
        }
     

Geçerli yazdırma işi örneğinde, aşağıdaki aralıklardan biri 15 saniyeden uzun sürerse PrintJob.start() öğesine yapılan sonraki çağrı falsedeğerini geri döndürür:

• PrintJob.start() ve ilk PrintJob.addPage()
• Bir PrintJob.addPage() ve sonraki PrintJob.addPage()
• Sonuncu PrintJob.addPage() ve PrintJob.send()

İlgili API Öğeleri

İşletim sisteminin Yazdırma iletişim kutusunu isteğe bağlı olarak gösterir, sıraya almayı başlatır ve PrintJob salt okunur özellik değerlerini değiştirebilir.

uiOptions parametresi, çağıranın Yazdırma iletişim kutusunda hangi seçeneklerin görüntülendiğini kontrol etmesine olanak verir. PrintUIOptions sınıfına bakın. Bu parametre showPrintDialog değeri false ise yok sayılır.

showPrintDialog true olduğunda bile, bu yöntemin davranışı start() yönteminden farklı olabilir. Bazı işletim sistemlerinde, start() Yazdırma iletişim kutusunu takip eden Sayfa Yapısı iletişim kutusunu gösterir. Bunun aksine, start2() hiç bir zaman Sayfa Yapısı iletişim kutusunu göstermez.

Aşağıdaki örnekte, Yazdırma iletişim kutusundaki min ve maks sayfa ayarları, iletişim kutusu kullanıcıya gösterilmeden önce ayarlanır.

     import flash.printing.PrintJob;
     import flash.printing.PrintUIOptions;
     
     var myPrintJob:PrintJob = new PrintJob();
     var uiOpt:PrintUIOptions = new PrintUIOptions();
     uiOpt.minPage = 1;
     uiOpt.maxPage = 3;
     var accepted:Boolean = myPrintJob.start2(uiOpt);
     

Parametreler

İlgili API Öğeleri

Yazdırma işinin göndermeden sonlandırılması gerektiğini söyler. Bu yöntemi, bir yazdırma işi zaten start() veya start2() öğesine yapılan bir çağrı tarafından başlatıldığında ancak yazıcıya herhangi bir sayfa göndermek uygun olmadığında kullanın. Genelde, terminate() yalnızca hataları onarmak için kullanılır.

Bu yöntem çağırıldıktan sonra, PrintJob örneği yeniden kullanılabilir. Mümkünse, işin yazdırma ayarları daha sonra kullanılmak için korunur.

1. Sprite türüne ait sheet1 ve sheet2 adlı iki adet değişken bildirin.
2. sheet1 ve sheet2 öğelerine yeni bir Sprite örneği atayan ve ardından farklı argümanlar kullanarak createSheet() öğesini çağıran init() öğesini çağırın.
3. createSheet() aşağıdakileri gerçekleştirir:
   1. İletilen Sprite nesnesi, açık gri arka plana ve bir piksel değerindeki siyah kenarlığa sahip bir dikdörtgen çizmek için kullanılır ve bu x = 0, y = 0 olacak şekilde 100 piksel genişliğe ve 200 piksel yüksekliğe sahiptir.
   2. Sprite ile aynı boyutlara sahip olan, wordWrap özelliği true olarak ayarlanmış ve text özelliği createSheet() öğesine bir argüman olarak iletilen String öğesi olarak belirlenmiş txt adlı yeni bir TextField nesnesi oluşturulur.
   3. İletilen Object argümanı boş değerdeyse, bu argümanın koordinat ve boyut özelliklerinden yararlanarak beyaz bir dikdörtgen çizmek için kullanılan img adlı yeni bir Sprite örneği oluşturun. Beyaz dikdörtgen, addChild() kullanılarak Sprite nesnesinin görüntüleme listesine eklenir.
   4. txt TextField, addChild() kullanılarak Sprite nesnesinin görüntüleme listesine eklenir.
4. Yapıcıda ise, etkinleştirilmiş (devreden çıkarılmamış) yazdırma yöntemi çağrılır. Yöntemler birbirine oldukça benzediği için printOnePerPage() aşağıda açıklanmıştır.
5. printOnePerPage() aşağıdakileri gerçekleştirir:
   1. pj ve pagesToPrint adlı yeni bir PrintJob nesnesini bir birim olarak bildirir.
   2. İşletim sisteminin yerli yazdırma iletişim kutusunu açın ve kullanıcının Tamam'ı tıklatması için bekler.
   3. Yönlendirmeyi kontrol eder ve yatay yön seçilmişse bir hata verir ve çıkar.
   4. sheet1 ve sheet2 için sayfa yüksekliğini ve genişliğini ayarlar.
   5. addPage() öğesini kullanarak sheet1 ve sheet2 sayfalarını yazıcı kuyruğuna gönderir.
   6. Yazdırılacak sayfa sayısı > 0 ise, sıradaki tüm sayfaları yazdırır.
6. draw() yöntemi çağrılır ve böylece iki Sprite özelliği sahne alanına sığacak şekilde yeniden boyutlandırılır ve sheet2 sayfası, sheet1 sayfasının tam sağında olacak şekilde yeniden konumlandırılır.

Not: yapıcı, tercihe bağlı olarak üç yazdırma yönteminden biri (sayfa başına bir yaprak, sayfa başına iki yaprak veya sayfanın üst yarısı üzerine yazdırma) seçilebilecek şekilde ayarlanmıştır. Kod yorumları kullanılarak yazdırma yöntemlerinin tam olarak ikisi devre dışı bırakılmadığı sürece bu örnek düzgün çalışmayacaktır. Bu örnek, printOnePerPage() çağrılacak şekilde ayarlanmıştır.

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}