Date  - AS3

День месяца по местному времени (целое число от 1 до 31), заданный объектом Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

День месяца (целое число от 1 до 31) по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

День недели по местному времени (0 — воскресенье, 1 — понедельник и т. д.), заданный объектом Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

День недели (0 – воскресенье, 1 – понедельник и т. д.) по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

Полный год (четырехзначное число, например 2000) объекта Date по местному времени. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

Четырехзначный год по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

Час дня по местному времени (целое число от 0 до 23) из объекта Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

Час дня (целое число от 0 до 23) по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

Число миллисекунд по местному времени (целое число от 0 до 999) из объекта Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

Число миллисекунд (целое число от 0 до 999) по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

Число минут по местному времени (целое число от 0 до 59) из объекта Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

Число минут (целое число от 0 до 59) по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

Месяц (0 — январь, 1 — февраль и т. д.) объекта Date по местному времени. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

Месяц (от 0 [январь] до 11 [декабрь]) по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

Число секунд по местному времени (целое число от 0 до 59) из объекта Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

Число секунд (целое число от 0 до 59) по всемирному скоординированному времени (UTC) из объекта Date.

Связанные элементы API

Число миллисекунд с полуночи 1 января 1970 года по всемирному скоординированному времени для объекта Date. Воспользуйтесь этим методом, чтобы представить определенный момент во времени при сравнении двух и более объектов Date.

Связанные элементы API

Разница в минутах между местным временем компьютера и временем по всемирному скоординированному времени (UTC). В частности, это значение представляет собой количество минут, которое необходимо добавить к местному времени компьютера, чтобы оно стало равно всемирному. Если время компьютера опережает UTC, значение будет отрицательным.

Связанные элементы API

Создает новый объект Date, который содержит заданную дату и время.

Конструктор Date() может иметь до 7 параметров (year, month, ..., millisecond), позволяющих указывать дату и время с точностью до миллисекунды. Дата, которую содержит только что созданный объект Date зависит от количества и типа данных переданных аргументов.

• Если аргументы не указываются, объекту Date присваивается текущие дата и время.
• Если передается один аргумент с типом данных Number, объекту Date присваивается временное значение, исходя из количества миллисекунд, прошедших с 0:00:000 1 января 1970 года (среднее время по Гринвичу) и указанных в этом единственном аргументе.
• Если передается один аргумент с типом данных String, и в этой строке есть действительная дата, объект Date содержит временное значение, основанное на этой дате.
• При передаче двух и большего числа аргументов объекту Date присваивается временное значение на основе переданных значений аргумента, которые относятся к году, месяцу, дате, часу, минуте, секунде и миллисекундам.

Если конструктору класса Date передается строка, дата может быть представлена в разных форматах, но должна включать, по крайней мере, месяц, дату и год. Например, Feb 1 2005 (1 февраля 2005 г.) – это действительное значение в отличие от Feb 2005 (февраль 2005 г.). В списке ниже приведены некоторые действительные форматы:

• «День Месяц Дата Часы:Минуты:Секунды GMT Год» (например, значение «Tue Feb 1 00:00:00 GMT-0800 2005», совпадающее со значением toString())
• «День Месяц Дата Год Часы:Минуты:Секунды AM/PM» (например, значение «Tue Feb 1 2005 12:00:00 AM», совпадающее со значением toLocaleString())
• «День Месяц Дата Год» (например, значение «Tue Feb 1 2005», совпадающее со значением toDateString())
• Месяц/День/Год (например, «02/01/2005»)
• Месяц/Год (например, «02/2005»)

Связанные элементы API

Возвращает день месяца по местному времени (целое число от 1 до 31), заданный объектом Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Связанные элементы API

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

Возвращает день недели по местному времени (0 — воскресенье, 1 — понедельник и т.д.), заданный объектом Date. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

Возвращает из объекта Date полный год по местному времени (четырехзначное число, например 2000). Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

Возвращает час (целое число от 0 до 23) дня, относящегося к объекту Date, по местному времени. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num as String;
}

Возвращает из объекта Date число миллисекунд по местному времени (целое число от 0 до 999). Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

var now:Date = new Date();
trace(now.getMilliseconds());

