Clipboard  - AS3

Uma matriz de strings contendo os nomes dos formatos de dados disponíveis nesse objeto Clipboard.

As constantes de string para os nomes dos formatos padrão são definidas na classe Clipboard. Outras strings definidas pelo aplicativo também podem ser usadas como nomes de formato, para transferir dados como um objeto.

Elementos da API relacionados

 var availableFormats:Array = Clipboard.generalClipboard.formats;

A área de transferência do sistema operacional.

Quaisquer dados colados para a área de transferência do sistema ficam disponíveis a outros aplicativos. Isso pode incluir código remoto não seguro sendo executado em um navegador da Web.

Observação: nos aplicativos Flash Player 10, a operação de colar da área de transferência requer um evento de usuário (por exemplo, atalho do teclado do comando Colar ou clique do mouse no comando Colar do menu de contexto). Clipboard.getData() só retornará o conteúdo da área de transferência se InteractiveObject tiver sido recebido e agindo em um evento paste. Em qualquer outra circunstância, chamar Clipboard.getData() será inútil. A mesma restrição se aplica no AIR ao conteúdo fora da caixa de proteção do aplicativo.

O objeto generalClipboard é criado automaticamente. Não é possível atribuir uma outra ocorrência de um Clipboard a essa propriedade. Em vez disso, você pode usar os métodos getData() e setData() para ler e gravar dados no objeto existente.

Você deverá sempre limpar a área de transferência antes de gravar novos dados nela para garantir que os dados antigos em todos os formatos sejam apagados.

O objeto generalClipboard não pode ser passado ao AIR NativeDragManager. Crie um novo objeto de Área de transferência de operações de arrastar e soltar nativas em um aplicativo de AIR.

 import flash.desktop.ClipboardFormats;
 
 var copy:String = "A string to copy to the system clipboard.";
 Clipboard.generalClipboard.clear();
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, copy);

 import flash.desktop.ClipboardFormats;
 
 var pasteData:String  = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Indica se o formato de área de transferência de promessa de arquivo é suportado no sistema cliente.

Cria um objeto Clipboard vazio.

Crie objetos de Área de transferência para manter os dados de um gesto de ação de arrastar e soltar nativo no Adobe AIR. Os objetos de área de transferência podem ser usados somente para um gesto de ação de arrastar e soltar; eles não podem ser reutilizados.

Não crie um objeto de Área de transferência para operações de copiar e colar. Em vez disso, utilize o objeto únicoClipboard.generalClipboard.

Elementos da API relacionados

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

Exclui todas as representações de dados do objeto Clipboard.

 Clipboard.generalClipboard.clear();

Exclui a representação de dados para o formato especificado.

Parâmetros

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

Obtém os dados da área de transferência se os dados no formato especifico estiverem presentes.

O Flash Player exige que o método getData() seja chamado em um gerenciador de eventos paste. No AIR, essa restrição só se aplica ao conteúdo fora da área de segurança do aplicativo.

Quando um formato de dados padrão é acessado, os dados são retornados como um novo objeto do tipo Flash correspondente.

Quando um formato definido pelo aplicativo é acessado, o valor do parâmetro transferMode determina se é retornada uma referência ao objeto original ou um objeto anônimo contendo uma cópia serializada do objeto original. Quando um modo originalPreferred ou clonePreferred é especificado, o Flash Player ou AIR retorna a versão alternativa, caso a versão preferida não esteja disponível. Quando um modo originalOnly ou cloneOnly é especificado, o Flash Player ou o AIR retorna null caso a versão solicitada não esteja disponível.

Parâmetros

Elementos da API relacionados

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

Verifica se os dados no formato especificado existem no objeto Clipboard.

Use as constantes na classe ClipboardFormats para fazer referência aos nomes de formato padrão.

Parâmetros

Elementos da API relacionados

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

Adiciona uma representação das informações a ser transferidas no formato de dados especificado.

Na área de segurança do aplicativo do Adobe AIR, setData() pode ser chamado a qualquer momento. Em outros contextos, setData() só pode ser chamado em resposta a um evento gerado pelo usuário, como um pressionamento de tecla ou clique no mouse.

Representações diferentes das mesmas informações podem ser adicionadas à área de transferência em diferentes formatos, o que aumenta a capacidade de outros componentes ou aplicativos de usar os dados disponíveis. Por exemplo, uma imagem poderia ser adicionada como dados de bitmap para uso por aplicativos de edição de imagem, como um URL e como um arquivo PNG codificado para transferência para o sistema de arquivos nativo.

