DisplacementMapFilter  - AS3

Anger vilket alfagenomskinlighetsvärde som ska användas för objekt som flyttas utanför gränserna. Detta anges som ett normaliserat värde från 0,0 till 1,0. 0,25 innebär till exempel att genomskinlighetsvärdet är 25 %. Standardvärdet är 0. Använd den här egenskapen om mode är inställt på DisplacementMapFilterMode.COLOR.

Anger vilken färg som ska användas för objekt som flyttas utanför gränserna. Det giltiga intervallet för förskjutningar är 0,0 till 1,0. Värdena är i hexadecimalt format. Standardvärdet för color är 0. Använd den här egenskapen om mode är inställt på DisplacementMapFilterMode.COLOR.

Beskriver vilken färgkanal som ska användas för att förskjuta x-resultatet i mappningsbilden. Möjliga värden är BitmapDataChannel-konstanterna:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Relaterade API-element

Beskriver vilken färgkanal som ska användas för att förskjuta y-resultatet i mappningsbilden. Möjliga värden är BitmapDataChannel-konstanterna:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Relaterade API-element

Ett BitmapData-objekt som innehåller schemadata för förskjutningen.

Relaterade API-element

Ett värde som innehåller förskjutningen för det övre vänstra hörnet av målvisningsobjektet från det övre vänstra hörnet av mappningsbilden.

Relaterade API-element

Filtrets läge. Möjliga värden är DisplacementMapFilterMode-konstanterna:

• DisplacementMapFilterMode.WRAP – flyttar över förskjutningsvärdet till andra sidan av källbilden.
• DisplacementMapFilterMode.CLAMP – klämmer ihop förskjutningsvärdet till källbildens kant.
• DisplacementMapFilterMode.IGNORE – ignorerar förskjutningen och använder källpixeln om förskjutningsvärdet är utanför området.
• DisplacementMapFilterMode.COLOR – om förskjutningsvärdet är utanför bilden ersätts värdena i color- och alpha-egenskaperna.

Relaterade API-element

Multiplikatorn som används för att skala x-förskjutningsresultatet från mappningsberäkningen.

Multiplikatorn som används för att skala y-förskjutningsresultatet från mappningsberäkningen.

Initierar en ny DisplacementMapFilter-instans med de angivna parametrarna.

Relaterade API-element

Returnerar en kopia av det här filterobjektet.

1. Klassen definierar variabler för bakgrundsfärgen, för textfältetiketten och för den storlek och förskjutning som ska användas i olika funktioner.
2. Konstruktorfunktionen anropar draw()-metoden som använder metoderna för Graphics-klassen för att rita en fyrkant med en radiell övertoningsfyllning. Observera att graphics är en egenskap i DisplacementMapFilterExample-objektet som utökar Sprite.
3. Konstruktorfunktionen anropar metoden createLabel() som skapar ett textfält som visar värdet för labelText och lägger till det i visningslistan.
4. Konstruktorfunktionen anropar metoden createFilter() som utför följande:
   • Skapar en variabel men namnet filter för filterobjektet.
   • Anropar metoden getDisplacementMapFilter() och kopplar det returnerade värdet till variabeln filter.
   • Skickar filter till filters-egenskapen i DisplacementFilterExample-objektet (huvudklassen).
5. Metoden getBitmapFilter() skapar ett BitmapData-objekt med namnet mapBitmap och kopplar det till resultatet av createBitmapData()-metoden. Objektet mapBitmap, tillsammans med andra variabler, definierar ett nytt förskjutningsfilter.
6. Metoden createBitmapData() skapar ett nytt BitmapData-objekt som baseras på det aktuella innehållet i DisplacementMapFilterExample-objektet. Det skapar en ny bitmapp baserat på bitmapData och lägger till bitmappsbilden i scenen.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}