GradientGlowFilter  - AS3

Matriz de valores de transparência alfa para as cores correspondentes na matriz colors. Os valores válidos para cada elemento na matriz são 0 a 1. Por exemplo, ,25 define o valor de transparência para 25%.

A propriedade alphas não pode ser alterada ao modificar diretamente seus valores. Em vez disso, é necessário obter uma referência para alphas, fazer a alteração conforme a referência e então definir alphas para a referência.

As propriedades colors, alphas e ratios são relatadas. O primeiro elemento na matriz colors corresponde ao primeiro elemento na matriz alphas e na matriz ratios e assim por diante.

Elementos da API relacionados

Ângulo, em graus. Os valores válidos são 0 a 360. O padrão é 45.

O valor do ângulo representa o ângulo da origem da luz teórica que cai sobre o objeto e determina o posicionamento do efeito referente ao objeto. Se distance estiver definida como 0, o efeito não é deslocado a partir do objeto e, portanto, a propriedade angle não tem efeito.

Intensidade de desfoque horizontal. Os valores válidos são 0 a 255. Um desfoque de 1 ou menos significa que a imagem original é copiada como está. O valor padrão é 4. Os valores que são uma potência de 2 (como 2, 4, 8, 16 e 32) são otimizados para renderizar mais rapidamente do que outros valores.

Intensidade do desfoque vertical. Os valores válidos são 0 a 255. Um desfoque de 1 ou menos significa que a imagem original é copiada como está. O valor padrão é 4. Os valores que são uma potência de 2 (como 2, 4, 8, 16 e 32) são otimizados para renderizar mais rapidamente do que outros valores.

Matriz de cores que define um gradiente. Por exemplo, vermelho é 0xFF0000, azul é 0x0000FF e assim por diante.

A propriedade colors não pode ser alterada ao modificar diretamente seus valores. Em vez disso, é necessário obter uma referência para colors, fazer a alteração conforme a referência e então definir colors para a referência.

As propriedades colors, alphas e ratios são relatadas. O primeiro elemento na matriz colors corresponde ao primeiro elemento na matriz alphas e na matriz ratios e assim por diante.

Elementos da API relacionados

Distância de deslocamento do brilho. O valor padrão é 4.

Especifica se o objeto tem um efeito de tachado. Um efeito de tachado torna o preenchimento do objeto transparente e revela a cor do plano de fundo do documento. O valor true especifica um efeito de tachado; o valor padrão é false (sem efeito de tachado).

Número de vezes para aplicar o filtro. O valor padrão é BitmapFilterQuality.LOW, que é equivalente a aplicar o filtro uma vez. O valor BitmapFilterQuality.MEDIUM aplica o filtro duas vezes; o valor BitmapFilterQuality.HIGH aplica três vezes. Os filtros com valores menores são renderizados mais rapidamente.

Para a maioria dos aplicativos, um valor de quality baixo, médio ou alto é suficiente. Embora você possa usar valores numéricos adicionais até 15 para obter efeitos diferentes, os valores maiores são renderizados mais lentamente. Em vez de aumentar o valor de quality, você pode normalmente obter um efeito similar, com uma renderização mais rápida, simplesmente aumentando os valores das propriedades blurX e blurY.

Elementos da API relacionados

Matriz de proporções de distribuição de cores para as cores correspondentes na matriz colors. Os valores válidos são 0 a 255.

A propriedade ratios não pode ser alterada ao modificar diretamente seus valores. Em vez disso, é necessário obter uma referência para ratios, fazer a alteração conforme a referência e então definir ratios para a referência.

As propriedades colors, alphas e ratios são relatadas. O primeiro elemento na matriz colors corresponde ao primeiro elemento na matriz alphas e na matriz ratios e assim por diante.

Pense no filtro de brilho de gradiente como um brilho que emana do centro do objeto (se o valor de distance estiver definido como 0), com gradientes que são listras de mesclagem de cor umas nas outras. A primeira cor na matriz colors é a cor mais externa do brilho. A última cor é a cor mais interna do brilho.

Cada valor na matriz ratios define a posição da cor no raio do gradiente, em que 0 representa o ponto mais externo do gradiente e 255 representa seu ponto mais interno. Os valores da proporção podem variar de 0 a 255 pixels, em valor crescente; por exemplo [0, 64, 128, 200, 255]. Os valores de 0 a 128 aparecem nas bordas externas do brilho. Os valores de 129 a 255 aparecem nas bordas internas do brilho. Dependendo dos valores de proporção das cores e do valor de type do filtro, as cores do filtro podem ficar obscurecidas pelo objeto no qual o filtro é aplicado.

