| Paket | flashx.textLayout.elements |
| Klass | public final class ParagraphElement |
| Arv | ParagraphElement  ParagraphFormattedElement FlowGroupElement FlowElement Object |
| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
MXML-standardegenskapmxmlChildren
Fler exempel
Relaterade API-element
Publika egenskaper
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaperPublika metoder
| Metod | Definieras med | ||
|---|---|---|---|
Konstruktor – representerar ett stycke i ett textflöde. | ParagraphElement | ||
 |
Lägger till ett underordnat FlowElement-objekt. | FlowGroupElement | |
|
Lägger till ett underordnat FlowElement-objekt vid den angivna indexpositionen. | FlowGroupElement | |
| Tar bort det format som anges av parametern styleProp från det här FlowElement-objektet. | FlowElement | |
|
Skapar en djup kopia av det här FlowElement-objektet, inklusive eventuella underordnade objekt, genom att kopiera innehållet mellan två angivna teckenpositioner och returnera kopian som ett FlowElement-objekt. | FlowElement | |
| Jämför userStyles för detta med userStyles för otherElement. | FlowElement | |
|
Utgå från en relativ textposition och hitta indexet för det första underordnade FlowElement-objekt, som innehåller den relativa positionen. | FlowGroupElement | |
|
Utgå från en relativ textposition och hitta det leaf-element som innehåller positionen. | FlowGroupElement | |
Söker framåt från den angivna positionen för att hitta nästa atoms placering i texten och returnerar indexet. | ParagraphElement | ||
Returnerar indexet för nästa ordgräns i texten. | ParagraphElement | ||
Söker bakåt från den angivna positionen för att hitta föregående atoms placering i texten och returnerar indexet. | ParagraphElement | ||
Returnerar indexet för föregående ordgräns i texten. | ParagraphElement | ||
|
Returnerar startpositionen för elementet i textflödet som ett absolut index. | FlowElement | |
|
Returnerar tecknet vid den angivna positionen, i förhållande till det här FlowElement-objektet. | FlowElement | |
| Returnerar teckenkoden vid den angivna positionen, i förhållande till det här FlowElement-objektet. | FlowElement | |
|
Returnerar det underordnade FlowElement-objektet vid det angivna indexet. | FlowGroupElement | |
|
Söker i underordnade objekt efter det angivna FlowElement-objektet och returnerar dess indexposition. | FlowGroupElement | |
|
Returnerar början av det här elementet i förhållande till ett överordnat element. | FlowElement | |
|
Returnerar det första underordnade FlowLeafElement-objektet i den här gruppen. | FlowGroupElement | |
|
Returnerar det sista underordnade FlowLeafElement-objektet i den här gruppen. | FlowGroupElement | |
Returnerar det stycke som kommer efter detta eller null, om det inte finns fler stycken. | ParagraphElement | ||
| Returnerar nästa likställda FlowElement-objekt i textflödeshierarkin. | FlowElement | |
|
Returnerar det ParagraphElement-objekt som är kopplat till det här elementet. | FlowElement | |
Returnerar det stycke som kommer före detta eller null, om det här stycket är det första i TextFlow. | ParagraphElement | ||
| Returnerar föregående likställda FlowElement-objekt i textflödeshierarkin. | FlowElement | |
| Returnerar värdet för det format som anges av parametern styleProp, som anger formatnamnet och kan inkludera alla användarformatnamn. | FlowElement | |
| [åsidosätt] | FlowGroupElement | |
|
Går uppåt i textflödeshierarkin för att returnera TextFlow-rotobjektet för det här elementet. | FlowElement | |
|
Anger om det finns en egenskap angiven för ett objekt. | Object | |
| Anropas för MXML-objekt efter att det implementerande objektet har skapats och alla komponentegenskaper som angetts för MXML-taggen har initierats. | FlowElement | |
|
Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter. | Object | |
|
Anger om den angivna egenskapen finns och är uppräkningsbar. | Object | |
|
Tar bort det angivna underordnade FlowElement-objektet från gruppen. | FlowGroupElement | |
|
Tar bort det underordnade FlowElement-objektet vid den angivna indexpositionen. | FlowGroupElement | |
|
Ersätter underordnade element i gruppen med angivna nya element. | FlowGroupElement | |
|
Anger tillgänglighet för en dynamisk egenskap för slingåtgärder. | Object | |
| Ställer in det format som anges av parametern styleProp på det värde som anges av parametern newValue. | FlowElement | |
|
Skapar en kopia av det här FlowElement-objektet genom att kopiera innehållet mellan två angivna teckenpositioner. | FlowElement | |
|
Delar det här objektet vid den position som anges av parametern childIndex. | FlowGroupElement | |
|
Delar det här FlowElement-objektet vid den position som anges av parametern relativePosition, vilket är en relativ position i texten för det här elementet. | FlowElement | |
|
Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner. | Object | |
|
Returnerar det angivna objektets strängbeteckning. | Object | |
|
Returnerar det angivna objektets primitiva värde. | Object | |
Konstruktordetaljer
ParagraphElement | () | Konstruktor |
public function ParagraphElement()| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
Konstruktor – representerar ett stycke i ett textflöde.
Metoddetaljer
findNextAtomBoundary | () | metod |
public function findNextAtomBoundary(relativePosition:int):int| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
Söker framåt från den angivna positionen för att hitta nästa atoms placering i texten och returnerar indexet. Termen atom hänvisar både till grafikelement och tecken (inklusive grupper av kombinerade tecken), det vill säga odelbara enheter som utgör en textrad.
Parametrar
relativePosition:int — position i texten att börja från, med början på 0
|
int — index i texten för efterföljande atom
|
Relaterade API-element
Exempel ( Så här använder du exemplet )
I det här exemplet hittas gränserna för nästa atom från givna förskjutningar i ett stycke.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextAtomBoundary extends Sprite
{
public function ParagraphElement_findNextAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next atom boundaries from offsets 5 and 10
var atomBoundary:int = paragraph.findNextAtomBoundary(4);
trace(atomBoundary); // 5
atomBoundary = paragraph.findNextAtomBoundary(10);
trace(atomBoundary); // 11
}
}
}
findNextWordBoundary | () | metod |
public function findNextWordBoundary(relativePosition:int):int| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
Returnerar indexet för nästa ordgräns i texten.
Söker framåt från den angivna positionen för att hitta nästa position i texten som är början eller slutet av ett ord.
Parametrar
relativePosition:int — position i texten att börja från, med början på 0
|
int — index i texten för nästa ordgräns
|
Exempel ( Så här använder du exemplet )
I det här exemplet hittas gränserna för nästa ord i ett stycke från givna förskjutningar.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findNextWordBoundary extends Sprite
{
public function ParagraphElement_findNextWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the next word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findNextWordBoundary(0);
trace(wordBoundary); // 5
wordBoundary = paragraph.findNextWordBoundary(12);
trace(wordBoundary); // 13
}
}
}
findPreviousAtomBoundary | () | metod |
public function findPreviousAtomBoundary(relativePosition:int):int| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
Söker bakåt från den angivna positionen för att hitta föregående atoms placering i texten och returnerar indexet. Termen atom hänvisar både till grafikelement och tecken (inklusive grupper av kombinerade tecken), det vill säga odelbara enheter som utgör en textrad.
Parametrar
relativePosition:int — position i texten att börja från, med början på 0
|
int — index i texten för föregående kluster
|
Relaterade API-element
Exempel ( Så här använder du exemplet )
I det här exemplet hittas gränserna för föregående atom från givna förskjutningar i ett stycke.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousAtomBoundary extends Sprite
{
public function ParagraphElement_findPreviousAtomBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous atom boundaries from offsets 6 and 13
var atomBoundary:int = paragraph.findPreviousAtomBoundary(6);
trace(atomBoundary); // 5
atomBoundary = paragraph.findPreviousAtomBoundary(13);
trace(atomBoundary); // 12
}
}
}
findPreviousWordBoundary | () | metod |
public function findPreviousWordBoundary(relativePosition:int):int| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
Returnerar indexet för föregående ordgräns i texten.
Söker bakåt från den angivna positionen för att hitta föregående position i texten som är början eller slutet av ett ord.
Parametrar
relativePosition:int — position i texten att börja från, med början på 0
|
int — index i texten för föregående ordgräns
|
Exempel ( Så här använder du exemplet )
I det här exemplet hittas gränserna för föregående ord i ett stycke från givna förskjutningar.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_findPreviousWordBoundary extends Sprite
{
public function ParagraphElement_findPreviousWordBoundary()
{
// create the TextFlow, ParagraphElement and SpanElement objects to hold paragraph
var textFlow:TextFlow = new TextFlow();
var paragraph:ParagraphElement = new ParagraphElement();
var span:SpanElement = new SpanElement();
// assign text to the span; add span to paragraph and paragraph to TextFlow
span.text = "Hello brave, new world!";
paragraph.addChild(span);
textFlow.addChild(paragraph);
// assign a controller to the stage and update it to compose and display text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// find the previous word boundary from offsets 0 and 12
var wordBoundary:int = paragraph.findPreviousWordBoundary(22);
trace(wordBoundary); // 17
wordBoundary = paragraph.findPreviousWordBoundary(11);
trace(wordBoundary); // 6
}
}
}
getNextParagraph | () | metod |
public function getNextParagraph():ParagraphElement| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
Returnerar det stycke som kommer efter detta eller null, om det inte finns fler stycken.
ReturnerarParagraphElement — nästa stycke eller null, om det inte finns fler stycken.
|
Relaterade API-element
Exempel ( Så här använder du exemplet )
I det här exemplet importeras tre textstycken från XML-kod, varpå det första stycket öppnas med getChildAtIndex(0) och det andra med getNextParagraph().
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getNextParagraph extends Sprite
{
public function ParagraphElement_getNextParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get first paragraph
var p:ParagraphElement = textFlow.getChildAt(0) as ParagraphElement;
// get next paragraph and display its content
var nextParagraph:ParagraphElement = p.getNextParagraph();
trace("nextParagraph.text is: " + nextParagraph.getText());
}
}
}
getPreviousParagraph | () | metod |
public function getPreviousParagraph():ParagraphElement| Språkversion: | ActionScript 3.0 |
| Körningsmiljöversioner: | Flash Player 10, AIR 1.5 |
Returnerar det stycke som kommer före detta eller null, om det här stycket är det första i TextFlow.
ReturnerarParagraphElement |
Relaterade API-element
Exempel ( Så här använder du exemplet )
I det här exemplet importeras tre textstycken från XML-kod, varpå det andra stycket öppnas med getChildAtIndex(1) och det första med getPreviousParagraph().
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
public class ParagraphElement_getPreviousParagraph extends Sprite
{
public function ParagraphElement_getPreviousParagraph()
{
// create TextFlow object
var textFlow:TextFlow = new TextFlow();
// create content for TextFlow using XML markup
var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\">"+
"<flow:p>"+
"<flow:span>This is the first paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the second paragraph.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>This is the third paragraph.</flow:span>"+
"</flow:p>"+
"</flow:TextFlow>";
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
// get second paragraph (first = 0)
var p:ParagraphElement = textFlow.getChildAt(1) as ParagraphElement;
// get previous paragraph and display its content
var prevParagraph:ParagraphElement = p.getPreviousParagraph();
trace("prevParagraph.text is: " + prevParagraph.getText());
}
}
}
Exempel Så här använder du exemplet
ParagraphElementExample.as
I det här exemplet skapas och formateras tre stycken med text.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flash.text.engine.FontPosture;
import flashx.textLayout.container.ContainerController;
import flashx.textLayout.elements.ParagraphElement;
import flashx.textLayout.elements.SpanElement;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.formats.TextLayoutFormat;
public class ParagraphElementExample extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// Create Strings of text for the paragraphs
private var para1String:String = "In the first paragraph of a "
private var para1String2:String = "cheap"
private var para1String3:String ="Western novel, a cowboy meets a saloon girl.";
private var para2String:String = "In the middle of the cheap novel a really bad guy, "+
"who is having a relationship with the saloon girl, sees the cowboy help "+
"her onto her horse as she smiles at him warmly."
private var para3String:String = "In the last paragraph of the cheap novel, the cowboy kills "+
"the really bad guy in a shootout in the middle of main street and "+
"then rides into the sunset with the saloon girl on the back of his horse.";
public function ParagraphElementExample()
{
// create a TextLayoutFormat object to use in formatting the paragraphs
var textLayoutFormat:TextLayoutFormat = new TextLayoutFormat();
var paragraph1:ParagraphElement = new ParagraphElement();
// create the ParagraphElement objects
var paragraph2:ParagraphElement = new ParagraphElement();
var paragraph3:ParagraphElement = new ParagraphElement();
// create the SpanElement objects to hold the content of the paragraphs
var p1Span1:SpanElement = new SpanElement();
var p1Span2:SpanElement = new SpanElement();
var p1Span3:SpanElement = new SpanElement();
var p2Span:SpanElement = new SpanElement();
var p3Span:SpanElement = new SpanElement();
// assign the strings of text for the 1st paragraph to spans
p1Span1.text = para1String;
p1Span2.text = para1String2;
p1Span2.fontStyle = FontPosture.ITALIC; // italicize 'cheap'
p1Span3.text = para1String3;
// add spans to first paragraph
paragraph1.addChild(p1Span1);
paragraph1.addChild(p1Span2);
paragraph1.addChild(p1Span3);
// assign the string of text for the 2nd paragraph to a span
// and add the span to the second paragraph
p2Span.text = para2String;
paragraph2.addChild(p2Span);
// assign the string of text for the 3rd paragraph to a span
// and add the span to the third paragraph
p3Span.text = para3String;
paragraph3.addChild(p3Span);
// add the paragraphs to the TextFlow
textFlow.addChild(paragraph1);
textFlow.addChild(paragraph2);
textFlow.addChild(paragraph3);
// set the text formatting properties
textLayoutFormat.fontSize = 14;
textLayoutFormat.textIndent = 15;
textLayoutFormat.paragraphSpaceAfter = 15;
textLayoutFormat.paddingTop = 4;
textLayoutFormat.paddingLeft = 4;
// assign the format object to the TextFlow
textFlow.hostFormat = textLayoutFormat;
// assign a controller to the stage and update it to compose and
// display the text
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
ParagraphElementExample2.as
I det här exemplet importeras XML-kod till ett TextFlow-objekt. XML-koden definierar samma tre textstycken (med formatering) som i föregående exempel.
package flashx.textLayout.elements.examples
{
import flash.display.Sprite;
import flashx.textLayout.elements.TextFlow;
import flashx.textLayout.conversion.TextConverter;
import flashx.textLayout.container.ContainerController;
public class ParagraphElementExample2 extends Sprite {
// create the TextFlow object
private var textFlow:TextFlow = new TextFlow();
// xml markup that defines the attributes and contents of a text flow
private var simpleText:String = "<?xml version=\"1.0\" encoding=\"utf-8\"?>" +
"<flow:TextFlow xmlns:flow=\"http://ns.adobe.com/textLayout/2008\" verticalScrollPolicy=\"auto\" horizontalScrollPolicy=\"auto\" editingMode=\"readWrite\" fontSize=\"14\" textIndent=\"15\" marginBottom=\"15\" paddingTop=\"4\" paddingLeft=\"4\">"+
"<flow:p>"+
"<flow:span>In the first paragraph of a </flow:span>"+
"<flow:span fontStyle=\"italic\">cheap</flow:span>"+
"<flow:span> Western novel, a cowboy meets a saloon girl.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the middle of the cheap novel a really bad guy, </flow:span>"+
"<flow:span>who is having a relationship with the saloon girl, sees the cowboy help </flow:span>"+
"<flow:span>her onto her horse as she smiles at him warmly.</flow:span>"+
"</flow:p>"+
"<flow:p>"+
"<flow:span>In the last paragraph of the cheap novel, the cowboy kills the really </flow:span>"+
"<flow:span> bad guy in a shootout in the middle of main street and then rides into the sunset with </flow:span>"+
"<flow:span>the saloon girl on the back of his horse.</flow:span>" +
"</flow:p>"+
"</flow:TextFlow>";
public function ParagraphElementExample2()
{
// import the xml markup into a TextFlow object and display it on the stage
textFlow = TextConverter.importToFlow(simpleText, TextConverter.TEXT_LAYOUT_FORMAT);
textFlow.flowComposer.addController(new ContainerController(this, 200, 400));
textFlow.flowComposer.updateAllControllers();
}
}
}
Tue Jun 12 2018, 01:40 PM Z