Mouse  - AS3

Nazwa kursora natywnego.

Wskazuje, czy komputer lub urządzenie wyświetla trwały kursor.

Właściwość supportsCursor ma wartość true na większości komputerów stacjonarnych i wartość false na większości urządzeń przenośnych.

Uwaga: Zdarzenia myszy mogą być wywoływane bez względu na to, czy ta właściwość ma wartość true. Jednak zdarzenia dotyczące myszy mogą działać inaczej w zależności od fizycznych właściwości urządzenia wskazującego.

Powiązane elementy interfejsu API

import flash.events.*;
import flash.display.*;
import flash.ui.Mouse;
import flash.text.TextField;

var supportsCursorTxt:TextField = new TextField();
supportsCursorTxt.width = 200;
supportsCursorTxt.border = true;
addChild(supportsCursorTxt);

addEventListener (MouseEvent.CLICK, getScreenKeyboardType);

function getScreenKeyboardType(e:MouseEvent):void{
    supportsCursorTxt.text= "Supports Cursor is : " + String(flash.ui.Mouse.supportsCursor);

}

if(Mouse.supportsCursor) {
    //Game acts as before
} else {
    if(Capabilities.touchscreenType == TouchscreenType.STYLUS ){
        //The Game has to change so that the character is chasing the location of the stylus as 
        //it's dragged around. Some of the animations will have to change
    }else if(Capabilities.touchscreenType = TouchscreenType.FINGER){
        //Same as above, except that the hit-area is larger for a finger.
    }else{
        //There's no pointing device at all. The developer designs some sort of custom cursor to 
        //be controlled with key presses or similar input
    }
}

Określa, czy bieżąca konfiguracja obsługuje kursory macierzyste.

Ukrywa wskaźnik. Wskaźnik jest domyślnie widoczny.

Uwaga: Metodę Mouse.hide() wystarczy wywołać tylko raz, niezależnie od liczby wcześniejszych wywołań metody Mouse.show().

Powiązane elementy interfejsu API

Rejestruje kursor macierzysty pod określoną nazwą przy użyciu określonych danych.

Parametry

Wyświetla wskaźnik. Wskaźnik jest domyślnie widoczny.

Uwaga: Metodę Mouse.show() wystarczy wywołać tylko raz, niezależnie od liczby wcześniejszych wywołań metody Mouse.hide().

Powiązane elementy interfejsu API

Anuluje rejestrację kursora natywnego pod określoną nazwą.

Parametry

1. Zadeklaruj następujące właściwości instancji: cursor typu CustomCursor, child typu CustomButton oraz gutter typu uint.
2. Przypisz instancję child do nowej instancji CustomButton, ustaw współrzędne x i y na 10 pikseli każdy i następnie dodaj instancję do listy wyświetlania. Klasa CustomButton przesłania właściwości downState, upState, overState oraz hitTestState w klasie SimpleButton. Każda z tych właściwości inicjuje obiekt ButtonDisplayState rysujący inny kwadrat w zależności od stanu instancji child.
3. Instancja child służy wówczas do dodania detektora zdarzeń MOUSE_OVER oraz metody detektora mouseOverHandler() razem z detektorem zdarzeń MOUSE_OUT oraz skojarzoną metodą mouseOutHandler().
4. Detektory zdarzeń funkcjonują w następujący sposób:
   • mouseOverHandler: Ukrywa „normalny” wskaźnik i dodaje detektor MOUSE_MOVE, który przetwarza ruchy myszki za pomocą metody mouseMoveHandler() opisanej poniżej.
   • mouseOutHandler: Kiedy mysz porusza się poza przyciskiem niestandardowym, pokazany jest „normalny” wskaźnik, detektor zdarzeń MOUSE_MOVE zostaje usunięty, a dla widoczności kursora niestandardowego zostaje ustawiona wartość false.
   • mouseMoveHandler: Porusza kursorem niestandardowym zgodnie z ruchem wskaźnika, a dla widoczności kursora niestandardowego zostaje ustawiona wartość true.
5. W konstruktorze MouseExample właściwość cursor jest przypisana do nowego obiektu CustomCursor, a następnie dodana do listy wyświetlania za pomocą metody addChild(). Za pomocą klasy CustomCursor rysowany jest niemal czarny kwadrat w miejscu „normalnego” wskaźnika za każdym razem, kiedy mysz znajdzie się nad instancją child.
6. Zostaje dodany czwarty detektor zdarzeń typu MOUSE_LEAVE za pomocą skojarzonej metody mouseLeaveHandler(). W tej metodzie (wywołanej, jeśli mysz opuści stół montażowy) mouseOutHandler() jest przekazana do obiektu detektora mouseMove, który zasadniczo usuwa wskaźnik, tak aby nie został na stole montażowym.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.ui.Mouse;
    import flash.events.*;

    public class MouseExample extends Sprite {
         private var cursor:CustomCursor;
         private var child:CustomButton;
         private var gutter:uint = 10;

        public function MouseExample() {
            child = new CustomButton();
            child.x = gutter;
            child.y = gutter;
            addChild(child);

            child.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            child.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);

            cursor = new CustomCursor();
            addChild(cursor);

            stage.addEventListener(Event.MOUSE_LEAVE, mouseLeaveHandler);
        }

        private function mouseOverHandler(event:MouseEvent):void {
            trace("mouseOverHandler");
            Mouse.hide();
            child.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseOutHandler(event:MouseEvent):void {
            trace("mouseOutHandler");
            Mouse.show();
            child.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            cursor.visible = false;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            cursor.x = event.localX;
            cursor.y = event.localY;
            event.updateAfterEvent();
            cursor.visible = true;
        }

        private function mouseLeaveHandler(event:Event):void {
            trace("mouseLeaveHandler");
            mouseOutHandler(new MouseEvent(MouseEvent.MOUSE_MOVE));
        }
    }
}

import flash.display.Shape;
import flash.display.SimpleButton;
    
class CustomButton extends SimpleButton {
    var upColor:uint = 0xFFCC00;
    var overColor:uint = 0xCCFF00;
    var downColor:uint = 0x00CCFF;
    var size:uint = 80;
    
    public function CustomButton() {
        downState = new ButtonDisplayState(downColor, size+10);
        overState = new ButtonDisplayState(overColor, size);
        upState = new ButtonDisplayState(upColor, size);
        hitTestState = new ButtonDisplayState(upColor, size);
    }
}

class ButtonDisplayState extends Shape {
    var bgColor:uint;
    var size:uint;
    
    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size = size;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}
    
class CustomCursor extends Shape {
    var bgColor:uint = 0x333333;
    var size:uint = 10;
    
    public function CustomCursor() {
        visible = false;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}