No código e imagem a seguir, um filtro é aplicado a um clipe de filme de círculo preto, com o tipo definido como "full". Para fins de instrução, a primeira cor na matriz colors, rosa, possui um valor alpha de 1, assim, ela é mostrada contra um plano de fundo branco do documento. (Na prática, você provavelmente não iria querer a primeira cor mostrada dessa maneira). A última cor na matriz, amarela, obscurece o círculo preto no qual o filtro é aplicado:

	var colors:Array = [0xFFCCFF, 0x0000FF, 0x9900FF, 0xFF0000, 0xFFFF00];
	var alphas:Array = [1, 1, 1, 1, 1];
	var ratios:Array = [0, 32, 64, 128, 225];
	var myGGF:GradientGlowFilter = new GradientGlowFilter(0, 0, colors, alphas, ratios, 50, 50, 1, 2, "full", false);
	

Para obter um efeito direto com o plano de fundo do seu documento ao definir o valor de type como "outer" ou "full", defina a primeira cor na matriz como a mesma cor do plano de fundo do documento ou defina o valor alfa da primeira cor como 0; qualquer uma das técnicas faz a mesclagem do filtro com o plano de fundo.

Se você fizer duas pequenas alterações no código, o efeito do brilho poderá ser muito diferente, mesmo com as mesmas matrizes ratios e colors. Defina o valor alfa da primeira cor na matriz como 0, para fazer a mesclagem do filtro com o plano de fundo branco do documento; e defina a propriedade type como "outer" ou "inner". Observe os resultados, conforme mostrado nas seguintes imagens.

Lembre-se de que a dispersão das cores no gradiente varia com base nos valores das propriedades blurX, blurY, strength e quality, assim como os valores ratios.

Elementos da API relacionados

Intensidade da impressão ou dispersão. Quanto maior o valor, mais cores são impressas e mais forte será o contraste entre o brilho e o plano de fundo. Os valores válidos são 0 a 255. Um valor 0 significa que o filtro não é aplicado. O valor padrão é 1.

Disposição do efeito de filtro. Os possíveis valores são constantes flash.filters.BitmapFilterType:

• BitmapFilterType.OUTER — Brilho na borda externa do objeto
• BitmapFilterType.INNER — Brilho na borda interna do objeto; o padrão.
• BitmapFilterType.FULL — Brilho na parte superior do objeto

Inicializa o filtro com os parâmetros especificados.

Retorna uma cópia deste objeto de filtro.

1. Importe as classes necessárias.
2. Declare as variáveis globais para definir o quadrado e o filtro.
3. Crie a função de construtor, que fazem o seguinte:
   • Chama o método draw(), que usa os métodos da classe Graphics acessada por meio da propriedade graphics de Sprite para desenhar um quadrado.
   • Cria um objeto BitmapFilter chamado filter e atribui a ele o valor de retorno de uma chamada para getBitmapFilter(), o que cria o filtro.
   • Cria uma nova matriz chamada myFilters e adiciona o filter a ela.
   • Atribui myFilters à propriedade filters do objeto GradientGlowFilterExample. Isso aplica todos os filtros encontrados em myFilters, o que, nesse caso, é somente filter.

package {
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;
    import flash.filters.GradientGlowFilter;
    import flash.display.Sprite;

    public class GradientGlowFilterExample extends Sprite {
        private var bgColor:uint = 0xCCCCCC;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        private var distance:Number  = 0;
        private var angleInDegrees:Number = 45;
        private var colors:Array     = [0xFFFFFF, 0xFF0000, 0xFFFF00, 0x00CCFF];
        private var alphas:Array     = [0, 1, 1, 1];
        private var ratios:Array     = [0, 63, 126, 255];
        private var blurX:Number     = 50;
        private var blurY:Number     = 50;
        private var strength:Number  = 2.5;
        private var quality:Number   = BitmapFilterQuality.HIGH;
        private var type:String      = BitmapFilterType.OUTER;
        private var knockout:Boolean = false;

        public function GradientGlowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            return new GradientGlowFilter(distance,
                                          angleInDegrees,
                                          colors,
                                          alphas,
                                          ratios,
                                          blurX,
                                          blurY,
                                          strength,
                                          quality,
                                          type,
                                          knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}