SQLConnection  - AS3

Wskazuje, czy podczas tworzenia bieżącej bazy danych włączona była funkcja automatycznej defragmentacji (wartość określona dla parametru autoCompact w wywołaniu metody open() lub openAsync() tworzącej bazę danych). Jeśli właściwość ma wartość true, po każdej operacji zapisu z pliku bazy danych automatycznie zostanie usunięta niewykorzystana przestrzeń, przez co plik bazy danych będzie zajmował mniej miejsca. Jeśli właściwość ma wartość false, przestrzeń wcześniej zajmowana przez usunięte dane pozostanie nienaruszona i będzie ponownie wykorzystywana w razie potrzeby. Nawet jeśli właściwość autoCompact ma wartość false, można wymusić na bazie danych odzyskanie niewykorzystanej przestrzeni, wywołując metodę compact().

Jeśli właściwość connected ma wartość false, ta właściwość zostanie ustawiona na false.

Powiązane elementy interfejsu API

Zapewnia dostęp do rozmiaru pamięci podręcznej dla połączenia. Rozmiar ten określa maksymalną liczbę stron dyskowych bazy danych, jaka będzie naraz przechowywana w pamięci. Każda strona zajmuje około 1,5 KB pamięci (zależy to od wartości określonej dla parametru pageSize w wywołaniu metody open() lub openAsync() tworzącej bazy danych). Wartością domyślną rozmiaru pamięci podręcznej jest 2000. Jeśli aplikacja wykonuje operacje UPDATE lub DELETE, które dokonują zmian w wielu wierszach bazy danych, powiększenie pamięci podręcznej może poprawić szybkość kosztem zużycia pamięci operacyjnej.

Powiązane elementy interfejsu API

Wskazuje, w jaki sposób nazwy kolumn zgłaszane są w wyniku instrukcji SELECT.

Stałe zdefiniowane w klasie SQLColumnNameStyle reprezentują potencjalne wartości właściwości:

• SQLColumnNameStyle.LONG wskazuje, że nazwy kolumn są zwracane w postaci [nazwa tabeli]_[nazwa kolumny].
• SQLColumnNameStyle.SHORT wskazuje, że nazwy kolumn mają format [nazwa kolumny]. Jeśli istnieje wiele kolumn o tej samej nazwie, tylko jedna właściwość z tą nazwą dodawana jest do obiektu wynikowego.
• SQLColumnNameStyle.DEFAULT jest wartością domyślną. W przypadku użycia tej wartości wynikowe nazwy kolumn zostaną sformatowane na podstawie tego, ile tabel w instrukcji SELECT,a podobne nazwy kolumn. Jeśli instrukcja SELECT zawiera tylko jedną tabelę, zostanie użyty format nazw krótkich w postaci [column-name], natomiast jeśli instrukcja SELECT zawiera wiele złączonych tabel i wystąpi konflikt nazw, dla identycznie nazwanych kolumn użyty zostanie format nazw długich w postaci [table-name]_[column-name].

Powiązane elementy interfejsu API

Wskazuje, czy instancja klasy SQLConnection ma otwarte połączenie z plikiem bazy danych.

Powiązane elementy interfejsu API

Wskazuje, czy połączenie jest aktualnie zaangażowane w transakcję.

Powiązane elementy interfejsu API

Wskazuje, czy klasa SQLConnection jest obsługiwana na bieżącej platformie.

Ostatnio wygenerowany identyfikator wiersza utworzony za pomocą instrukcji INSERT. Identyfikator wiersza jednoznacznie identyfikuje wiersz w tabeli bazy danych. Jego wartość jest często generowana przez bazę danych.

Ma wartość zero, jeśli żadna baza danych nie została podłączona lub nie wykonano żadnej instrukcji INSERT.

Identyfikator wiersza dla pojedynczego wykonania instrukcji SQL INSERT można odczytać z właściwości lastInsertRowID obiektu SQLResult zwróconego przez metodę getResult() obiektu SQLStatement (wywołanej po tym, jak obiekt SQLStatement wygenerował zdarzenie result).

Więcej informacji na temat kluczy głównych i generowanych identyfikatorów wierszy zawiera opis instrukcji „CREATE TABLE” oraz sekcja „Wyrażenia” w dodatku Obsługa języka SQL w lokalnych bazach danych”

Powiązane elementy interfejsu API

Wskazuje rozmiar bazy danych (w bajtach) określony w momencie tworzenia bieżącej bazy danych (wartość określona dla parametru pageSize w wywołaniu metody open() lub openAsync() tworzącym bazę danych)

Jeśli właściwość connected ma wartość false, wartość tej właściwości będzie równa 0.

Rozmiar strony bazy danych może być zmieniany (za pomocą metody open() lub openAsync()) do momentu utworzenia pierwszej tabeli w bazie danych.

Powiązane elementy interfejsu API

Zawiera całkowitą liczbę zmian danych dokonanych od momentu otwarcia połączenia z bazą danych. Poza zmianami dokonanymi przez instrukcje INSERT, DELETE i UPDATE wartość ta uwzględnia zmiany dokonane przez wyzwalacze.

Gdy połączenie bazy danych jest zamykane, wartość jest ponownie ustawiana na 0. Jeśli instancja klasy SQLConnection nie jest podłączona do bazy danych, wartość jest równa 0.

Powiązane elementy interfejsu API

Tworzy wystąpienie klasy SQLConnection.

