FocusEvent  - AS3

focusIn olayı için odak yönünü belirtir.

İlgili API Öğeleri

true olursa, relatedObject özelliği, güvenlik sanal alanlarıyla ilgili nedenlerden dolayı null değerine ayarlanır. relatedObject öğesinin nominal değeri, başka bir güvenlik sanal alanındaki DisplayObject öğesine başvuruysa, bu sanal alan sınırı içinde her iki yönde de izin olmadığı sürece relatedObject öğesi null değerine ayarlanır. Bir SWF dosyasından Security.allowDomain() öğesi çağrılarak veya bir görüntü dosyası sunucusundan ilke dosyası sağlanarak ve görüntü yüklenirken LoaderContext.checkPolicyFile özelliği ayarlanarak izin oluşturulur.

İlgili API Öğeleri

keyFocusChange olayını tetiklemek için basılan tuşun tuş kod değeri.

Odaktaki değişiklikten etkilenen tamamlayıcı bir InteractiveObject örneğine bir başvuru. Örneğin, bir focusOut olayı oluştuğunda, relatedObject, odağı kazanan InteractiveObject örneğini temsil eder.

Bu özelliğin değeri, iki durumda null olabilir: ilgili bir nesne yoksa veya bir ilgili nesne varsa ancak bu sizin erişemediğiniz bir güvenlik sanal alanındaysa. Bu nedenlerden hangisinin geçerli olduğunu belirlemek için isRelatedObjectInaccessible() özelliğini kullanın.

İlgili API Öğeleri

Shift tuşu değiştiricisinin etkinleştirilmiş olup (bu durumda değer true olur) olmadığını gösterir. Çevrimdışı kullanılamıyorsa, değer false olur. Bu özellik yalnızca FocusEvent keyFocusChange türünde olduğunda kullanılır.

Focus olaylarıyla ilgili belirli bilgileri içeren bir Event nesnesi oluşturur. Event nesneleri, olay dinleyicilerine parametre olarak iletilir.

İlgili API Öğeleri

FocusEvent nesnesinin bir kopyasını oluşturur ve her özelliğin değerini, orijinal ile aynı olacak şekilde ayarlar.

FocusEvent nesnesinin tüm özelliklerini içeren bir dize döndürür. Dize şu biçimdedir:

[FocusEvent type=değeri bubbles=değeri cancelable=değeri relatedObject=değeri shiftKey=değeri] keyCode=değeri]

Bir focusIn olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

focusOut olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

keyFocusChange olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

mouseFocusChange olay nesnesinin type özelliği değerini tanımlar.

Bu olay şu özelliklere sahiptir:

İlgili API Öğeleri

1. child (Sprite türünde) ve childCount (uint türünde) özelliklerini bildirir.
2. for döngüsü, beş adet açık mavi kare (0,0) oluşturur. Yeni bir CustomSprite örneğine child öğesi atayarak başlar. Her CustomSprite nesnesi oluşturulduğunda, şunlar olur:
   • uint türünün size özelliği 50 piksel olarak ve bgColor özelliği de açık mavi olarak ayarlanır.
   • Sprite sınıfının buttonMode ve useHandCursor özellikleri, yapıcı içinde true değerine ayarlanır.
   • İlişkili clickHandler() abonesiyle birlikte click türünde bir olay dinleyicisi başlatılır. Subscriber yöntemi Sprite türünde yerel bir target değişkeni oluşturur ve bu değişkeni tıklatılan her kutuya atar. Sahne Alanı'nın odağı daha sonra target öğesine atanır.
   • draw() yöntemi çağrılır, bu çağrı, Graphics sınıfının ve instance özelliklerinin beginFill(), drawRect() ve endFill() yöntemlerinin çağrılmasıyla 50 x 50 piksel bir kare oluşturur.
3. for döngüsünde, configureListeners() yöntemi çağrılır, bu çağrı üç olay dinleyicisi/abonesi başlatır:
   • Tıklatılan her görüntüleme listesi nesnesi (kutu) için click olayından sonra, focusIn/focusInHandler() gönderilir.
   • Başka bir kutu tıklatıldığında veya odak, Sahne Alanı'ndan çıktığında (örneğin, Flash Player dışı tıklatılarak), focusOut/focusOutHandler() gönderilir.
   • Bir görüntüleme listesi nesnesini seçmek için Tab tuşunu veya sol ok ya da sağ ok tuşlarını kullanırsanız, keyFocusChange/keyFocusChangeHandler() gönderilir. Ancak keyFocusChangeHandler() yöntemi sol ok veya sağ ok tuşlarını engeller ve bunları devre dışı bırakmak için preventDefault() yöntemini çağırır.
4. for döngüsünde karelerin her biri addChild() aracılığıyla görüntüleme listesine eklenir ve görüntülenir (tümü aynı alana).
5. Daha sonra yapıcı refreshLayout() çağırır, bu çağrı turuncu kareleri 5 piksel ile birbirinden ayrılacak şekilde ekranın üst kısmına (y = 0) dağıtır.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}