O parâmetro dos dados deverá ser o tipo de dados apropriado para o formato especificado:

Nomes de formato personalizados não podem iniciar com "air:" ou "flash:". Para evitar colisões de nome ao usar formatos personalizados, talvez você queira usar seu ID de aplicativo ou um nome de pacote como um prefixo para o formato, como "com.example.applicationName.dataPacket".

Na transferência dentro ou entre aplicativos, o parâmetro serializable determina se uma referência e uma cópia estão disponíveis, ou se somente uma referência a um objeto está disponível. Defina serializable como true para disponibilizar a referência e uma cópia do objeto de dados. Defina serializable como false para disponibilizar somente a referência do objeto. As referências de objeto só são válidas dentro do aplicativo atual; assim, definir serializable como false também significa que os dados nesse formato não estão disponíveis para outro Flash Player ou AIR. Um componente pode preferir obter a referência ou a cópia do objeto definindo o modo de transferência apropriado da área de transferência ao acessar os dados para esse formato.

Observação: os formatos padrão são sempre convertidos para os formatos nativos quando os dados são colados ou arrastados fora de um aplicativo suportado; assim, o valor do parâmetro serializable não afeta a disponibilidade dos dados nos formatos padrão para os aplicativos não Flash.

Para adiar a renderização dos dados para um formato, use o método setDataHandler(). Se ambos os métodos setData() e setDataHandler() forem usados para adicionar uma representação de dados com o mesmo nome de formato, então, a função do manipulador jamais será chamada.

Observação: No OS Mac, quando você define o parâmetro format para ClipboardFormats. URL_FORMAT, o URL só será transferido se for um URL válido. De outra maneira, o objeto de Área de transferência é esvaziado (e chamar getData() retorna null).

Parâmetros

Elementos da API relacionados

 import flash.desktop.ClipboardFormats;
 
 var htmlString:String = "<html><body>Body content</body></html>";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.HTML_FORMAT, urlString);

Adiciona uma referência a uma função de controlador que produz os dados a serem transferidos.

Use uma função de gerenciador para adiar a criação ou a renderização dos dados até que os dados sejam realmente acessados.

A função do manipulador deverá retornar o tipo de dados apropriado para o formato especificado:

A função do manipulador é chamada quando os dados no formato especificado são lidos. Observe que em alguns casos, o sistema operacional chama a função antes que uma operação de soltar ocorra. Por exemplo, quando você usa uma função de controlador para fornecer os dados de um arquivo arrastado de um aplicativo de AIR para o sistema de arquivos, o sistema operacional chama a função de controlador de dados logo que o gesto de arrastar deixe o aplicativo normalmente de AIR que resulta em uma pausa indesejável enquanto os dados de arquivo são carregados ou criados. Você pode usar um URLFilePromise com esta finalidade.

Observe que os dados subjacentes podem se alterar entre o momento em que o manipulador é adicionado e o momento em que os dados são lidos, a não ser que seu aplicativo tome medidas para proteger os dados. O comportamento que ocorre quando os dados no clipboard representados por uma função de manipulador são lidos mais de uma vez não é garantido. A área de transferência pode retornar os dados produzidos pela primeira chamada de função ou pode chamar a função novamente. Não confie em nenhum comportamento.

Na área de segurança do aplicativo do Adobe AIR, setDataHandler() pode ser chamado a qualquer momento. Em outros contextos, setDataHandler() só pode ser chamado em resposta a um evento gerado pelo usuário, como um pressionamento de tecla ou clique no mouse.

Para adicionar dados diretamente a esse objeto Clipboard, use o método setData(). Se ambos os métodos setData() e setDataHandler() forem chamados com o mesmo nome de formato, então, a função do manipulador jamais será chamada.

Observação: ENo OS Mac, quando você define o parâmetro format para ClipboardFormats. URL_FORMAT, só será transferido se o controlador retornar um URL válido. De outra maneira, o objeto de Área de transferência é esvaziado (e chamar getData() retorna null).

Parâmetros

Elementos da API relacionados

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. Grave os dados, nesse caso uma string, na Clipboard.generalClipboard.
2. Leia o conteúdo da área de transferência de Clipboard.generalClipboard.

Observação: Por causa de restrições de segurança no acesso de dados da área de transferência, este exemplo não funciona no Flash Player. No Flash Player, você só pode chamar o método getData() do objeto da Área do transferência no controlador de eventos paste.

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void 
        {
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String
        {
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT))
            {
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } 
            else 
            {
                return null;
            }
        }
        
    }
}