Rejestruje obiekt detektora zdarzenia w obiekcie EventDispatcher, dzięki czemu detektor będzie otrzymywał powiadomienia o zdarzeniu. We wszystkich węzłach listy wyświetlania można rejestrować detektory zdarzeń reagujące na zdarzenia konkretnego typu, znajdujące się w określonej fazie i mające określony priorytet.

Po pomyślnym zarejestrowaniu detektora zdarzeń nie można zmienić jego priorytetu poprzez dodatkowe wywołania metody addEventListener(). Aby zmienić priorytet detektora, należy najpierw wywołać metodę removeListener(). Następnie można ponownie zarejestrować detektor z nowym poziomem priorytetu.

Należy pamiętać, że po zarejestrowaniu detektora późniejsze wywołania metody addEventListener() z różnymi wartościami type albo useCapture powodują rejestrowanie odrębnych detektorów. Na przykład detektor zarejestrowany z parametrem useCapture ustawionym na true wykrywa tylko zdarzenia w fazie przechwytywania. Po ponownym wywołaniu metody addEventListener() z tym samym obiektem detektora, ale z parametrem useCapture ustawionym na false będą istniały dwa odrębne detektory: jeden wykrywający zdarzenia w fazie przechwytywania, a drugi wykrywający zdarzenia w fazach miejsca docelowego i propagacji.

Nie można zarejestrować detektora zdarzeń, który wykrywałby tylko zdarzenia w fazie miejsca docelowego lub tylko zdarzenia w fazie propagacji. Te fazy są sprzężone podczas rejestracji, ponieważ propagacja zachodzi tylko w przodkach węzła miejsca docelowego.

Gdy detektor zdarzeń przestanie być potrzebny, należy go usunąć, wywołując metodę removeEventListener(); w przeciwnym razie mogą wystąpić problemy w zarządzaniu pamięcią. Detektory zdarzeń nie są automatycznie usuwane z pamięci, ponieważ proces czyszczenia pamięci nie usuwa detektora, pod warunkiem że istnieje obiekt wywołujący (o ile dla parametru useWeakReference ustawiona jest wartość true).

Skopiowanie instancji klasy EventDispatcher nie powoduje skopiowania detektorów zdarzeń dołączonych do tej instancji. (Jeśli utworzono nowy węzeł, dla którego potrzebny jest detektor zdarzeń, należy dołączyć detektor po utworzeniu węzła). Jednak przeniesienie instancji klasy EventDispatcher powoduje również przeniesienia dołączonych do niej detektorów zdarzeń

Jeśli detektor zdarzeń jest rejestrowany w węźle w momencie, gdy ten węzeł przetwarza zdarzenie, detektor nie zostanie wywołany w bieżącej fazie, ale może być wywołany w późniejszej fazie przepływu zdarzeń, np. w fazie propagacji.

Jeśli detektor zdarzeń zostanie usunięty z węzła w momencie, gdy ten węzeł przetwarza zdarzenie, zostanie wywołany przez bieżące operacje. Raz usunięty detektor zdarzeń nie jest nigdy ponownie wywoływany (chyba że zostanie ponownie zarejestrowany na potrzeby dalszego etapu wykonania programu).

Parametry

function(evt:Event):void

Zbiera statystyki na temat indeksów bazy danych i zapisuje je w tej bazie. Statystyki mogą być następnie używane przez optymalizator zapytań (moduł mechanizmu bazy danych, która określa najbardziej efektywny sposób wykonania każdej instrukcji). Statystyki pomagają optymalizatorowi zapytań dokonać lepszego wyboru indeksu lub indeksów, aby zastosować je w momencie wykonywania konkretnego zapytania.

Jeśli baza danych ma już zdefiniowane indeksy, lecz metoda analyze() nie była jeszcze wywoływana, środowisko wykonawcze nadal będzie korzystać z tych indeksów przy wykonywaniu instrukcji. Jednak bez dodatkowych informacji statystycznych wygenerowanych przez metodę analyze() metoda może nie wybrać najefektywniejszego indeksu dla konkretnego zapytania.

Jeśli dane tabeli zostaną zmienione (w wyniku wykonania instrukcji INSERT, UPDATE lub DELETE), indeksy skojarzone z tą tabelą również zostaną zmienione. Informacje statystyczne wygenerowane za pomocą metody analyze() nie są automatycznie aktualizowane. Dlatego po dokonaniu wielu zmian danych korzystne może być ponowne wywołanie metody analyze(). Jednak korzyść uzyskana z ponownego wywołania metody analyze() będzie zależała od kilku czynników, w tym liczby indeksów zdefiniowanych dla tabeli, relacji pomiędzy liczbą zmienionych wierszy i całkowitą liczbą wierszy w tabeli, ilości zmian w indeksowanych danych tabeli oraz od stopnia zróżnicowania danych przed i po zmianie.

Parametr resourceName wskazuje, czy operację należy wykonać na indeksach wszystkich dołączonych baz danych, na konkretnej bazie, czy też na konkretnej tabeli.

Po każdym wywołaniu tej metody jakiekolwiek wcześniej utworzone dane statystyczne są usuwane i tworzone ponownie dla bazy danych lub tabeli określonej w parametrze resourceName (lub wszystkich tabel we wszystkich połączonych bazach danych jeśli parametr resourceName ma wartość null). Ta metoda może być wywoływana w dowolnym momencie, jeśli połączenie z bazą danych jest otwarte. Operacja analyze() i dane statystyczne przez nią utworzone nie są uwzględniane w transakcji; jednak nie zaleca się wywoływania metody analyze(), jeśli w bazie danych wykonywana jest transakcja (właściwość inTransaction ma wartość true). Wynika to z faktu, że wszystkie zmiany danych, schematu tabeli lub indeksu, które zostały wykonane w transakcji, ale nie sfinalizowane, nie zostaną uwzględnione przez wywołanie metody analyze(), a dane metody analyze() staną się nieaktualne po zatwierdzeniu transakcji.

