NetStatusEvent  - AS3

Um objeto com propriedades que descrevem o status ou condição de erro do objeto.

O objeto de informação pode ter uma propriedade code contendo uma string que representa um evento específico ou uma propriedade level contendo uma string que seja "status" ou "error".

O objeto de informação também pode ser algo diferente. As propriedades code e level talvez não funcionem em algumas implementações e pode ser que alguns servidores enviem objetos diferentes.

As conexões P2P enviam mensagens para um NetConnection com um parâmetro stream no objeto information que indica a que NetStream a mensagem pertence.

Por exemplo, o Flex Data Services envia objetos Message que provocam erros de coerção se você tentar acessar a propriedade code ou level.

A tabela a seguir descreve os valores de string possíveis das propriedades code e level.

Se você encontrar erros consistentemente em relação ao buffer, tente alterá-lo, usando a propriedade NetStream.bufferTime.

Elementos da API relacionados

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

Cria um objeto Event que contém informações sobre eventos netStatus. Objetos Event são transmitidos como parâmetros para ouvintes de eventos.

Elementos da API relacionados

Cria uma cópia do objeto NetStatusEvent e define o valor de cada propriedade para corresponder ao do original.

Retorna uma string que contém todas as propriedades do objeto NetStatusEvent. A string está no seguinte formato:

[NetStatusEvent type=value bubbles=value cancelable=value info=value]

Define o valor da propriedade type de um objeto de evento netStatus.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Neste exemplo, o método netStatusHandler é registrado como um ouvinte do evento NetStatusEvent NetConnection.netStatus. Quando o status (êxito ou falha) da tentativa do NetConnection.connect() for determinado, o evento netStatus dispara este método. Se a tentativa de conexão com o objeto NetConnection tiver êxito (ou seja, se a propriedade info do objeto NetStatusEvent despachado pelo evento netStatus tiver uma propriedade code que indique êxito), o código criará os objetos Video e NetStream, e chamará os métodos Video.attachNetStream() e NetStream.play().

Observação: Para executar este exemplo, você precisa de um arquivo FLV cujo nome e local correspondam à variável transmitida ao videoURL; neste caso, um arquivo FLV chamado Video.flv que se encontra no mesmo diretório do arquivo SWF.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }