XMLNode

Paket	flash.xml
Klass	public class XMLNode
Arv	XMLNode Object
Underklasser	XMLDocument

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Klassen XMLDocument representerar det gamla XML-objektet som fanns i ActionScript 2.0 och fick ett nytt namn i ActionScript 3.0. I ActionScript 3.0 använder du den nya XML-klassen på översta nivån och relaterade klasser, som har stöd för E4X (ECMAScript for XML). XMLNode-klassen finns med för bakåtkompatibilitet.

Visa exemplen

Relaterade API-element

XML
flash.xml.XMLDocument

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		attributes : Object Ett objekt som innehåller alla attribut i den angivna XMLNode-instansen.	XMLNode
		childNodes : Array [skrivskyddad] En array med det angivna XMLNode-objektets underordnade noder.	XMLNode
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		firstChild : XMLNode Utvärderar det angivna XMLDocumen-objektet och refererar till den första noden i den överordnade nodens lista över underordnade noder.	XMLNode
		lastChild : XMLNode Ett XMLNode-värde som refererar till den sista noden i nodens lista över underordnade noder.	XMLNode
		localName : String [skrivskyddad] Den lokala delen av XML-nodens namn.	XMLNode
		namespaceURI : String [skrivskyddad] Om XML-noden har ett prefix är namespaceURI värdet för xmlns-deklarationen för prefixet (URI) som vanligen kallas namnutrymmes-URI.	XMLNode
		nextSibling : XMLNode Ett XMLNode-värde som refererar till nästa jämställda nod i den överordnade nodens lista över underordnade noder.	XMLNode
		nodeName : String En sträng som returnerar XMLNode-objektets nodnamn.	XMLNode
		nodeType : uint Ett nodeType-konstantvärde, antingen XMLNodeType.ELEMENT_NODE för ett XML-element eller XMLNodeType.TEXT_NODE för en textnod.	XMLNode
		nodeValue : String XMLDocument-objektets nodvärde.	XMLNode
		parentNode : XMLNode Ett XMLNode-värde som refererar till den överordnade noden i det angivna XML-objektet, eller returnerar null om noden inte har någon överordnad nod.	XMLNode
		prefix : String [skrivskyddad] Prefixdelen av XML-nodens namn.	XMLNode
		previousSibling : XMLNode Ett XMLNode-värde som refererar till föregående jämställda nod i den överordnade nodens lista över underordnade noder.	XMLNode

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		XMLNode(type:uint, value:String) Skapar ett nytt XMLNode-objekt.	XMLNode
		appendChild(node:XMLNode):void Lägger till den angivna noden i XML-objektets lista över underordnade noder.	XMLNode
		cloneNode(deep:Boolean):XMLNode Konstruerar och returnerar en ny XML-nod av samma typ och med samma namn, värde och attribut som det angivna XML-objektet.	XMLNode
		getNamespaceForPrefix(prefix:String):String Returnerar den namnutrymmes-URI som är associerad med det angivna prefixet för noden.	XMLNode
		getPrefixForNamespace(ns:String):String Returnerar det prefix som är associerat med den angivna namnutrymmes-URI:n för noden.	XMLNode
		hasChildNodes():Boolean Anger om det angivna XML-objektet har underordnade noder.	XMLNode
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		insertBefore(node:XMLNode, before:XMLNode):void Infogar en ny underordnad nod i XML-objektets lista över underordnade noder, före noden beforeNode.	XMLNode
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		removeNode():void Tar bort det angivna XML-objektet från dess överordnade nod.	XMLNode
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Utvärderar det angivna XMLNode-objektet, konstruerar en textbeteckning för XML-strukturen inklusive noden, underordnade noder och attribut, och returnerar resultatet som en sträng.	XMLNode
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object

Egenskapsdetaljer

attributes

egenskap