Aby usunąć dane statystyczne utworzone za pomocą metody analyze(), należy skorzystać z metody deanalyze().

Parametry

Powiązane elementy interfejsu API

Dodaje kolejną bazę danych do instancji klasy SQLConnection, nadając nowej bazie danych określoną nazwę. Dołączenie bazy danych umożliwia skorzystanie z niej w instrukcjach SQL wykonywanych na instancji klasy SQLConnection.

Jeśli jakaś baza danych została już dołączona pod podaną nazwą, wywołanie metody attach() spowoduje błąd. Jednak tę samą bazę danych można dołączyć wielokrotnie, korzystając z niepowtarzalnych nazw. Do pojedynczej instancji klasy SQLConnection można dołączyć maksymalnie dziesięć baz danych.

Każda instrukcja SQL może być wykonana na bazie danych podłączonej za pomocą metody attach(), jeśli tylko można ją wykonać na głównej bazie danych (bazie danych podłączonej za pomocą metody open() lub openAsync()). Instrukcja SQL ma dostęp do tabel we wszystkich bazach danych dołączonych do skojarzonych z nią instancji klasy SQLConnection, w tym dostęp do tabel z wielu baz danych w pojedynczej instrukcji. Gdy środowisko wykonawcze tłumaczy nazwy tabel, przeszukuje bazy danych instancji klasy SQLConnection w kolejności, w której bazy danych zostały dołączone, rozpoczynając od bazy danych podłączonej za pomocą metody open() lub openAsync(). Aby sprecyzować nazwę tabeli, należy w instrukcji użyć jawnie nazwy bazy danych (określonej w parametrze name metody attach()).

Aby usunąć bazę danych dołączoną za pomocą metody attach(), należy użyć metody detach(). Gdy instancja klasy SQLConnection zostanie zamknięta (przez wywołanie metody close()), wszystkie dołączone bazy danych zostaną odłączone.

Dołączona baza danych będzie obsługiwana w tym samym trybie wykonywania (synchronicznym lub asynchronicznym), co główna baza danych — w zależności od tego, czy baza danych została podłączona za pomocą metody open(), czy za pomocą metody openAsync().

Parametry

Powiązane elementy interfejsu API

Rozpoczyna transakcję, wewnątrz której wszystkie instrukcje SQL wykonane na bazach danych połączenia są grupowane.

Domyślnie każda instrukcja jest wykonywana wewnątrz swojej transakcji, a transakcja jest kończona, gdy wykonanie instrukcji zakończy się pomyślnie lub niepowodzeniem. Utworzenie transakcji za pomocą metody begin() powoduje powstanie nowej, utworzonej ręcznie transakcji. Od tej pory wszystkie instrukcje SQL wykonane na instancji klasy SQLConnection mają miejsce wewnątrz transakcji i jakiekolwiek operacje lub modyfikacje wykonane przez instrukcje mogą być zatwierdzone (utrwalone) lub wycofane jako grupa.

Aby zakończyć transakcję, należy wywołać metodę commit() lub rollback(), w zależności od tego, czy zmiany dokonane przez instrukcje transakcji należy utrwalić, czy odrzucić.

Zagnieżdżone wywołania metody begin() są ignorowane. Możliwe jest tworzenie punktów zapisu, które działają jak zakładki w transakcji, ponieważ wywołują metodę setSavepoint(). Następnie możliwe jest częściowe zatwierdzanie lub wycofywanie instrukcji SQL poprzez wywoływanie metod releaseSavepoint() lub rollbackToSavepoint(). Jeśli jednak transakcja zostanie uruchomiona poprzez wywołanie metody begin(), zmiany nie zostaną trwale zatwierdzone w bazie danych do czasu wywołania metody commit().

Jeśli połączenie z bazą danych zostanie zamknięte w sytuacji, gdy jest otwarta transakcja, środowisko AIR automatycznie wycofa transakcję. (Uwaga: w wersji 1.1 i wcześniejszych wersjach środowiska AIR otwarta transakcja jest automatycznie zatwierdzana z chwilą zamknięcia połączenia).

Transakcja nie ogranicza się do wykonywania instrukcji w pojedynczej bazie danych, może ona także obejmować instrukcje wykonywane na innych dołączonych bazach danych.

Parametry

Powiązane elementy interfejsu API

package
{
    import flash.data.SQLConnection;
    import flash.data.SQLResult;
    import flash.data.SQLStatement;
    import flash.display.Sprite;
    import flash.events.SQLErrorEvent;
    import flash.events.SQLEvent;
    import flash.filesystem.File;
    
    public class MultiInsertTransactionExample extends Sprite
    {
        private var conn:SQLConnection;
        private var insertEmployee:SQLStatement;
        private var insertPhoneNumber:SQLStatement;
        
        public function MultiInsertTransactionExample():void
        {
            // define where to find the database file
            var appStorage:File = File.applicationStorageDirectory;
            var dbFile:File = appStorage.resolvePath("ExampleDatabase.db");
            
            // open the database connection
            conn = new SQLConnection();
            conn.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            conn.addEventListener(SQLEvent.OPEN, openHandler);
            conn.openAsync(dbFile);
        }
        
        // Called when the database is connected
        private function openHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.OPEN, openHandler);
            
            // start a transaction
            conn.addEventListener(SQLEvent.BEGIN, beginHandler);
            conn.begin();
        }
        
        // Called when the transaction begins
        private function beginHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.BEGIN, beginHandler);
            
            // create and execute the first SQL statement:
            // insert an employee record
            insertEmployee = new SQLStatement();
            insertEmployee.sqlConnection = conn;
            insertEmployee.text = 
                "INSERT INTO employees (lastName, firstName, email) " + 
                "VALUES (:lastName, :firstName, :email, :birthday)";
            insertEmployee.parameters[":lastName"] = "Smith";
            insertEmployee.parameters[":firstName"] = "Bob";
            insertEmployee.parameters[":email"] = "bsmith@example.com";
            insertEmployee.parameters[":birthday"] = new Date(1971, 8, 12);
            
            insertEmployee.addEventListener(SQLEvent.RESULT, insertEmployeeHandler);
            insertEmployee.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            insertEmployee.execute();
        }
        
        // Called after the employee record is inserted
        private function insertEmployeeHandler(event:SQLEvent):void
        {
            insertEmployee.removeEventListener(SQLEvent.RESULT, insertEmployeeHandler);
            insertEmployee.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            // Get the employee id of the newly created employee row
            var result:SQLResult = insertEmployee.getResult();
            var employeeId:Number = result.lastInsertRowID;
            
            // Add a phone number to the related phoneNumbers table
            insertPhoneNumber = new SQLStatement();
            insertPhoneNumber.sqlConnection = conn;
            insertPhoneNumber.text =
                "INSERT INTO phoneNumbers (employeeId, type, number) " +
                "VALUES (:employeeId, :type, :number)";
            insertPhoneNumber.parameters[":employeeId"] = employeeId;
            insertPhoneNumber.parameters[":type"] = "Home";
            insertPhoneNumber.parameters[":number"] = "(555) 555-1234";
            
            insertPhoneNumber.addEventListener(SQLEvent.RESULT, insertPhoneNumberHandler);
            insertPhoneNumber.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            insertPhoneNumber.execute();
        }
        
        // Called after the phone number record is inserted
        private function insertPhoneNumberHandler(event:SQLEvent):void
        {
            insertPhoneNumber.removeEventListener(SQLEvent.RESULT, insertPhoneNumberHandler);
            insertPhoneNumber.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            // No errors so far, so commit the transaction
            conn.addEventListener(SQLEvent.COMMIT, commitHandler);
            conn.commit();
        }
        
        // Called after the transaction is committed
        private function commitHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.COMMIT, commitHandler);
            
            trace("Transaction complete");
        }
        
        // Called whenever an error occurs
        private function errorHandler(event:SQLErrorEvent):void
        {
            // If a transaction is happening, roll it back
            if (conn.inTransaction)
            {
                conn.addEventListener(SQLEvent.ROLLBACK, rollbackHandler);
                conn.rollback();
            }
            
            trace(event.error.message);
            trace(event.error.details);
        }
        
        // Called when the transaction is rolled back
        private function rollbackHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.ROLLBACK, rollbackHandler);
            
            // add additional error handling, close the database, etc.
        }
    }
}

package
{
    import flash.data.SQLConnection;
    import flash.data.SQLResult;
    import flash.data.SQLStatement;
    import flash.display.Sprite;
    import flash.events.SQLErrorEvent;
    import flash.events.SQLEvent;
    import flash.filesystem.File;
    
    public class MultiDeleteTransactionExample extends Sprite
    {
        private var conn:SQLConnection;
        private var deleteEmployee:SQLStatement;
        private var deletePhoneNumbers:SQLStatement;
        
        private var employeeIdToDelete:Number = 25;
        
        public function MultiDeleteTransactionExample():void
        {
            // define where to find the database file
            var appStorage:File = File.applicationStorageDirectory;
            var dbFile:File = appStorage.resolvePath("ExampleDatabase.db");
            
            // open the database connection
            conn = new SQLConnection();
            conn.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            conn.addEventListener(SQLEvent.OPEN, openHandler);
            conn.openAsync(dbFile);
        }
        
        // Called when the database is connected
        private function openHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.OPEN, openHandler);
            
            // start a transaction
            conn.addEventListener(SQLEvent.BEGIN, beginHandler);
            conn.begin();
        }
        
        // Called when the transaction begins
        private function beginHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.BEGIN, beginHandler);
            
            // Create and execute the first SQL statement:
            // Delete an employee's phone number records
            deletePhoneNumbers = new SQLStatement();
            deletePhoneNumbers.sqlConnection = conn;
            deletePhoneNumbers.text =
                "DELETE FROM phoneNumbers " +
                "WHERE employeeId = :employeeId";
            deletePhoneNumbers.parameters[":employeeId"] = employeeIdToDelete;
            
            deletePhoneNumbers.addEventListener(SQLEvent.RESULT, deletePhoneNumbersHandler);
            deletePhoneNumbers.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            deletePhoneNumbers.execute();
        }
        
        // Called after the phone number records are deleted
        private function deletePhoneNumbersHandler(event:SQLEvent):void
        {
            deletePhoneNumbers.removeEventListener(SQLEvent.RESULT, deletePhoneNumbersHandler);
            deletePhoneNumbers.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            deleteEmployee = new SQLStatement();
            deleteEmployee.sqlConnection = conn;
            deleteEmployee.text = 
                "DELETE FROM employees " + 
                "WHERE employeeId = :employeeId";
            deleteEmployee.parameters[":employeeId"] = employeeIdToDelete;
            
            deleteEmployee.addEventListener(SQLEvent.RESULT, deleteEmployeeHandler);
            deleteEmployee.addEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            deleteEmployee.execute();
        }
        
        // Called after the employee record is deleted
        private function deleteEmployeeHandler(event:SQLEvent):void
        {
            deleteEmployee.removeEventListener(SQLEvent.RESULT, deleteEmployeeHandler);
            deleteEmployee.removeEventListener(SQLErrorEvent.ERROR, errorHandler);
            
            // No errors so far, so commit the transaction
            conn.addEventListener(SQLEvent.COMMIT, commitHandler);
            conn.commit();
        }
        
        // Called after the transaction is committed
        private function commitHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.COMMIT, commitHandler);
            
            trace("Transaction complete");
        }
        
        // Called whenever an error occurs
        private function errorHandler(event:SQLErrorEvent):void
        {
            // If a transaction is happening, roll it back
            if (conn.inTransaction)
            {
                conn.addEventListener(SQLEvent.ROLLBACK, rollbackHandler);
                conn.rollback();
            }
            
            trace(event.error.message);
            trace(event.error.details);
        }
        
        // Called when the transaction is rolled back
        private function rollbackHandler(event:SQLEvent):void
        {
            conn.removeEventListener(SQLEvent.ROLLBACK, rollbackHandler);
            
            // add additional error handling, close the database, etc.
        }
    }
}

