BevelFilter  - AS3

Ângulo do bisel. Os valores válidos são 0 a 360º. O valor padrão é 45°.

O valor do ângulo representa o ângulo da origem da luz teórica que cai sobre o objeto e determina o posicionamento do efeito referente ao objeto. Se a propriedade distance estiver definida como 0, o efeito não é deslocado a partir do objeto e, portanto, a propriedade angle não tem efeito.

Intensidade do desfoque horizontal, em pixels. Os valores válidos são de 0 a 255 (ponto flutuante). O valor padrão é 4. Os valores que são uma potência de 2 (como 2, 4, 8, 16 e 32) são otimizados para renderizar mais rapidamente do que outros valores.

Intensidade do desfoque vertical, em pixels. Os valores válidos são de 0 a 255 (ponto flutuante). O valor padrão é 4. Os valores que são uma potência de 2 (como 2, 4, 8, 16 e 32) são otimizados para renderizar mais rapidamente do que outros valores.

Distância de deslocamento do bisel. Valores válidos em pixels (ponto flutuante). O padrão é 4.

Valor de transparência alfa da cor de realce. O valor é especificado como um valor normalizado de 0 a 1. Por exemplo, ,25 define um valor de transparência de 25%. O valor padrão é 1.

Cor de realce do bisel. Os valores válidos estão no formato hexadecimal, 0xRRGGBB. O padrão é 0xFFFFFF.

Aplica um efeito de tachado (true), que torna efetivamente transparente o preenchimento do objeto e revela a cor de plano de fundo do documento. O valor padrão é false (sem tachado).

Número de vezes para aplicar o filtro. O valor padrão é BitmapFilterQuality.LOW, que é equivalente a aplicar o filtro uma vez. O valor BitmapFilterQuality.MEDIUM aplica o filtro duas vezes; o valor BitmapFilterQuality.HIGH aplica três vezes. Os filtros com valores menores são renderizados mais rapidamente.

Para a maioria dos aplicativos, um valor de quality baixo, médio ou alto é suficiente. Embora você possa usar valores numéricos adicionais até 15 para obter efeitos diferentes, os valores maiores são renderizados mais lentamente. Em vez de aumentar o valor de quality, você pode normalmente obter um efeito similar, com uma renderização mais rápida, simplesmente aumentando os valores das propriedades blurX e blurY.

Você pode usar as seguintes constantes BitmapFilterQuality para especificar os valores da propriedade quality:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Valor de transparência alfa da cor de sombra. Esse valor é especificado como um valor normalizado de 0 a 1. Por exemplo, ,25 define um valor de transparência de 25%. O padrão é 1.

Cor de sombra do bisel. Os valores válidos estão no formato hexadecimal, 0xRRGGBB. O padrão é 0x000000.

Intensidade da impressão ou dispersão. Os valores válidos são 0 a 255. Quanto maior o valor, mais cores são impressas e mais forte será o contraste entre o bisel e o plano de fundo. O valor padrão é 1.

Disposição do bisel no objeto. Os biséis interno e externo ficam dispostos na borda interna ou externa; um bisel inteiro fica disposto no objeto inteiro. Os valores válidos são as constantes BitmapFilterType:

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

Inicializa uma nova ocorrência BevelFilter com os parâmetros especificados.

Elementos da API relacionados

Retorna uma cópia deste objeto de filtro.

1. Importe as classes necessárias.
2. Declare três propriedades usadas na função draw(), que desenha o objeto no qual o filtro de bisel é aplicado.
3. Crie a função de construtor BevelFilterExample(), que faz o seguinte:
   • Chama a função draw(), que é declarada posteriormente.
   • Declara uma variável filter como um objeto BitmapFilter e o atribui para o retorno de uma chamada para getBitmapFilter().
   • Cria um novo objeto Matriz myFilters e adiciona filter à matriz e atribui myFilters à propriedade filters do objeto BevelFilterExample. Isso aplica todos os filtros encontrados em myFilters, o que, nesse caso, é somente filter.
4. Crie a função getBitmapFilter para criar e definir as propriedades do filtro.
5. Crie a função draw(). Essa função usa métodos da classe Graphics, acessados por meio da propriedade graphics da classe Sprite para desenhar o quadrado.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}