XMLDocument

Paket	flash.xml
Klass	public class XMLDocument
Arv	XMLDocument XMLNode Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Klassen XMLDocument representerar det gamla XML-objektet som fanns i ActionScript 2.0. Det bytte namn i ActionScript 3.0 till XMLDocument för att undvika namnkonflikt med den nya XML-klassen i ActionScript 3.0. I ActionScript 3.0 rekommenderar vi att du använder den nya XML-klassen på översta nivån och relaterade klasser, som har stöd för E4X (ECMAScript for XML).

XMLDocument-klassen, liksom XMLNode och XMLNodeType, finns med för bakåtkompatibilitet. Funktionen för att läsa in XML-dokument kan du nu hitta i URLLoader-klassen.

Visa exemplen

Relaterade API-element

flash.net.URLLoader
XML, klass

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		attributes : Object Ett objekt som innehåller alla attribut i den angivna XMLNode-instansen.	XMLNode
		childNodes : Array [skrivskyddad] En array med det angivna XMLNode-objektets underordnade noder.	XMLNode
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		docTypeDecl : Object = null Anger information om XML-dokumentets DOCTYPE-deklaration.	XMLDocument
		firstChild : XMLNode Utvärderar det angivna XMLDocumen-objektet och refererar till den första noden i den överordnade nodens lista över underordnade noder.	XMLNode
		idMap : Object Ett objekt som innehåller noderna i XML-koden som har ett ID-attribut tilldelat.	XMLDocument
		ignoreWhite : Boolean = false När egenskapen är inställd på true tolkas inte textnoder som bara innehåller tomrum.	XMLDocument
		lastChild : XMLNode Ett XMLNode-värde som refererar till den sista noden i nodens lista över underordnade noder.	XMLNode
		localName : String [skrivskyddad] Den lokala delen av XML-nodens namn.	XMLNode
		namespaceURI : String [skrivskyddad] Om XML-noden har ett prefix är namespaceURI värdet för xmlns-deklarationen för prefixet (URI) som vanligen kallas namnutrymmes-URI.	XMLNode
		nextSibling : XMLNode Ett XMLNode-värde som refererar till nästa jämställda nod i den överordnade nodens lista över underordnade noder.	XMLNode
		nodeName : String En sträng som returnerar XMLNode-objektets nodnamn.	XMLNode
		nodeType : uint Ett nodeType-konstantvärde, antingen XMLNodeType.ELEMENT_NODE för ett XML-element eller XMLNodeType.TEXT_NODE för en textnod.	XMLNode
		nodeValue : String XMLDocument-objektets nodvärde.	XMLNode
		parentNode : XMLNode Ett XMLNode-värde som refererar till den överordnade noden i det angivna XML-objektet, eller returnerar null om noden inte har någon överordnad nod.	XMLNode
		prefix : String [skrivskyddad] Prefixdelen av XML-nodens namn.	XMLNode
		previousSibling : XMLNode Ett XMLNode-värde som refererar till föregående jämställda nod i den överordnade nodens lista över underordnade noder.	XMLNode
		xmlDecl : Object = null En sträng som anger information om ett dokuments XML-deklaration.	XMLDocument

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		XMLDocument(source:String = null) Skapar ett nytt XMLDocument-objekt.	XMLDocument
		appendChild(node:XMLNode):void Lägger till den angivna noden i XML-objektets lista över underordnade noder.	XMLNode
		cloneNode(deep:Boolean):XMLNode Konstruerar och returnerar en ny XML-nod av samma typ och med samma namn, värde och attribut som det angivna XML-objektet.	XMLNode
		createElement(name:String):XMLNode Skapar ett nytt XMLNode-objekt med det namn som anges i parametern.	XMLDocument
		createTextNode(text:String):XMLNode Skapar en ny XML-textnod med den angivna texten.	XMLDocument
		getNamespaceForPrefix(prefix:String):String Returnerar den namnutrymmes-URI som är associerad med det angivna prefixet för noden.	XMLNode
		getPrefixForNamespace(ns:String):String Returnerar det prefix som är associerat med den angivna namnutrymmes-URI:n för noden.	XMLNode
		hasChildNodes():Boolean Anger om det angivna XML-objektet har underordnade noder.	XMLNode
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		insertBefore(node:XMLNode, before:XMLNode):void Infogar en ny underordnad nod i XML-objektets lista över underordnade noder, före noden beforeNode.	XMLNode
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		parseXML(source:String):void Tolkar XML-texten som anges i parametern value och fyller i det angivna XMLDocument-objektet med det resulterande XML-trädet.	XMLDocument
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		removeNode():void Tar bort det angivna XML-objektet från dess överordnade nod.	XMLNode
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String [åsidosätt] Returnerar XML-objektets strängbeteckning.	XMLDocument
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object