Przerywa wszystkie bieżące instrukcje SQL wykonywane na bazach danych połączonych z instancją klasy SQLConnection. Z tej metody można korzystać w celu zatrzymania długo przetwarzanych zapytań lub zapytań, nad którymi utracono kontrolę.

Jeśli metoda cancel() wywołana zostanie w momencie wykonywania instrukcji, zatrzymane zostaną operacje instrukcji, a wszystkie niekompletne uaktualnienia lub transakcje zostaną wycofane. Jeśli w danym momencie żadna instrukcja nie jest wykonywana, wywołanie metody tylko wycofa otwartą transakcję.

Parametry

Powiązane elementy interfejsu API

Zamyka bieżące połączenie bazy danych. Wszystkie dołączone bazy danych także zostaną odłączone.

Jeśli w momencie wywołania metody close() była otwarta transakcja, zostanie ona wycofana. Jeśli instancja klasy SQLConnection zostanie usunięta w wyniku porządkowania pamięci, środowisko wykonawcze automatycznie wywoła metodę close() — również wtedy, gdy aplikacja AIR jest zamykana, a instancja klasy SQLConnection jest nadal połączona z bazą danych.

Parametry

Zatwierdza istniejącą transakcję, powodując wykonanie trwałe wprowadzenie do bazy danych wyników operacji przetwarzanych przez instrukcje transakcji.

Pośrednie punktu zapisu, które działają jak zakładki w transakcji, mogą być tworzone poprzez wywołanie metody setSavepoint(). Za pomocą punktów zapisu można zatwierdzać części transakcji poprzez wywoływanie metody releaseSavepoint() lub wycofywanie części transakcji poprzez wywoływanie metody rollbackToSavepoint(). Jeśli jednak transakcja została otwarta za pomocą metody begin(), wówczas zmiany nie są trwale zapisywane w bazie danych do czasu zatwierdzenia całej transakcji poprzez wywołanie metody commit().

W transakcji, w której używane są punkty zapisu, instrukcje wycofane za pomocą metody rollbackToSavepoint() nie są zatwierdzane, nawet jeśli zatwierdzona została cała transakcja. Instrukcje zatwierdzone za pomocą metody releaseSavepoint() lub takie, których punkty zapisu nie zostały zwolnione ani wycofane, są zatwierdzane w bazie danych.

Parametry

Powiązane elementy interfejsu API

Odzyskuje całą niewykorzystaną przestrzeń w bazie danych. Gdy obiekt (tabela, indeks lub wyzwalacz) zostanie usunięty z bazy danych, w jego miejscu pojawia się pusta przestrzeń. Wskutek tego plik bazy danych zajmuje więcej miejsca, niż w rzeczywistości potrzebuje. Takie rozwiązanie pozwala jednak na przyspieszenie operacji INSERT. Po pewnym czasie operacje INSERT i DELETE mogą spowodować fragmentację struktury pliku bazy danych, co doprowadzi do spowolnienia dostępu do zawartości bazy danych na dysku. Opisywana metoda defragmentuje plik bazy danych, usuwając puste strony i rozmieszczając dane tabeli w sposób ciągły; poza tym porządkuje inne aspekty jego struktury.

Metoda compact() nie może być wykonywana na dołączonym pliku bazy danych; można ją wykonać jedynie na głównym (oryginalnym) pliku bazy danych otwartym za pomocą instancji klasy SQLConnection. Operacja zakończy się niepowodzeniem, jeśli jakaś transakcja jest aktywna. Ponadto nie ma wpływu na bazy danych rezydujące w pamięci operacyjnej.

Parametry

Usuwa wszystkie informacje statystyczne utworzone za pomocą metody analyze().

Ponieważ statystyki wygenerowane za pomocą metody analyze() zajmują miejsce w bazie danych, wywołanie metody deanalyze() pozwala odzyskać tę przestrzeń, podobnie jak usunięcie kilku indeksów i tabel.

Ta operacja nie jest uwzględniana w aktywnej transakcji.

Parametry

Powiązane elementy interfejsu API

