WorkerDomain  - AS3

A instância WorkerDomain em que o código está sendo executado no momento. Este é o único WorkerDomain no aplicativo.

Indica se o contexto do runtime atual suporta os objetos WorkerDomain e Worker para execuções de código concorrentes.

Se a concorrência estiver disponível, o valor desta propriedade será true.

Cria uma nova instância Worker a partir dos bytes de um swf.

Cada worker é criado a partir de um aplicativo swf isolado e é executado nele. Para criar uma instância Worker, você obtém os bytes do arquivo SWF como uma instância ByteArray e a passa a este método. Há três formas comuns para acessar os bytes de um swf para esta finalidade:

• Utilize a metatag [Embed] para integrar o arquivo .swf ao aplicativo como um ByteArray.

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Carregue um arquivo SWF externo usando o URLLoader:

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• Utilize um único swf como o worker primário e de fundo:

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

A criação de um objeto Worker com o createWorker() não inicia a execução do worker. Para iniciar a execução de um código de Worker, execute uma chamada para o método start() do objeto Worker.

Workers são úteis pois diminuem as chances de diminuição da taxa de quadros devido ao fato de o thread de aplicação de acabamento ser bloqueado por outro código. Entretanto, workers requerem memória do sistema e uso do CPU adicionais, o que pode ser mais custoso ao desempenho geral do aplicativo. Como cada worker utiliza suas próprias instâncias da máquina virtual do runtime, até mesmo o overhead de um worker comum pode ser grande. Ao utilizar workers, teste seu código em todas as plataformas de destino para garantir que as demandas sobre o sistema não sejam tão grandes. A Adobe não recomenda a utilização de mais de um ou dois workers de fundo em um cenário típico.

Parâmetros

Fornece acesso ao conjunto de workers no WorkerDomain em execução no momento (a propriedade do estado da instância do Worker é WorkerState.RUNNING).