Возвращает из объекта Date число минут по местному времени (целое число от 0 до 59). Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

Возвращает из объекта Date месяц по местному времени (0 — январь, 1 — февраль и т.д.). Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

Возвращает из объекта Date число секунд по местному времени (целое число от 0 до 59). Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

var now:Date = new Date();
trace(now.getSeconds());

Возвращает для объекта Date число миллисекунд с полуночи 1 января 1970 года по всемирному скоординированному времени. Воспользуйтесь этим методом, чтобы представить определенный момент во времени при сравнении двух и более объектов Date.

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

 function addMonths(num:Number):void {
     currentMonth = currentMonth + num;
     if(currentMonth > 12) {
         currentYear++;
         currentMonth = currentMonth - 12;
     }
 }
 

Возвращает разницу в минутах между местным временем компьютера и всемирным скоординированным временем (UTC).

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

Возвращает из объекта Date день месяца (целое число от 1 до 31) по всемирному скоординированному времени (UTC).

Связанные элементы API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

Возвращает из объекта Date день недели (0 – воскресенье, 1 – понедельник и т. д.) по всемирному скоординированному времени (UTC).

Связанные элементы API

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

Возвращает из объекта Date четырехзначный год по всемирному скоординированному времени (UTC).

Связанные элементы API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

Возвращает из объекта Date час дня (целое число от 0 до 23) по всемирному скоординированному времени (UTC).

Связанные элементы API

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

Возвращает из объекта Date число миллисекунд (целое число от 0 до 999) по всемирному скоординированному времени (UTC).

var now:Date = new Date();
trace(now.getUTCMilliseconds());

Возвращает из объекта Date число минут (целое число от 0 до 59) по всемирному скоординированному времени (UTC).

var now:Date = new Date();
trace(now.getUTCMinutes());

Возвращает из объекта Date месяц (от 0 [январь] до 11 [декабрь]) по всемирному скоординированному времени (UTC).

Связанные элементы API

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

Возвращает из объекта Date число секунд (целое число от 0 до 59) по всемирному скоординированному времени (UTC).

var now:Date = new Date();
trace(now.getUTCSeconds());

Преобразует строку, представляющую дату, в число, равное количеству миллисекунд с полуночи 1 января 1970 года по Гринвичу (UTC).

Параметры

     Day Mon DD HH:MM:SS TZD YYYY
     

     Wed Apr 12 15:30:17 GMT-0700 2006
     

     MM/DD/YYYY HH:MM:SS TZD
     HH:MM:SS TZD Day Mon/DD/YYYY 
     Mon DD YYYY HH:MM:SS TZD
     Day Mon DD HH:MM:SS TZD YYYY
     Day DD Mon HH:MM:SS TZD YYYY
     Mon/DD/YYYY HH:MM:SS TZD
     YYYY/MM/DD HH:MM:SS TZD
     

Связанные элементы API

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

Задает день месяца по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Параметры

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

Задает год по местному времени и возвращает новое время в миллисекундах. Если указаны параметры month и day, им присваивается местное время. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Вызов этого метода не приводит к изменению других полей объекта Date, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

Связанные элементы API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

Задает час по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Параметры

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

Задает количество миллисекунд по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Параметры

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

Задает количество минут по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Параметры

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

Задает месяц и (при необходимости) день месяца по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Параметры

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

Задает количество секунд по местному времени и возвращает новое время в миллисекундах. Местное время определяется операционной системой, в которой запущена среда выполнения Flash.

Параметры

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

Задает дату в миллисекундах с полуночи 1 января 1970 года и возвращает новое время в миллисекундах.

Параметры

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

Задает день месяца по Гринвичу (UTC) и возвращает новое время в миллисекундах. Вызов этого метода не приводит к изменению других полей объекта Date, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

Связанные элементы API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

Задает год по Гринвичу (UTC) и возвращает новое время в миллисекундах.

При желании этот метод может установить также месяц и день месяца. Вызов этого метода не приводит к изменению других полей, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

Связанные элементы API

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

Задает час по Гринвичу (UTC) и возвращает новое время в миллисекундах. При желании можно также указать минуты, секунды и миллисекунды.