Egenskapsdetaljer

docTypeDecl

egenskap

public var docTypeDecl:Object = null

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Anger information om XML-dokumentets DOCTYPE-deklaration. Om XML-texten har tolkats till ett XML-objekt, ställs egenskapen XMLDocument.docTypeDecl i XML-objektet in på texten i XML-dokumentets DOCTYPE-deklaration (till exempel <!DOCTYPE greeting SYSTEM "hello.dtd">). Den här egenskapen ställs in med en strängbeteckning för DOCTYPE-deklarationen, inte ett XMLNode-objekt.

ActionScript XML Parser är inte validerande. DOCTYPE-deklarationen läses av parsern och lagras i egenskapen XMLDocument.docTypeDecl, men ingen Dtd-validering görs.

Om ingen DOCTYPE-deklaration påträffas under en tolkningsåtgärd ställs egenskapen XMLDocument.docTypeDecl in på null. Metoden XML.toString() visar innehållet i XML.docTypeDecl omedelbart efter att XML-deklarationen lagras i XML.xmlDecl och före all annan text i XML-objektet. Om XMLDocument.docTypeDecl är null matas ingen DOCTYPE-deklaration ut.

idMap

egenskap

public var idMap:Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Ett objekt som innehåller noderna i XML-koden som har ett id-attribut tilldelat. Namnen på objektets egenskaper (som var och en innehåller en nod) matchar värdena för id-attributen.

Se följande XMLDocument-objekt:

     <employee id='41'>
         <name>
             John Doe
         </name>
         <address>
             601 Townsend St.
         </address>
     </employee>
     
     <employee id='42'>
         <name>
             Jane Q. Public
         </name>
     </employee>
     <department id="IT">
         Information Technology
     </department>

I det här exemplet är idMap-egenskapen i XMLDocument-objektet ett objekt med tre egenskaper: 41, 42 och IT. Var och en av dessa egenskaper är en XMLNode som har det matchande id-värdet. IT-egenskapen i idMap-objektet är till exempel den här noden:

     <department id="IT">
         Information Technology
     </department>

Du måste använda metoden parseXML() i XMLDocument-objektet för att idMap-egenskapen ska instansieras.

Om det finns mer än en XMLNode med samma id-värde är den matchande egenskapen i idNode-objektet den för den senast tolkade noden. Till exempel:

     var x1:XML = new XMLDocument("<a id='1'><b id='2' /><c id='1' /></a>");
     x2 = new XMLDocument();
     x2.parseXML(x1);
     trace(x2.idMap['1']);

Följande ger noden <c>:

     <c id='1' />

ignoreWhite

egenskap

public var ignoreWhite:Boolean = false

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

När egenskapen är inställd på true tolkas inte textnoder som bara innehåller tomrum. Textnoder med inledande eller avslutande tomrum påverkas inte. Standardinställningen är false.

Du kan ställa in egenskapen ignoreWhite för enskilda XMLDocument-objekt, liksom i följande kod:

     my_xml.ignoreWhite = true;

xmlDecl

egenskap

public var xmlDecl:Object = null

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

En sträng som anger information om ett dokuments XML-deklaration. Efter att XML-dokumentet tolkas till ett XMLDocument-objekt ställs egenskapen in till texten i dokumentets XML-deklaration. Den här egenskapen ställs in med en strängbeteckning för XML-deklarationen, inte ett XMLNode-objekt. Om ingen XML-deklaration påträffas under en tolkningsåtgärd ställs egenskapen in på null. Metoden XMLDocument.toString() returnerar innehållet i egenskapen XML.xmlDecl före all annan text i XML-objektet. Om egenskapen XML.xmlDecl innehåller null returneras ingen XML-deklaration.

Konstruktordetaljer

()

Konstruktor

public function XMLDocument(source:String = null)

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Skapar ett nytt XMLDocument-objekt. Du måste använda konstruktorn för att skapa ett XMLDocument-objekt innan du kan anropa metoderna i klassen XMLDocument.

Obs: Använd metoderna createElement() och createTextNode() för att lägga till element och textnoder i ett XML-dokumentträd.