Odłącza dodatkową bazę danych wcześniej dołączoną do instancji klasy SQLConnection za pomocą metody attach(). Istnieje możliwość wielokrotnego dołączania tej samej bazy danych za pomocą różnych nazw oraz odłączenia jednego połączenia bez naruszania pozostałych. Nie można odłączyć bazy danych, jeśli połączenie zawiera otwartą transakcję (właściwość inTransaction ma wartość true).

Parametry

Powiązane elementy interfejsu API

Zapewnia dostęp do wyniku wywołania metody loadSchema(). Metoda getSchemaResult() działa jak kolejka FIFO (pierwszy na wejściu — pierwszy na wyjściu) z wynikami. Po każdym zakończonym wywołaniu metody loadSchema() (za każdym razem, kiedy zdarzenieschema jest wywoływane w asynchronicznym trybie wykonywania) do kolejki dodawana jest nowa instancja klasy SQLSchemaResult. Za każdym razem, kiedy wywoływana jest metoda getSchemaResult(), pierwszy wynik (ten, który jako pierwszy został dodany do kolejki) jest zwracany i usuwany z kolejki. Kiedy w kolejce nie pozostanie już żadna instancja, metoda getSchemaResult() zwraca wartość null.

Jeśli połączenie bazy danych jest zamknięte, metoda zwraca wartość null.

Powiązane elementy interfejsu API

Ładuje informacje o schemacie z podłączonej bazy danych lub innych dołączonych baz danych. Schemat wskazuje strukturę tabel, kolumn, indeksów i wyzwalaczy bazy danych.

Aby uzyskać dostęp do załadowanego schematu, należy skorzystać z metody SQLConnection.getSchemaResult().

W asynchronicznym trybie wykonywania wywoływane jest zdarzenie schema dla operacji zakończonych sukcesem lub zdarzenie error w przypadku niepowodzenia.

Kombinacja wartości parametrów type oraz name określa typ danych schematu wygenerowanego za pomocą metody loadSchema() i w konsekwencji wartości właściwości wygenerowanej instancji klasy SQLSchemaResult. Poniższa tabela zawiera listę poprawnych par argumentów type i name oraz dane schematu, które zostaną wygenerowane:

Jeśli kombinacja argumentów type i name nie jest zgodna z jedną z powyższych, w asynchronicznym trybie wykonywania wywołane zostanie zdarzenie error, a w synchronicznym trybie wykonywania zgłoszony zostanie wyjątek. Przykładowo jeśli argument type ma wartośćSQLViewSchema i argument name jest nazwą tabeli (a nie nazwą widoku), zgłoszony zostanie błąd wskazujący, że baza danych nie zawiera obiektu o określonym typie i podanej nazwie.

Jeśli baza danych jest pusta (nie zawiera tabel, widoków, wyzwalaczy ani indeksów), wywołanie metody loadSchema() spowoduje błąd.

Parametry

Powiązane elementy interfejsu API

Otwiera synchroniczne połączenie do pliku bazy danych w określonej lokalizacji w systemie plików lub tworzy i otwiera nowy plik bazy danych w tej lokalizacji lub też tworzy i otwiera bazę danych rezydującą w pamięci operacyjnej. W przypadku otwierania bazy danych za pomocą tej metody wszelkie operacje tworzenia i otwierania bazy danych, podobnie jak wszystkie pozostałe operacje, które są wykonywane za pomocą instancji klasy SQLConnection (także wykonywanie instrukcji i innych operacji przetwarzanych przez instancję klasy SQLStatement skojarzoną z instancją klasy SQLConnection) są wykonywane synchronicznie. Aby wykonywać operacje asynchronicznie, należy otworzyć połączenie z bazą danych za pomocą metody openAsync().

Po podłączeniu bazy danych należy użyć instancji klasy SQLStatement w celu wykonywania komend SQL. Operacje na poziomie bazy danych, takie jak rozpoczynanie i kończenie transakcji, ładowanie informacji o schemacie oraz inne operacje, są wykonywane za pomocą instancji klasy SQLConnection.

Bazie danych podłączonej za pomocą metody open() automatycznie przypisywana jest nazwa „main”; nazwy tej można używać w celu sprecyzowania nazw tabel w instrukcjach SQL, przy użyciu formatu [nazwa bazy danych].[nazwa tabeli].

Parametry

Powiązane elementy interfejsu API

Otwiera asynchroniczne połączenie do pliku bazy danych w określonej lokalizacji w systemie plików lub tworzy i otwiera nowy plik bazy danych w tej lokalizacji lub też tworzy i otwiera bazę danych rezydującą w pamięci operacyjnej. W przypadku otwierania bazy danych za pomocą tej metody wszelkie operacje tworzenia i otwierania bazy danych, podobnie jak wszystkie pozostałe operacje, które są wykonywane za pomocą instancji klasy SQLConnection (także wykonywanie instrukcji i innych operacji przetwarzanych przez instancję klasy SQLStatement skojarzoną z instancją klasy SQLConnection) są wykonywane asynchronicznie. Aby wykonać operacje synchronicznie, należy otworzyć połączenie z bazą danych za pomocą metody open().

Po podłączeniu bazy danych należy użyć instancji klasy SQLStatement w celu wykonywania komend SQL. Operacje na poziomie bazy danych, takie jak rozpoczynanie i kończenie transakcji, ładowanie informacji o schemacie oraz inne operacje, są wykonywane za pomocą instancji klasy SQLConnection.

Bazie danych podłączonej za pomocą metody openAsync() automatycznie przypisywana jest nazwa "main"; nazwy tej można użyć w celu precyzowania nazw tabel w instrukcjach SQL, korzystając z formatu [nazwa bazy danych].[nazwa tabeli].

