GlowFilter  - AS3

Renk için alfa saydamlık değeri. Geçerli değerler 0 ila 1'dir. Örneğin ,25, %25'lik bir saydamlık değeri ayarlar. Varsayılan değer 1'dir.

Yatay bulanıklaştırma miktarı. Geçerli değerler 0 ile 255 arasındadır (kayar nokta). Varsayılan değer 6'dır. 2'nin katları olan değerler (2, 4, 8, 16 ve 32 gibi) diğer değerlerden daha hızlı oluşturmak için en iyileştirilir.

Dikey bulanıklaştırma miktarı. Geçerli değerler 0 ile 255 arasındadır (kayar nokta). Varsayılan değer 6'dır. 2'nin katları olan değerler (2, 4, 8, 16 ve 32 gibi) diğer değerlerden daha hızlı oluşturmak için en iyileştirilir.

Işımanın rengi. Geçerli değerler, onaltılık 0xRRGGBB biçimindedir. Varsayılan değer 0xFF0000 değeridir.

Işımanın iç ışıma olup olmadığını belirtir. true değeri bir iç ışımayı belirtir. Varsayılan değer false değeridir ve bir dış ışımayı (nesnenin dış kenarları üzerinde bir ışıma) belirtir.

Nesnenin boşaltma efekti olup olmadığını belirtir. Bir true değeri nesnenin dolgusunu saydam yapar ve belgenin arka plan rengini ortaya çıkarır. Varsayılan değer false değeridir. (Boşaltma efekti yok.)

Filtrenin kaç defa uygulanacağı. Varsayılan değer, filtrenin bir kez uygulanmasına karşılık gelen BitmapFilterQuality.LOW değeridir. BitmapFilterQuality.MEDIUM değeri filtreyi iki kez uygular; BitmapFilterQuality.HIGH filtreyi üç kez uygular. Daha düşük değerlere sahip filtreler daha hızlı oluşturulur.

Birçok uygulama için düşük, orta veya yüksek quality değeri yeterlidir. Farklı bir efekt elde etmek için fazladan 15'e kadar sayısal değer kullanabilseniz de, daha yüksek değerler daha yavaş oluşturulur. quality değerini artırmak yerine, hızlı oluşturmayla birlikte yalnızca blurX ve blurY özelliklerinin değerlerini artırarak benzer bir efekt elde edebilirsiniz.

İlgili API Öğeleri

Baskı ve dağılma kuvveti. Değer ne kadar yüksek olursa daha fazla renk baskısı yapılır ve ışıma ve arka plan arasındaki kontrast o kadar güçlü olur. Geçerli değerler 0 ila 255'tir. Varsayılan değer 2'dür.

Yeni bir GlowFilter örneğini, belirtilen parametreler ile başlatır.

İlgili API Öğeleri

Bu filtre nesnesinin kopyasını döndürür.

1. Gerekli sınıfları içe aktarın.
2. draw yönteminde kullanılan üç özelliği bildirin. Bu yöntem, turuncu bir kare çizmek için Sprite öğesinin graphics özelliği üzerinden erişilen Graphics sınıfının yöntemlerini kullanır.
3. Yapıcı işlevini oluşturun. Bu işlev aşağıdakileri gerçekleştirir:
   • Bir dikdörtgen oluşturmak için draw işlevini çağırır.
   • Bir BitmapFilter nesnesi glowFilter öğesi oluşturur ve bu öğeye getBitmapFilter() işlevinden gelen dönüş değerlerini atar.
   • glowFilter nesnesinden gelen değerler dizisini kök görüntüleme nesnesinin filters özelliğine atar. Bu durumda, kök görüntüleme nesnesinin tüm görüntüleme nesnesi alt öğeleri ışıma filtresi özelliklerini miras alır. Böylece draw() işlevinde oluşturulan dikdörtgen ışıma filtresi özelliklerini görüntüler.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.GlowFilter;

    public class GlowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function GlowFilterExample() {
        //draw the rectangle using the draw() function below
            draw();
            
        //assign the values from getBitmapFilter function below
        //to a BitmapFilter object "glowFilter"
            var glowFilter:BitmapFilter = getBitmapFilter();
            
        //populate the filters property of the root display object with the array of values
        //from the glowFilter object.
            filters = [ glowFilter ];
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x33CCFF;
            var alpha:Number = 0.8;
            var blurX:Number = 35;
            var blurY:Number = 35;
            var strength:Number = 2;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;

            return new GlowFilter(color,
                                  alpha,
                                  blurX,
                                  blurY,
                                  strength,
                                  quality,
                                  inner,
                                  knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}