Пакет flash.utils 

Отменяет указанный вызов метода setInterval().

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

Отменяет указанный вызов метода setTimeout().

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }
}

Создает объект XML, описывающий объект ActionScript, который именуется как параметр метода. В этом методе реализована концепция программирования отражение для языка ActionScript.

Если параметр value является экземпляром типа, возвращаемый объект XML содержит все свойства экземпляра, имеющие этот тип, но не содержит статических свойств. Это условие можно проверить при анализе объекта XML посредством исследования значения атрибута isStatic тега <type>, который содержит значение false, если параметр value является экземпляром типа.

Чтобы получить статические свойства типа, передайте для параметра value сам тип. Возвращаемый объект XML содержит не только статические свойства типа, но также все свойства его экземпляра. Свойства экземпляра вложены в тег под именем <factory>, что позволяет отличить их от статических свойств. В этом случае атрибут isStatic тега <type> содержит значение true.

Примечание. Если требуется только пройти по иерархии наследования объекта, а остальные сведения, предоставляемые функцией describeType() не требуются, вместо последней используйте функции getQualifiedClassName() и getQualifiedSuperclassName().

В следующей таблице описываются некоторые теги и атрибуты объекта XML, создаваемого методом describeType() (все возвращенные имена классов и интерфейсов имеют полностью определенный формат).

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.utils.describeType;
    
    public class DescribeTypeExample extends Sprite {
        public function DescribeTypeExample() {
            var child:Sprite = new Sprite();
            var description:XML = describeType(child);
            trace(description..accessor.@name.toXMLString());
        }
    }
}

Возвращает изолированную копию входной строки, зашифрованную с помощью UTF-8 или системной кодовой страницы, в зависимости от значения System.useCodePage. Использование параметра System.useCodePage позволяет среде выполнения получать доступ к содержимому, использующему локальные кодировки, но только в системах, использующих такие кодировки. Например, данные на японском языке, закодированные как Shift-JIS, будут правильно преобразованы только в операционной системе, в которой по умолчанию используется японская кодировка.

Параметры

Возвращает ссылку на объект класса, заданного параметром name.

Параметры

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class GetDefinitionByNameExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint = 80;

        public function GetDefinitionByNameExample() {
            var ClassReference:Class = getDefinitionByName("flash.display.Sprite") as Class;
            var instance:Object = new ClassReference();
            instance.graphics.beginFill(bgColor);
            instance.graphics.drawRect(0, 0, size, size);
            instance.graphics.endFill();
            addChild(DisplayObject(instance));
        }
    }
}

Возвращает полное имя класса для объекта.

Параметры

Связанные элементы API

Возвращает полное имя класса для базового класса объекта, заданного параметром value. Эта функция обеспечивает более быстрый способ получения имени базового класса по сравнению с describeType(), но она не предоставляет сведения, которые передает функция describeType().

После получения имени класса с помощью этой функции имя класса можно преобразовать с помощью функции getDefinitionByName() в ссылку на класс.

Примечание. Эта функция ограничивается иерархиями экземпляра, а функция describeType() использует иерархии объекта класса, если параметр value является типом данных. Вызов функции describeType() по отношению к типу данных возвращает суперкласс на основе иерархии объекта класса, в которой все объекты класса унаследованы из класса Class. При этом функция getQualifiedSuperclassName() игнорирует иерархию объекта класса и возвращает суперкласс на основе более привычной иерархии экземпляра. Например, при вызове getQualifiedSuperclassName(String) возвращается Object, хотя технически объект класса String наследуется из класса Class. Другими словами, результаты совпадают независимо от использования экземпляра типа или самого типа.

Параметры

Связанные элементы API

Используется для вычисления относительного времени. Когда среда выполнения Flash обрабатывает ActionScript 3.0, этот метод возвращает число миллисекунд, прошедшее с момента запуска виртуальной машины среды выполнения Flash для ActionScript 3.0 (AVM2). Когда среда выполнения Flash обрабатывает ActionScript 2.0, этот метод возвращает число миллисекунд, прошедшее с момента инициализации среды выполнения Flash. Среды выполнения Flash использует две виртуальных машины для обработки ActionScript. AVM1 — это виртуальная машина ActionScript, используем для обработки ActionScript 1.0 и 2.0. AVM2 — это виртуальная машина ActionScript, используемая для обработки ActionScript 3.0. Метод getTimer() ведет себя по-разному для AVM1 и AVM2.

Дату календаря (метку времени) см. в объекте Date.

Связанные элементы API

package {
    import flash.utils.getTimer;
    import flash.display.Sprite;

    public class GetTimerExample extends Sprite {
        public function GetTimerExample() {
            var duration:uint = getTimer();
            trace("duration: " + duration);
        }
    }
}

Выполняет функцию с заданным интервалом (в миллисекундах).

Вместо использования метода setInterval() рекомендуется создавать объект Timer с заданным интервалом, в котором в качестве параметра repeatCount используется значение 0 (то есть таймер выполняется бесконечно).

Если предполагается использование метода clearInterval() для отмены вызова setInterval(), метод setInterval() обязательно должен быть назначен переменной (к которой в последующем будет обращаться функция clearInterval()). Если не вызвать функцию clearInterval() для отмены вызова setInterval(), объект, содержащий функцию очистки заданного интервала, не будет удален.

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        
        public function SetIntervalExample() {
            var intervalId:uint = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Выполняет указанную функцию с определенной задержкой (в миллисекундах).

Вместо использования этого метода рекомендуется создавать объект Timer с указанным интервалом, в котором в качестве параметра repeatCount используется значение 1 (то есть таймер запускается один раз).

Если предполагается использование метода clearTimeout() для отмены вызова setTimeout(), метод setTimeout() обязательно должен быть присвоен переменной (к которой в последующем будет обращаться функция clearTimeout()). Если не вызвать функцию clearTimeout() для отмены вызова setTimeout(), объект, содержащий функцию очистки заданного интервала, не будет удален.

Параметры

Связанные элементы API

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        
        public function SetTimeoutExample() {
            var intervalId:uint = setTimeout(myDelayedFunction, delay, "Hello", "World");
        }

        public function myDelayedFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Возвращает неизолированную копию входной строки, расшифрованную из системной кодовой страницы или UTF-8, в зависимости от значения System.useCodePage. Использование параметра System.useCodePage позволяет среде выполнения получать доступ к содержимому, использующему локальные кодировки, но только в системах, использующих такие кодировки. Например, данные на японском языке, закодированные как Shift-JIS, будут правильно преобразованы только в операционной системе, в которой по умолчанию используется японская кодировка.

Параметры