Parametrar

source:String (default = null) — XML-texten som tolkas för att skapa det nya XMLDocument-objektet.

Relaterade API-element

XMLDocument.createElement()
XMLDocument.createTextNode()

Metoddetaljer

createElement

()

metod

public function createElement(name:String):XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Skapar ett nytt XMLNode-objekt med det namn som anges i parametern. Den nya noden har från början inga överordnade, underordnade eller jämställda element. Metoden returnerar en referens till det nyskapade XMLNode-objektet som representerar elementet. Den här metoden och metoden XMLDocument.createTextNode() är de konstruktormetoder som används för att skapa noder för ett XMLDocument-objekt.

Parametrar

name:String — Taggnamnet för XMLDocument-elementet som skapas.

Returnerar

XMLNode — Ett XMLNode-objekt.

Relaterade API-element

XMLDocument.createTextNode()

createTextNode

()

metod

public function createTextNode(text:String):XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Skapar en ny XML-textnod med den angivna texten. Den nya noden har från början ingen överordnad nod, och textnoder kan inte ha underordnade eller jämställda noder. Metoden returnerar en referens till XMLDocument-objektet som representerar den nya textnoden. Den här metoden och metoden XMLDocument.createElement() är de konstruktormetoder som används för att skapa noder för ett XMLDocument-objekt.

Parametrar

text:String — Den text som användes för att skapa den nya textnoden.

Returnerar

XMLNode — Ett XMLNode-objekt.

Relaterade API-element

XMLDocument.createElement()

parseXML

()

metod

public function parseXML(source:String):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Tolkar XML-texten som anges i parametern value och fyller i det angivna XMLDocument-objektet med det resulterande XML-trädet. Alla befintliga träd i XMLDocument-objektet kasseras.

Parametrar

source:String — XML-texten som ska tolkas och skickas till det angivna XMLDocumen-objektet.

toString

()

metod

override public function toString():String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Returnerar XML-objektets strängbeteckning.

Returnerar

String — En strängbeteckning på XML-objektet.

Exempel Så här använder du exemplet

XMLDocumentExample.as

I följande exempel används XMLDocument- och XMLNode-klasserna för att tolka och formatera ett XML-dokument. I stället för att läsa in en extern XML-fil används den översta nivån för XML-klassen i exemplet för att skapa ett XML-dokument. Sedan utförs en analys.

package {
    import flash.display.Sprite;
    import flash.xml.XMLDocument;
    import flash.xml.XMLNode;
    import flash.xml.XMLNodeType;

    public class XMLDocumentExample extends Sprite {
        public function XMLDocumentExample() {
            var result:XMLDocument = new XMLDocument();
            result.ignoreWhite = true;
            result.parseXML(getXMLString());

            var books:Array = parseBooks(result.firstChild);
            trace("books: \n" + books);
        }

        private function parseBooks(node:XMLNode):Array {
            var books:Array = new Array();

            var kids:Array = node.childNodes;
            for each(var item:XMLNode in kids) {
                parseBook(item, books);
            }

            return books;
        }

        private function parseBook(node:XMLNode, books:Array):void {
            var item:Book = new Book();
            item.setPublisher(node.attributes.publisher);
            item.setName(node.attributes.name);
            books.push(item);
        }

        private function getXMLString():String {
            var list:XML = <books>
                                <book publisher="Addison-Wesley" name="Design Patterns" />
                                <book publisher="Addison-Wesley" name="The Pragmatic Programmer" />
                                <book publisher="Addison-Wesley" name="Test Driven Development" />
                                <book publisher="Addison-Wesley" name="Refactoring to Patterns" />
                                <book publisher="O'Reilly Media" name="The Cathedral & the Bazaar" />
                                <book publisher="O'Reilly Media" name="Unit Test Frameworks" />
                            </books>;
            return list.toXMLString();
        }
    }

}
class Book {
    private var publisher:String;
    private var name:String;

    public function setPublisher(publisher:String):void {
        this.publisher = publisher;
    }

    public function setName(name:String):void {
        this.name = name;
    }

    public function toString():String {
        return "[Book name: " + name + " publisher: " + publisher + "]\n";
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

XMLDocument - AS3

Paketx

Språkelement

Bilagor

Paket flash.xml

docTypeDecl

idMap

ignoreWhite

xmlDecl

XMLDocument

createElement

createTextNode

parseXML

toString