Pacote flash.utils 

Cancela uma chamada setInterval() especificada.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        private var intervalId:uint;
        private var counter:uint     = 0;
        private var stopCount:uint     = 3;
        
        public function ClearIntervalExample() {
            intervalId = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);

            counter++;
            if(counter == stopCount) {
                trace("Clearing Interval");
                clearInterval(intervalId);    
            }
        }
    }
}

Cancela uma chamada setTimeout() especificada.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class ClearTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        private var intervalId:uint;
        private var count:uint = 1000000;
        
        public function ClearTimeoutExample() {
            intervalId = setTimeout(myDelayedFunction, delay);
            startCounting();
        }

        public function startCounting():void {
            var i:uint = 0;
            do {
                if(i == count-1) {
                    clearTimeout(intervalId);
                    trace("Your computer can count to " + count + " in less than " + delay/1000 + " seconds.");    
                }
                i++;
            } while(i < count)            
        }
        
        public function myDelayedFunction():void {
            trace("Time expired.");
        }
    }
}

Gera um objeto XML que descreve o objeto ActionScript nomeado como parâmetro do método. Este método implementa o conceito de programação de reflexão para a linguagem ActionScript.

Se o parâmetro value for uma ocorrência de um tipo, o objeto XML retornado inclui todas as propriedades de ocorrências desse tipo, mas não as propriedades estáticas. Você pode verificar essa condição quando analisar o objeto XML, com o exame do valor do atributo <type> isStatic da marca, que é false quando o parâmetro value for uma ocorrência de um tipo.

Para obter as propriedades estática de um tipo, transmita o próprio tipo como parâmetro value. O objeto XML retornado inclui tanto as propriedades estáticas do tipo como todas as suas propriedades de ocorrências. As propriedades de ocorrências estão aninhadas dentro de uma marca chamada <factory> para distingui-las das propriedades estáticas. Nesse caso, o atributo isStatic da marca <type> é true.

Observação:Se você precisar apenas cruzar a hierarquia de herança do objeto e não necessita das outras informações fornecidas pela describeType(), use em seu lugar as funções getQualifiedClassName() e getQualifiedSuperclassName().

A tabela a seguir descreve algumas tags e atributos do objeto XML gerado por describeType() (todos os nomes de classe e de interface retornados estão em formato totalmente qualificado):

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.describeType;
    
    public class DescribeTypeExample extends Sprite {
        public function DescribeTypeExample() {
            var child:Sprite = new Sprite();
            var description:XML = describeType(child);
            trace(description..accessor.@name.toXMLString());
        }
    }
}

Retorna uma cópia com escape da string de entrada codificada como UTF-8 ou página de códigos do sistema, dependendo do valor de System.useCodePage. O uso de System.useCodePage permite que o conteúdo criptografado nas páginas de código local seja acessado pelo player, mas apenas nos sistemas que usem a página de código preexistente. Por exemplo, os dados japoneses codificados como Shift-JIS terão escape ou não adequado apenas num OS que use a página de código japonês padrão.

Parâmetros

Retorna uma referência ao objeto de classe da classe especificada pelo parâmetro de name.

Parâmetros

package {
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class GetDefinitionByNameExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint = 80;

        public function GetDefinitionByNameExample() {
            var ClassReference:Class = getDefinitionByName("flash.display.Sprite") as Class;
            var instance:Object = new ClassReference();
            instance.graphics.beginFill(bgColor);
            instance.graphics.drawRect(0, 0, size, size);
            instance.graphics.endFill();
            addChild(DisplayObject(instance));
        }
    }
}

Retorna o nome de classe totalmente qualificado de um objeto.

Parâmetros

Elementos da API relacionados

Retorna o nome de classe totalmente qualificado da classe base do objeto especificado pelo parâmetro value. Esta função oferece uma forma mais rápida de recuperar o nome de classe de base do que o describeType(), mas também não apresenta todas as informações que o describeType() fornece.

Depois de você recuperar o nome de uma classe com esta função, poderá converter o nome da classe em uma referência de classe com a função getDefinitionByName().

