DisplacementMapFilter  - AS3

Especifica o valor da transparência alfa a ser usado para deslocamentos fora dos limites. Ele é especificado como um valor normalizado de 0,0 a 1,0. Por exemplo, ,25 define um valor de transparência de 25%. O valor padrão é 0. Use esta propriedade se a propriedade mode estiver definida como DisplacementMapFilterMode.COLOR.

Especifica a cor a ser usada para deslocamentos fora dos limites. A faixa válida de deslocamentos é de 0,0 a 1,0. Os valores estão no formato hexadecimal. O valor padrão para color é 0. Use esta propriedade se a propriedade mode estiver definida como DisplacementMapFilterMode.COLOR.

Descreve o canal de cor a ser usado na imagem de mapa para deslocar o resultado x. Os possíveis valores são as constantes BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Elementos da API relacionados

Descreve o canal de cor a ser usado na imagem de mapa para deslocar o resultado y. Os possíveis valores são as constantes BitmapDataChannel:

• BitmapDataChannel.ALPHA
• BitmapDataChannel.BLUE
• BitmapDataChannel.GREEN
• BitmapDataChannel.RED

Elementos da API relacionados

Objeto BitmapData contendo os dados do mapa de deslocamento.

Elementos da API relacionados

Valor que contém o deslocamento do canto superior esquerdo do objeto de exibição de destino a partir do canto superior esquerdo da imagem de mapa.

Elementos da API relacionados

Modo do filtro. Os possíveis valores são as constantes DisplacementMapFilterMode:

• DisplacementMapFilterMode.WRAP — Preenche o valor de deslocamento no outro lado da imagem de origem.
• DisplacementMapFilterMode.CLAMP — Fixa o valor de deslocamento para a borda da imagem de origem.
• DisplacementMapFilterMode.IGNORE — Se o valor de deslocamento estiver fora da faixa, ignorará o deslocamento e usará o pixel de origem.
• DisplacementMapFilterMode.COLOR — Se o valor de deslocamento estiver fora da imagem, substituirá os valores nas propriedades color e alpha.

Elementos da API relacionados

Multiplicador a ser usado para dimensionar o resultado do deslocamento x a partir do cálculo do mapa.

Multiplicador a ser usado para dimensionar o resultado do deslocamento y a partir do cálculo do mapa.

Inicializa uma ocorrência DisplacementMapFilter com os parâmetros especificados.

Elementos da API relacionados

Retorna uma cópia deste objeto de filtro.

1. A classe define as variáveis para a cor do plano de fundo, para o rótulo do campo de texto e para o tamanho e o deslocamento que serão usados em várias funções.
2. A função de construtor chamada o método draw(), que usa os métodos da classe Graphics para desenhar um quadrado com um preenchimento de gradiente radial. Note que graphics é a propriedade do objeto DisplacementMapFilterExample, que estende o Sprite.
3. A função de construtor chama o método createLabel(), que cria um valor de exibição do campo de texto de labelText e o adiciona à lista de exibição.
4. A função de construtor chamada o método createFilter(), que faz o seguinte:
   • Cria uma variável chamada filter para o objeto de filtro.
   • Chamada o método getDisplacementMapFilter() e atribui seu valor de retorno à variável filter.
   • Transmite filter à propriedade filters do objeto DisplacementFilterExample (classe principal).
5. O método getBitmapFilter() cria um objeto BitmapData chamado mapBitmap e atribui a ele os resultados do método createBitmapData(). O objeto mapBitmap, juntamente com outras variáveis, define um novo filtro de mapa de deslocamento.
6. O método createBitmapData() cria um novo objeto BitmapData que é baseado no conteúdo atual do objeto DisplacementMapFilterExample. Ele cria um novo bitmap baseado no bitmapData e adiciona o bitmap ao Palco.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.Sprite;
    import flash.filters.BitmapFilter;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Matrix;
    import flash.geom.Point;
    import flash.text.TextField;
    
    public class DisplacementMapFilterExample extends Sprite {
        private var bgColor:uint     = 0xFFCC00;
        private var size:uint        = 200;
        private var offset:uint      = 90;
        private var labelText:String = "Watch the text bend with the displacement map";

        public function DisplacementMapFilterExample() {
            draw();
            createLabel();
            createFilter();
        }

        private function createFilter():void {
            var filter:BitmapFilter = getBitmapFilter();
            filters = new Array(filter);
        }

        private function getBitmapFilter():BitmapFilter {
            var mapBitmap:BitmapData = createBitmapData();
            var mapPoint:Point       = new Point(0, 0);
            var channels:uint        = BitmapDataChannel.RED;
            var componentX:uint      = channels;
            var componentY:uint      = channels;
            var scaleX:Number        = 0.5;
            var scaleY:Number        = -30;
            var mode:String          = DisplacementMapFilterMode.CLAMP;
            var color:uint           = 0;
            var alpha:Number         = 0;
            return new DisplacementMapFilter(mapBitmap,
                                             mapPoint,
                                             componentX,
                                             componentY,
                                             scaleX,
                                             scaleY,
                                             mode,
                                             color,
                                             alpha);
        }

        private function draw():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(size, size);
            graphics.beginGradientFill(GradientType.RADIAL,
                                       [0xFF0000, 0x0000FF],
                                       [100, 100],
                                       [55, 200],
                                       matrix,
                                       SpreadMethod.PAD);
            graphics.drawRect(0, 0, size, size);
        }

        private function createBitmapData():BitmapData {
            var bitmapData:BitmapData = new BitmapData(size, size, true, bgColor);
            bitmapData.draw(this, new Matrix());
            var bitmap:Bitmap = new Bitmap(bitmapData);
            bitmap.x = size;
            addChild(bitmap);
            return bitmapData;
        }

        private function createLabel():void {
            var tf:TextField = new TextField();
            tf.text = labelText;
            tf.y = offset;
            tf.width = size;
            addChild(tf);
        }
    }
}