Parametry

Powiązane elementy interfejsu API

Zmienia klucz szyfrowania zaszyfrowanej bazy danych. Ta metoda ma wpływ wyłącznie na klucz szyfrowania głównej bazy danych (bazy danych podłączonej za pomocą metody open() lub openAsync()). Metodę reencrypt() można wywołać tylko w odniesieniu do bazy danych zaszyfrowanej podczas jej tworzenia. Bazy danych, która została utworzona jako zaszyfrowana, nie można już odszyfrować. Podobnie, bazy danych, która została utworzona jako niezaszyfrowana, nie można później zaszyfrować.

Operacja ponownego szyfrowania działa w swojej własnej transakcji. Jeśli proces ponownego szyfrowania zostanie przerwany, baza danych wycofuje transakcję, a klucz szyfrowania nie ulega zmianie.

Parametry

Powiązane elementy interfejsu API

Ta metoda zatwierdza operacje SQL zrealizowane od czasu ostatniego punktu zapisu lub nazwanego punktu zapisu, jeśli nazwa została określona.

Należy zauważyć, że do czasu zatwierdzenia całej transakcji zmiany nie będą trwale zapisywane w bazie danych. Jeśli transakcja jest uruchamiana za pomocą metody begin(), należy wywołać metodę commit() w celu zatwierdzenia całej transakcji. Jeśli transakcja została uruchomiona za pomocą metody setSavepoint(), gdy parametr inTransaction miał wartość false, wówczas całą transakcję można zakończyć poprzez wywołanie metody commit() albo wywołanie metody releaseSavepoint() lub rollbackToSavepoint() dla pierwszego punktu zapisu transakcji.

Jeśli kod wywoła metodę rollback(), metoda trwale odrzuci wszystkie zmiany w transakcji, bez względu na to, czy metoda releaseSavepoint() została wywołana przed wycofaniem transakcji.

Jeśli metoda została wywołana bez parametrów (lub z wartością null dla parametru name), metoda zatwierdza wszystkie zmiany bazy danych od czasu ostatniego niezapisanego punktu zapisu (najnowszy punkt zapisu utworzony przez wywołanie metody setSavepoint() bez parametru name). Na przykład: jeśli metoda setSavepoint() została wywołana trzy razy, ustawiane są trzy punkty zapisu. Wywołanie metody releaseSavepoint() w tym momencie powoduje zatwierdzenie operacji SQL wykonywanych od czasu trzeciego (najnowszego) punktu zapisu.

Jeśli określono wartość dla parametru name, ta metoda zatwierdza wszystkie operacje SQL wykonywane od czasu punktu zapisu o określonej nazwie. Jeśli inne punkty zapisu są nowsze niż wybrany punkt zapisu, wówczas operacje wykonywane po tych punktach zapisu również zostaną zatwierdzone.

Po zwolnieniu lub wycofaniu punktu zapisu następuje usunięcie tego punktu oraz punktów nowszych niż on. Jeśli kod wykona dodatkowe operacje SQL, gdy metoda releaseSavepoint() lub rollbackToSavepoint() usunie punkt zapisu, wówczas te operacje będą należały do najnowszego pozostałego punktu zapisu. (Innymi słowy — będą należały do najnowszego punktu zapisu przed usuniętym punktem zapisu). Jeśli nie pozostaną żadne punkty zapisu, operacje będą należały do transakcji głównej.

Parametry

Powiązane elementy interfejsu API

Usuwa detektor z obiektu EventDispatcher. Jeśli w obiekcie EventDispatcher nie ma zarejestrowanego zgodnego detektora zdarzeń, wywołanie tej metody nie odnosi żadnego skutku.

Parametry

Wycofuje istniejącą transakcję utworzoną za pomocą metody begin(); oznacza to, że wszystkie zmiany dokonane przez którąkolwiek z instrukcji SQL w transakcji zostaną odrzucone.

Pośrednie punkty zapisu mogą zostać oznaczone w transakcji poprzez wywołanie metody setSavepoint(). Za pomocą punktów zapisu można zatwierdzać części transakcji poprzez wywoływanie metody releaseSavepoint() lub wycofywanie części transakcji poprzez wywoływanie metody rollbackToSavepoint(). Jednak wywołanie metody rollback() powoduje trwałe odrzucenie wszystkich zmian wykonanych w transakcji, bez względu na to, czy poszczególne punkty zapis zostały zwolnione (zatwierdzone) przed wycofaniem transakcji.

Parametry

Powiązane elementy interfejsu API

Wycofuje wszelkie operacje SQL zrealizowane od czasu ostatniego punktu zapisu lub nazwanego punktu zapisu, jeśli nazwa została określona.

Należy zauważyć, że jeśli cała transakcja została wycofana poprzez wywołanie metody commit(), wszelkie zmiany w transakcji, które nie zostały jeszcze wycofane za pomocą metody rollbackToSavepoint() zostaną trwale zapisane w bazie danych. Ponadto: wywołanie metody rollback() trwale odrzuca wszystkie zmiany, bez względu na to, czy poszczególne punkty zapisu zostały zwolnione (zatwierdzone) czy wycofane przed wycofaniem transakcji.

Jeśli ta metoda jest wywoływana bez parametrów (lub null dla parametru name), metoda wywołuje wszystkie zmiany bazy danych od najnowszego nienazwanego punktu zapisu (najnowsze wywołanie metody setSavepoint() bez wartości parametru name).

