NetStatusEvent  - AS3

Nesnenin durumunu veya hata koşulunu açıklayan özellikleri olan bir nesne.

information nesnesinin, "status" veya "error" olan bir dizeyi içeren belirli bir olayı ya da level özelliğini temsil eden bir dizenin yer aldığı bir code özelliği olabilir.

information nesnesi başka bir öğe de olabilir. Bazı uygulamalar için code ve level özellikleri çalışmayabilir ve bazı sunucular farklı nesneler gönderebilir.

P2P bağlantıları, iletinin hangi NetStream öğesine ait olduğunu belirten bilgi nesnesindeki stream parametresiyle bir NetConnection öğesine mesajlar gönderebilir.

Örneğin, code veya level özelliğine erişmeye çalışırsanız, Flex Data Services zorlama hatalarına neden olan Message nesneleri gönderir.

Şu tablo, code ve level özelliklerinin olası dize değerlerini açıklar.

Sürekli arabellekle ilgili hatalar görüyorsanız, NetStream.bufferTime özelliğini kullanarak arabelleği değiştirmeyi deneyin.

İlgili API Öğeleri

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

netStatus olayları hakkındaki bilgileri içeren bir Event nesnesi oluşturur. Event nesneleri, olay dinleyicilerine parametre olarak iletilir.

İlgili API Öğeleri

NetStatusEvent nesnesinin bir kopyasını oluşturur ve her özelliğin değerini, orijinal ile aynı olacak şekilde ayarlar.

NetStatusEvent nesnesinin tüm özelliklerini içeren bir dize döndürür. Dize şu biçimdedir:

[NetStatusEvent type=value bubbles=value cancelable=value info=value]

Bir netStatus olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

Bu örnekte, netStatusHandler yöntemi, NetConnection.netStatus NetStatusEvent olayı için bir dinleyici olarak kaydedilir. NetConnection.connect() denemesinin durumu (başarılı veya başarısız) belirlendiğinde, netStatus olayı bu yöntemi tetikler. NetConnection nesnesine bağlanma denemesi başarılı olursa (başka bir deyişle, netStatus olayı tarafından gönderilen NetStatusEvent nesnesinin info özelliği, başarı belirten bir code özelliğine sahipse), kod Video ve NetStream nesneleri oluşturur ve Video.attachNetStream() ve NetStream.play() yöntemlerini çağırır.

Not: Bu örneği çalıştırmak için, adı ve konumu videoURL öğesine verilen değişkenle eşleşen bir FLV dosyasına ihtiyacınız vardır; bu durumda bu dosya, SWF dosyasıyla aynı dizinde olan Video.flv adlı bir FLV dosyasıdır.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }