DataGridEvent  - AS3 Flash

Obtém ou define o nome do campo ou propriedade nos dados associados à coluna.

Obtém o renderizador de item referente ao item que está sendo editado ou o renderizador de cabeçalho que está sendo clicado ou redimensionado.

Obtém o motivo do despacho do evento itemEditEnd. Esta propriedade é válida apenas para eventos do tipo DataGridEvent.ITEM_EDIT_END.

Os valores possíveis são definidos na classe DataGridEventReason.

Elementos da API relacionados

Cria um novo objeto DataGridEvent com os parâmetros especificados.

Elementos da API relacionados

Cria uma cópia do objeto DataGridEvent e define o valor de cada propriedade para corresponder ao original.

Retorna uma string que contém todas as propriedades do objeto DataGridEvent. A string está no seguinte formato:

[DataGridEvent type=value bubbles=value cancelable=value columnIndex=value rowIndex=value itemRenderer=value dataField=value reason=value]

A constante DataGridEvent.COLUMN_STRETCH define o valor da propriedade type de um objeto de evento columnStretch.

Esse evento tem as seguintes propriedades:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

A constante DataGridEvent.HEADER_RELEASE define o valor da propriedade type de um objeto de evento headerRelease.

Esse evento tem as seguintes propriedades:

import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

A constante DataGridEvent.ITEM_EDIT_BEGIN define o valor da propriedade type de um objeto de evento itemEditBegin.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

A constante DataGridEvent.ITEM__EDIT_BEGINNING define o valor da propriedade type de um objeto de evento itemEditBeginning.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

A constante DataGridEvent.ITEM_EDIT_END define o valor da propriedade type de um objeto de evento itemEditEnd.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

A constante DataGridEvent.ITEM_FOCUS_IN define o valor da propriedade type de um objeto de evento itemFocusIn.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

A constante DataGridEvent.ITEM_FOCUS_OUT define o valor da propriedade type de um objeto de evento itemFocusOut.

Esse evento tem as seguintes propriedades:

Elementos da API relacionados

Para executar o exemplo, siga estas etapas:

1. Adicione o componente DataGrid à biblioteca.
2. Salve esse código como DataGridEventExample.as no mesmo diretório do arquivo FLA.
3. Defina a classe Document no arquivo FLA como DataGridEventExample.

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}