Jeśli określono wartość dla parametru name, ta metoda wycofuje wszystkie operacje SQL wykonywane od czasu punktu zapisu o określonej nazwie. Jeśli inne punkty zapisu są nowsze niż wybrany punkt zapisu, wówczas operacje wykonywane po tych punktach zapisu również zostaną wycofane.

Po zwolnieniu lub wycofaniu punktu zapisu następuje usunięcie tego punktu oraz punktów nowszych niż on. Jeśli kod wykona dodatkowe operacje SQL, gdy metoda releaseSavepoint() lub rollbackToSavepoint() usunie punkt zapisu, wówczas te operacje będą należały do najnowszego pozostałego punktu zapisu. (Innymi słowy — będą należały do najnowszego punktu zapisu przed usuniętym punktem zapisu). Jeśli nie pozostaną żadne punkty zapisu, operacje będą należały do transakcji głównej.

Parametry

Powiązane elementy interfejsu API

Tworzy punkt zapisu, który pełni rolę zakładki w transakcji bazy danych. Punkt zapisu reprezentuje punkt w transakcji. Zestaw operacji SQL wykonanych między punktami zapisu może zostać zatwierdzony lub odrzucony (bez wpływu na inne operacje) za pomocą metodreleaseSavepoint() i rollbackToSavepoint(). W ten sposób korzystanie z punktów zapisu umożliwia traktowanie zestawu operacji SQL jako zagnieżdżonej transakcji.

Jeśli metoda setSavepoint() została wywołana, a transakcja nie została jeszcze otwarta (poprzez wywołanie metody begin()), wówczas wywołanie metody rozpoczyna transakcję i zapisuje punkt zapisu na początku transakcji. Jeśli transakcja jest już otwarta, wywołanie metody setSavepoint() powoduje zapisanie punktu zapisu w transakcji.

Należy zauważyć, że do czasu zatwierdzenia całej transakcji zmiany nie będą trwale zapisywane w bazie danych. Jeśli transakcja jest uruchamiana za pomocą metody begin(), należy wywołać metodę commit() w celu zatwierdzenia całej transakcji. Jeśli transakcja została uruchomiona poprzez wywołanie metody setSavepoint(), a parametr inTransaction ma wartość false, wówczas całą transakcję można zakończyć poprzez wywołanie metody commit(). Transakcja zostanie również zakończona automatycznie w przypadku wywołania metody releaseSavepoint() lub metody rollbackToSavepoint() dla punktu zapisu, który uruchomił transakcję.

Nazwę dla punktu zapisu można określić poprzez wprowadzenie wartości dla parametru name. Dzięki temu możliwe będzie zatwierdzenie lub wycofanie wszystkich zmian wprowadzonych od czasu punktu zapisu. Jeśli nie określono żadnej nazwy (domyślnie), wówczas tworzony jest nienazwany punkt zapisu.

Po zwolnieniu lub wycofaniu punktu zapisu następuje usunięcie tego punktu oraz punktów nowszych niż on. Jeśli kod wykona dodatkowe operacje SQL, gdy metoda releaseSavepoint() lub rollbackToSavepoint() usunie punkt zapisu, wówczas te operacje będą należały do najnowszego pozostałego punktu zapisu. (Innymi słowy — będą należały do najnowszego punktu zapisu przed usuniętym punktem zapisu). Jeśli nie pozostaną żadne punkty zapisu, operacje będą należały do transakcji głównej.

Parametry

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody analyze() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody attach() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody begin() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody cancel() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody close() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody commit() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody compact() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody deanalyze() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy dane w jednej z tabel w którejkolwiek z podłączonych baz danych zostaną zmienione wyniku wykonania instrukcji DELETE języka SQL. Zmiana danych może być bezpośrednim wynikiem instrukcji DELETE wykonanej przez instancję klasy SQLStatement lub pośrednim wynikiem wywołanym działaniem wyzwalacza w odpowiedzi na wykonanie instrukcji.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody detach() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy którakolwiek z asynchronicznych operacji obiektu SQLConnection zakończy się błędem. Instancja klasy SQLErrorEvent wywołana jako obiekt zdarzenia ma właściwość error zawierającą informacje o wykonywanej operacji i przyczynie jej niepowodzenia.

Wywoływane, gdy dane w jednej z tabel w którejkolwiek z podłączonych baz danych zostaną zmienione wyniku wykonania instrukcji INSERT języka SQL. Zmiana danych może być bezpośrednim wynikiem instrukcji INSERT wykonanej przez instancję klasy SQLStatement lub pośrednim wynikiem spowodowanym działaniem wyzwalacza w odpowiedzi na wykonanie instrukcji.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody openAsync() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody reencrypt() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody releaseSavepoint() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody rollback() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody rollbackToSavepoint() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody loadSchema() zakończy się pomyślnie, a wyniki schematu są gotowe.

Powiązane elementy interfejsu API

Wywoływane, gdy operacja wywołania metody setSavepoint() zakończy się pomyślnie.

Powiązane elementy interfejsu API

Wywoływane, gdy dane w jednej z tabel w którejkolwiek z podłączonych baz danych zostaną zmienione wyniku wykonania instrukcji UPDATE języka SQL. Zmiana danych może być bezpośrednim wynikiem instrukcji UPDATE wykonanej przez instancję klasy SQLStatement lub pośrednim wynikiem wywołanym działaniem wyzwalacza w odpowiedzi na wykonanie instrukcji.

Zdarzenie update ma następujące właściwości:

Powiązane elementy interfejsu API