Observação: Esta função se restringe a hierarquias de ocorrências, enquanto a função describeType() usa hierarquias de classes de objetos se o parâmetro value for um tipo de dado. Chamar describeType() em um tipo de dado retorna a superclasse com base na hierarquia de objeto de classe, na qual todos os objetos de classe são herdados da Classe. A função getQualifiedSuperclassName(), entretanto, ignora a hierarquia do objeto de classe e retorna a superclasse baseada na hierarquia de ocorrência mais familiar. Por exemplo, chamar getQualifiedSuperclassName(String) retorna Objeto embora tecnicamente o objeto de classe String seja herdado de Classe. Em outras palavras, os resultados são os mesmos, use você uma ocorrência de um tipo ou o próprio tipo.

Parâmetros

Elementos da API relacionados

Usado para computar a hora relativa. Para um tempo de execução de Flash que processa ActionScript 3.0, este método retorna o número de milissegundos passados desde a máquina virtual de tempo de execução de Flash de ActionScript 3.0 (AVM2) foi iniciado. Para um tempo de execução de Flash que processa ActionScript 2.0, este método retorna o número de milissegundos desde que o tempo de execução de Flash começou a inicialização. Os tempos de execução de Flash usam duas máquinas virtuais para processar ActionScript. AVM1 é a máquina virtual ActionScript usada para executar o ActionScript 1.0 e 2.0. AVM2 é a máquina virtual ActionScript usada para executar ActionScript 3.0. O comportamento do método getTimer() para uma AVM1 é diferente do comportamento para AVM2.

Para obter a data calendário (timestamp), consulte o objeto Data.

Elementos da API relacionados

package {
    import flash.utils.getTimer;
    import flash.display.Sprite;

    public class GetTimerExample extends Sprite {
        public function GetTimerExample() {
            var duration:uint = getTimer();
            trace("duration: " + duration);
        }
    }
}

Executa uma função em um intervalo especificado (em milissegundos).

Em vez de usar o método setInterval(), considere criar um objeto Timer, com o intervalo especificado, usando 0 com o parâmetro repeatCount (que configura o timer para repetir indefinidamente).

Se você pretende usar o método clearInterval() para cancelar a chamada setInterval(), certifique-se de atribuir a chamada setInterval() a uma variável (à qual o método clearInterval() fará referência posteriormente). Se você não chamar a função clearInterval() para cancelar a chamada setInterval(), o objeto que contém a função set timeout closure não terá coleta de lixo.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetIntervalExample extends Sprite {
        private var intervalDuration:Number = 1000; // duration between intervals, in milliseconds
        
        public function SetIntervalExample() {
            var intervalId:uint = setInterval(myRepeatingFunction, intervalDuration, "Hello", "World");
        }

        public function myRepeatingFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Executa uma função especificada após um atraso especificado (em milissegundos).

Em vez de usar este método, considere criar um objeto Timer, com o intervalo especificado, usando 1 como o parâmetrorepeatCount (que configura o timer para rodar apenas uma vez).

Se você pretende usar o método clearTimeout() para cancelar a chamada setTimeout(), certifique-se de atribuir a chamada setTimeout() a uma variável (à qual a função setTimeout() fará referência posteriormente). Se você não chamar a função clearTimeout() para cancelar a chamada setTimeout(), o objeto que contém a função set timeout closure não terá coleta de lixo.

Parâmetros

Elementos da API relacionados

package {
    import flash.display.Sprite;
    import flash.utils.*;

    public class SetTimeoutExample extends Sprite {
        private var delay:Number = 1000; // delay before calling myDelayedFunction
        
        public function SetTimeoutExample() {
            var intervalId:uint = setTimeout(myDelayedFunction, delay, "Hello", "World");
        }

        public function myDelayedFunction():void {
            trace(arguments[0] + " " + arguments[1]);
        }
    }
}

Retorna uma cópia sem escape da string de entrada, que é decodificada da página de código do sistema ou de UTF-8, dependendo do valor de System.useCodePage. O uso de System.useCodePage permite que o conteúdo criptografado nas páginas de código local seja acessado pelo player, mas apenas nos sistemas que usem a página de código preexistente. Por exemplo, os dados japoneses codificados como Shift-JIS terão escape ou não adequado apenas num OS que use a página de código japonês padrão.

Parâmetros