| Pakiet | flash.ui |
| Klasa | public final class MouseCursorData |
| Dziedziczenie | MouseCursorData  Object |
| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10.2, AIR 2.6 |
Do wyświetlania kursora służy metoda Mouse.registerCursor(). Aby przywrócić sterowanie kursorem przez system operacyjny, należy wywołać metodę Mouse.unregisterCursor(). Wywołując metodę Mouse.supportsNativeCursor, można sprawdzić, czy na bieżącym komputerze są obsługiwane kursory macierzyste.
Maksymalny rozmiar kursora wynosi 32x32 piksele. W większości systemów operacyjnych jest obsługiwana przezroczystość.
Kursor macierzysty to funkcja zaimplementowana za pośrednictwem mechanizmu obsługi kursora oferowanego przez system operacyjny. Jest to wydajniejsza metoda wyświetlania własnego obrazu kursora niż używanie obiektu ekranowego. Kursor można animować, przekazując więcej niż jeden obraz we właściwości data i ustawiając szybkość odtwarzania.
Kursor jest wyświetlany tylko w obrębie stołu montażowego. Poza stołem montażowym jest przywracany obraz kursora stosowany w systemie operacyjnym.
Więcej informacji
Powiązane elementy interfejsu API
Ukryj dziedziczone właściwości publiczne
Pokaż dziedziczone właściwości publiczne| Właściwość | Zdefiniowane przez | ||
|---|---|---|---|
 | constructor : Object
Odwołanie do obiektu klasy lub funkcji konstruktora, dotyczące danej instancji obiektu. | Object | |
| data : Vector.<BitmapData>
Wektor obiektów BitmapData zawierający obraz lub obrazy kursora. | MouseCursorData | ||
| frameRate : Number
Szybkość odtwarzania w przypadku animowania kursora. | MouseCursorData | ||
| hotSpot : Point
Miejsce aktywne kursora w pikselach. | MouseCursorData | ||
| Metoda | Zdefiniowane przez | ||
|---|---|---|---|
Tworzy obiekt MouseCursorData. | MouseCursorData | ||
|
Wskazuje, czy dla obiektu zdefiniowano określoną właściwość. | Object | |
|
Wskazuje, czy instancja klasy Object należy do łańcucha prototypów obiektu określonego jako parametr. | Object | |
|
Wskazuje, czy określona właściwość istnieje i jest przeliczalna. | Object | |
|
Ustawia dostępność właściwości dynamicznej używanej w pętlach. | Object | |
|
Zwraca ciąg reprezentujący obiekt — sformatowany zgodnie z konwencjami właściwymi dla ustawień regionalnych. | Object | |
|
Zwraca ciąg reprezentujący określony obiekt. | Object | |
|
Zwraca pierwotną wartość dla określonego obiektu. | Object | |
data | właściwość |
data:Vector.<BitmapData>| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10.2, AIR 2.6 |
Wektor obiektów BitmapData zawierający obraz lub obrazy kursora.
Kursor można animować, przekazując więcej niż jeden obraz i ustawiając właściwość framerate.
Maksymalny rozmiar kursora wynosi 32x32 piksele.
Implementacja
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | właściwość |
frameRate:Number| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10.2, AIR 2.6 |
Szybkość odtwarzania w przypadku animowania kursora.
Przekazując więcej niż jeden obraz we właściwości data i ustawiając szybkość odtwarzania większą niż 0, można animować kursor. Szybkość odtwarzania kursora być inna niż bieżąca szybkość odtwarzania pliku SWF.
Implementacja
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | właściwość |
hotSpot:Point| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10.2, AIR 2.6 |
Miejsce aktywne kursora w pikselach.
Miejsce aktywne jest to punkt kursora, w którym są rejestrowane kliknięcia myszą. Domyślnie miejscem aktywnym jest lewy górny róg — punkt o współrzędnych (0,0).
Implementacja
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Konstruktor |
public function MouseCursorData()| Wersja języka: | ActionScript 3.0 |
| Wersje środowiska wykonawczego: | Flash Player 10.2, AIR 2.6 |
Tworzy obiekt MouseCursorData.
W celu wyświetlenia kursora należy wywołać metodę Mouse.registerCursor().
Powiązane elementy interfejsu API
Przy użyciu poleceń rysowania dostępnych za pośrednictwem klasy Graphics jest tworzonych osiem odpowiednio obróconych obrazów strzałki. Obrazy są umieszczane w wektorze i przypisywane do właściwości data obiektu MouseCursorData. (Jako kursorów można też używać wstępnie renderowanych obrazów bitmapowych).
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Tue Jun 12 2018, 12:06 PM Z