attributes:Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Ett objekt som innehåller alla attribut i den angivna XMLNode-instansen. Objektet XMLNode.attributes innehåller en variabel för varje attribut i XMLNode-instansen. Eftersom dessa variabler definieras som en del av objektet, refereras de oftast som egenskaper för objektet. Värdet för varje attribut lagras i motsvarande egenskap som en sträng. Om du till exempel har ett attribut som heter color, hämtar du attributets värde genom att ange color som egenskapsnamn, liksom i följande kod:

	 var myColor:String = doc.firstChild.attributes.color

Implementering
public function get attributes():Object
public function set attributes(value:Object):void

childNodes

egenskap

childNodes:Array [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

En array med det angivna XMLNode-objektets underordnade noder. Varje element i arrayen är en referens till ett XMLNode-objekt som representerar en underordnad nod. Det här är en skrivskyddad egenskap som inte kan användas för att hantera underordnade noder. Använd metoderna appendChild(), insertBefore() och removeNode() för att hantera underordnade noder.

Egenskapen är odefinierad för textnoder (nodeType == 3).

Implementering
public function get childNodes():Array

Relaterade API-element

XMLNode.nodeType
XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

firstChild

egenskap

public var firstChild:XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Utvärderar det angivna XMLDocumen-objektet och refererar till den första noden i den överordnade nodens lista över underordnade noder. Egenskapen är null om noden inte har några underordnade noder. Egenskapen är undefined om noden är en textnod. Det här är en skrivskyddad egenskap som inte kan användas för att hantera underordnade noder. Använd metoderna appendChild(), insertBefore() och removeNode() för att hantera underordnade noder.

Relaterade API-element

XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

lastChild

egenskap

public var lastChild:XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Ett XMLNode-värde som refererar till den sista noden i nodens lista över underordnade noder. Egenskapen XMLNode.lastChild är null om noden inte har några underordnade noder. Den här egenskapen kan inte användas för att hantera underordnade noder. Använd metoderna appendChild(), insertBefore() och removeNode() för att hantera underordnade noder.

Relaterade API-element

XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

localName

egenskap

localName:String [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Den lokala delen av XML-nodens namn. Det är elementnamnet utan namnutrymmesprefixet. Noden <contact:mailbox/>bob@example.com</contact:mailbox> har till exempel det lokala namnet "mailbox" och prefixet "contact" som utgör det fullständiga elementnamnet "contact.mailbox".

Du kan komma åt namnutrymmesprefixet via egenskapen prefix i XMLNode-objektet. Egenskapen nodeName returnerar det fullständiga namnet (inklusive prefix och lokalt namn).

Implementering
public function get localName():String

namespaceURI

egenskap

namespaceURI:String [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Om XML-noden har ett prefix är namespaceURI värdet för xmlns-deklarationen för prefixet (URI) som vanligen kallas namnutrymmes-URI. xmlns-deklarationen är i den aktuella noden eller i en högre nod i XML-hierarkin.

Om XML-noden inte har ett prefix beror värdet för egenskapen namespaceURI på om det finns ett standardnamnutrymme definierat (som i xmlns="http://www.example.com/"). Om det finns ett standardnamnutrymme är värdet för egenskapen namespaceURI värdet för standardnamnutrymmet. Om det inte finns något standardnamnutrymme är namespaceURI-egenskapen för den noden en tom sträng ("").

Du kan använda metoden getNamespaceForPrefix() för att identifiera det namnutrymme som är associerat med ett viss prefix. Egenskapen namespaceURI returnerar det prefix som är associerat nodnamnet.

Implementering
public function get namespaceURI():String

Relaterade API-element

getNamespaceForPrefix()
getPrefixForNamespace()

nextSibling

egenskap

public var nextSibling:XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Ett XMLNode-värde som refererar till nästa jämställda nod i den överordnade nodens lista över underordnade noder. Egenskapen är null om noden inte har någon nästa jämställda nod. Den här egenskapen kan inte användas för att hantera underordnade noder. Använd metoderna appendChild(), insertBefore() och removeNode() för att hantera underordnade noder.

Relaterade API-element

XMLNode.firstChild
XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

nodeName

egenskap

public var nodeName:String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

En sträng som returnerar XMLNode-objektets nodnamn. Om XMLNode-objektet är ett XML-element (nodeType == 1) är nodeName namnet på den tagg som representerar noden i XML-filen. TITLE är till exempel nodeName för en HTML TITLE-tagg. Om XMLNode-objektet är en textnod (nodeType == 3) är nodeName null.

Relaterade API-element

XMLNode.nodeType

nodeType

egenskap

public var nodeType:uint

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Ett nodeType-konstantvärde, antingen XMLNodeType.ELEMENT_NODE för ett XML-element eller XMLNodeType.TEXT_NODE för en textnod.

nodeType är ett numeriskt värde från NodeType-numreringen i W3C DOM Level 1-rekommendationen: http://www.w3.org/TR/1998/REC-DOM-Level-1-19981001/level-one-core.html. Värdena listas i följande tabell:

Heltalsvärde	Definierad konstant
1	ELEMENT_NODE
3	TEXT_NODE
5	ENTITY_REFERENCE_NODE
7	PROCESSING_INSTRUCTION_NODE
9	DOCUMENT_NODE
11	DOCUMENT_FRAGMENT_NODE

I Flash Player har den inbyggda klassen XMLNode bara stöd för XMLNodeType.ELEMENT_NODE och XMLNodeType.TEXT_NODE.

Relaterade API-element

XMLNodeType.TEXT_NODE
XMLNodeType.ELEMENT_NODE

nodeValue

egenskap

public var nodeValue:String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

XMLDocument-objektets nodvärde. Om XMLDocument-objektet är en textnod är nodeType 3 och nodeValue är nodens text. Om XMLDocument-objektet är ett XML-element (nodeType är 1) är nodeValue null och skrivskyddat.

Relaterade API-element

XMLNode.nodeType

parentNode

egenskap

public var parentNode:XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Ett XMLNode-värde som refererar till den överordnade noden i det angivna XML-objektet, eller returnerar null om noden inte har någon överordnad nod. Det här är en skrivskyddad egenskap som inte kan användas för att hantera underordnade noder. Använd metoderna appendChild(), insertBefore() och removeNode() för att hantera underordnade noder.

Relaterade API-element

XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

prefix

egenskap

prefix:String [skrivskyddad]

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Prefixdelen av XML-nodens namn. Noden <contact:mailbox/>bob@example.com</contact:mailbox> har till exempel det lokala namnet "mailbox" och prefixet "contact" som utgör det fullständiga elementnamnet "contact.mailbox".

Egenskapen nodeName i ett XMLNode-objekt returnerar det fullständiga namnet (inklusive prefix och lokalt namn). Du kan använda den lokala delen av elementets namn med egenskapen localName.

Implementering
public function get prefix():String

previousSibling

egenskap

public var previousSibling:XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Ett XMLNode-värde som refererar till föregående jämställda nod i den överordnade nodens lista över underordnade noder. Egenskapen har värdet null om noden inte har någon föregående jämställda nod. Den här egenskapen kan inte användas för att hantera underordnade noder. Använd metoderna appendChild(), insertBefore() och removeNode() för att hantera underordnade noder.

Relaterade API-element

XMLNode.lastChild
XMLNode.appendChild()
XMLNode.insertBefore()
XMLNode.removeNode()

Konstruktordetaljer

()

Konstruktor

public function XMLNode(type:uint, value:String)

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Skapar ett nytt XMLNode-objekt. Du måste använda konstruktorn för att skapa ett XMLNode-objekt innan du kan anropa metoderna i klassen XML.

Obs: Använd metoderna createElement() och createTextNode() för att lägga till element och textnoder i ett XML-dokumentträd.

Parametrar

	`type:uint` — Nodtypen: antingen 1 för ett XML-element eller 3 för en textnod.

	`value:String` — XML-texten som tolkas för att skapa det nya XMLNode-objektet.

Relaterade API-element

XMLDocument.createElement()
XMLDocument.createTextNode()

Metoddetaljer

appendChild

()

metod

public function appendChild(node:XMLNode):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Lägger till den angivna noden i XML-objektets lista över underordnade noder. Den här metoden verkar direkt på den nod som refereras av parametern childNode. Den lägger inte till någon kopia av noden. Om noden som ska läggas till redan finns i en annan trädstruktur, tas den bort från sin befintliga plats om den läggs till på en ny plats. Om parametern childNode refererar till en nod som redan finns i en annan XML-trädstruktur, placeras den tillagda underordnade noden till i den nya trädstrukturen efter att den tagits bort från sin nuvarande överordnade nod.

Parametrar

node:XMLNode — En XMLNode som representerar den nod som ska flyttas från sin nuvarande plats till listan med underordnade noder i my_xml-objektet.

cloneNode

()

metod

public function cloneNode(deep:Boolean):XMLNode

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Konstruerar och returnerar en ny XML-nod av samma typ och med samma namn, värde och attribut som det angivna XML-objektet. Om deep är inställd på true klonas alla underordnade noder rekursivt, vilket ger en exakt kopia av det ursprungliga objektets dokumentträd.

Klonen av noden som returneras är inte längre associerad med det klonade objektets träd. Därför har nextSibling, parentNode och previousSibling alla värdet null. Om parametern deep är inställd på false eller om noden my_xml inte har några underordnade noder är firstChild och lastChild också null.

Parametrar

deep:Boolean — Ett booleskt värde. Om det är inställt på true kommer det angivna XML-objektets underordnade noder att klonas rekursivt.

Returnerar

XMLNode — Ett XMLNode-objekt.

getNamespaceForPrefix

()

metod

public function getNamespaceForPrefix(prefix:String):String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Returnerar den namnutrymmes-URI som är associerad med det angivna prefixet för noden. getPrefixForNamespace() avgör URI:n genom att söka uppåt i XML-hierarkin från noden. Namnutrymmes-URI:n för den första xmlns-deklarationen som hittas för givet prefix returneras.

Om inget namnutrymme är definierat för angivet prefix returnerar metoden null.

Om du anger en tom sträng ("") som prefix och det finns ett standardnamnutrymme definierat för noden (som i xmlns="http://www.example.com/") returnerar metoden standardnamnutrymmes-URI:n.

Parametrar

prefix:String — Det prefix som metoden returnerar associerat namnutrymme för.

Returnerar

String — Det namnutrymme som är associerat med det angivna prefixet.

Relaterade API-element

XMLNode.getPrefixForNamespace()
XMLNode.namespaceURI

getPrefixForNamespace

()

metod

public function getPrefixForNamespace(ns:String):String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Returnerar det prefix som är associerat med den angivna namnutrymmes-URI:n för noden. getPrefixForNamespace() avgör prefixet genom att söka uppåt i XML-hierarkin från noden. Prefixet för den första xmlns-deklarationen med en namnutrymmes-URI som matchar ns returneras.

Om det inte finns någon xmlns-tilldelning för den givna URI:n returnerar metoden null. Om det finns en xmlns-tilldelning för den givna URI:n men inget prefix är associerat till tilldelningen, returnerar metoden en tom sträng ("").

Parametrar

ns:String — Den namnutrymmes-URI som metoden returnerar associerat prefix för.

Returnerar

String — Det prefix som är associerat med det angivna namnutrymmet.

Relaterade API-element

XMLNode.getNamespaceForPrefix()
XMLNode.namespaceURI

hasChildNodes

()

metod

public function hasChildNodes():Boolean

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Anger om det angivna XML-objektet har underordnade noder. Returnerar true om det angivna XMLNode-objektet har underordnade noder, annars returneras false.

Returnerar

Boolean — Returnerar true om det angivna XMLNode-objektet har underordnade noder, annars returneras false.

insertBefore

()

metod

public function insertBefore(node:XMLNode, before:XMLNode):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Infogar en ny underordnad nod i XML-objektets lista över underordnade noder, före noden beforeNode. Om beforeNode-parametern inte har definierats eller är null läggs noden till med appendChild()-metoden. Om beforeNode inte är underordnad my_xml misslyckas infogningen.

Parametrar

	`node:XMLNode` — XMLNode-objektet som ska infogas.

	`before:XMLNode` — XMLNode-objektet före insättningspunkten för `childNode`.

Relaterade API-element

XMLNode.cloneNode()

removeNode

()

metod

public function removeNode():void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Tar bort det angivna XML-objektet från dess överordnade nod. Alla noder som är underordnade noden tas också bort.

toString

()

metod

public function toString():String

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0, Flash Player 9, Flash Lite 4

Utvärderar det angivna XMLNode-objektet, konstruerar en textbeteckning för XML-strukturen inklusive noden, underordnade noder och attribut, och returnerar resultatet som en sträng.

För XMLDocument-objekt på högsta nivån (de som skapats med konstruktorn) returnerar metoden XMLDocument.toString() dokumentets XML-deklaration (lagras i egenskapen XMLDocument.xmlDecl), följd av dokumentets DOCTYPE-deklaration (lagras i egenskapen XMLDocument.docTypeDecl), följd av textbeteckningen för alla XML-noder i objektet. XML-deklarationen returneras inte om egenskapen XMLDocument.xmlDecl är null. DOCTYPE-deklarationen returneras inte om egenskapen XMLDocument.docTypeDecl är null.

Returnerar

String — Strängen representerar XMLNode-objektet.

Relaterade API-element

XMLDocument.docTypeDecl
XMLDocument.xmlDecl

Exempel Så här använder du exemplet

XMLDocumentExample.as

I följande exempel används XMLDocument- och XMLNode-klasserna för att tolka och formatera ett XML-dokument. I stället för att läsa in en extern XML-fil används den översta nivån för XML-klassen i exemplet för att skapa ett XML-dokument. Sedan utförs en analys.

package {
    import flash.display.Sprite;
    import flash.xml.XMLDocument;
    import flash.xml.XMLNode;
    import flash.xml.XMLNodeType;

    public class XMLDocumentExample extends Sprite {
        public function XMLDocumentExample() {
            var result:XMLDocument = new XMLDocument();
            result.ignoreWhite = true;
            result.parseXML(getXMLString());

            var books:Array = parseBooks(result.firstChild);
            trace("books: \n" + books);
        }

        private function parseBooks(node:XMLNode):Array {
            var books:Array = new Array();

            var kids:Array = node.childNodes;
            for each(var item:XMLNode in kids) {
                parseBook(item, books);
            }

            return books;
        }

        private function parseBook(node:XMLNode, books:Array):void {
            var item:Book = new Book();
            item.setPublisher(node.attributes.publisher);
            item.setName(node.attributes.name);
            books.push(item);
        }

        private function getXMLString():String {
            var list:XML = <books>
                                <book publisher="Addison-Wesley" name="Design Patterns" />
                                <book publisher="Addison-Wesley" name="The Pragmatic Programmer" />
                                <book publisher="Addison-Wesley" name="Test Driven Development" />
                                <book publisher="Addison-Wesley" name="Refactoring to Patterns" />
                                <book publisher="O'Reilly Media" name="The Cathedral & the Bazaar" />
                                <book publisher="O'Reilly Media" name="Unit Test Frameworks" />
                            </books>;
            return list.toXMLString();
        }
    }

}
class Book {
    private var publisher:String;
    private var name:String;

    public function setPublisher(publisher:String):void {
        this.publisher = publisher;
    }

    public function setName(name:String):void {
        this.name = name;
    }

    public function toString():String {
        return "[Book name: " + name + " publisher: " + publisher + "]\n";
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

XMLNode - AS3

Paketx

Språkelement

Bilagor

Paket flash.xml

attributes

childNodes

firstChild

lastChild

localName

namespaceURI

nextSibling

nodeName

nodeType

nodeValue

parentNode

prefix

previousSibling

XMLNode

appendChild

cloneNode

getNamespaceForPrefix

getPrefixForNamespace

hasChildNodes

insertBefore

removeNode

toString