Параметры

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

Задает количество миллисекунд по Гринвичу (UTC) и возвращает новое время в миллисекундах.

Параметры

var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

Задает количество минут по Гринвичу (UTC) и возвращает новое время в миллисекундах. При желании можно указать секунды и миллисекунды.

Параметры

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

Задает месяц и (при необходимости) день месяца по Гринвичу (UTC) и возвращает новое время в миллисекундах. Вызов этого метода не приводит к изменению других полей, но методы Date.getUTCDay() и Date.getDay() могут указывать новое значение, если день недели изменяется в результате вызова этого метода.

Параметры

Связанные элементы API

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

Задает количество секунд и (при необходимости) миллисекунд по Гринвичу (UTC) и возвращает новое время в миллисекундах.

Параметры

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

Возвращает строковое представление дня и даты без времени или часового пояса. Сравните это с указанными ниже методами.

• Date.toTimeString(), который возвращает только время и часовой пояс.
• Date.toString(), который возвращает не только день и дату, но также время и часовой пояс.

Связанные элементы API

var now:Date = new Date();
trace(now);
trace(now.toDateString());

Предоставляет переопределяемый метод, позволяющий настраивать кодировку JSON значений в объекте Date.

Метод JSON.stringify() ищет метод toJSON() в каждом объекте, который он проходит. В случае обнаружения toJSON() метод JSON.stringify() вызывает его для каждого обнаруженного значения, передавая ключ, составляющий пару с этим значением.

Объект Date обеспечивает реализацию toJSON() по умолчанию, которая возвращает вывод метода Date.toString(). Если требуется экспортировать объекты Date в JSON в любом другом формате, можно настроить собственную реализацию. Для этого необходимо переопределить метод toJSON() в прототипе класса.

Метод toJSON() может возвращать значение любого типа. Если он возвращает объект, stringify() возвращается к этому объекту. Если toJSON() возвращает строку, stringify() не возвращается и продолжает прохождение.

Параметры

Связанные элементы API

Возвращает строковое представление дня и даты без времени или часового пояса. Этот метод возвращает то же значение, что и Date.toDateString. Сравните это с указанными ниже методами.

• Date.toTimeString(), который возвращает только время и часовой пояс.
• Date.toString(), который возвращает не только день и дату, но также время и часовой пояс.

Связанные элементы API

Возвращает строковое представление дня, даты и времени по местному времени. Сравните это с методом Date.toString(), возвращающим ту же информацию (а также часовой пояс), относящуюся к году, указанному в конце строки.

Возвращает строковое представление времени без дня, даты, года или часового пояса. Сравните это с методом Date.toTimeString(), который возвращает время и часовой пояс.

Связанные элементы API

Возвращает строковое представление дня, даты, времени и часового пояса. Формат выводимой даты:

     Day Mon Date HH:MM:SS TZD YYYY
     

Например:

     Wed Apr 12 15:30:17 GMT-0700 2006
     

var now:Date = new Date();
trace(now);

Возвращает строковое представление времени и часового пояса без дня и даты. Сравните это с методом Date.toDateString(), который возвращает только день и дату.

Связанные элементы API

Возвращает строковое представление дня, даты и времени по Гринвичу (UTC). Например, дата 1 февраля 2005 г. выглядит как Tue Feb 1 00:00:00 2005 UTC.

Связанные элементы API

Возвращает число миллисекунд от полуночи 1 января 1970 года по Гринвичу до момента, заданного параметрами. В этом методе используется всемирное скоординированное время, а в конструкторе Date – местное время.

Этот метод полезен, если требуется передать дату в формате всемирного скоординированного времени (UTC) конструктору класса Date. Поскольку конструктор класса данных Date поддерживает в качестве аргумента смещение в миллисекундах, можно воспользоваться методом Date.UTC(), чтобы преобразовать дату в формате UTC в соответствующее смещение, выраженное в миллисекундах, а затем отправить это смещение в качестве аргумента конструктору класса Date:

Параметры

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

Возвращает для объекта Date число миллисекунд с полуночи 1 января 1970 года по всемирному скоординированному времени.