ICellRenderer - Adobe ActionScript® 3 (AS3 Flash)

Pakiet	fl.controls.listClasses
Interfejs	public interface ICellRenderer
Implementory	CellRenderer, DataGridCellEditor, ImageCell

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Interfejs ICellRenderer udostępnia metody i właściwości wymagane przez mechanizm renderujący komórki. Wszystkie zdefiniowane przez użytkownika mechanizmy renderujące komórki powinny implementować ten interfejs. Wszystkie zdefiniowane przez użytkownika mechanizmy renderujące komórki muszą rozszerzać klasę UIComponent albo jej podklasę.

Wyświetl przykłady

Powiązane elementy interfejsu API

CellRenderer

Właściwości publiczne

	Właściwość		Zdefiniowane przez
		data : Object Pobiera lub ustawia obiekt (klasy Object) reprezentujący dane skojarzone ze składnikiem.	ICellRenderer
		listData : ListData Pobiera lub ustawia właściwości listy zastosowane do komórki, np. wartości index i selected.	ICellRenderer
		selected : Boolean Pobiera lub ustawia wartość typu Boolean wskazującą, czy bieżąca komórka jest zaznaczona.	ICellRenderer
		x : Number [tylko do zapisu] Ustawia współrzędną x mechanizmu renderującego komórkę.	ICellRenderer
		y : Number [tylko do zapisu] Ustawia współrzędną y mechanizmu renderującego komórkę	ICellRenderer

Metody publiczne

	Metoda		Zdefiniowane przez
		setMouseState(state:String):void Ustawia konkretny stan myszy dla bieżącej komórki.	ICellRenderer
		setSize(width:Number, height:Number):void Ustawia wielkość danych według wartości w pikselach, podanych w parametrach szerokości i wysokości.	ICellRenderer

Szczegół właściwości

data	właściwość

data:Object

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera lub ustawia obiekt (klasy Object) reprezentujący dane skojarzone ze składnikiem. Ustawienie tej wartości powoduje zapisanie danych składnika i unieważnienie zawierającego je składnika. Unieważniony składnik jest wówczas automatycznie ponownie rysowany.

Właściwość data reprezentuje obiekt zawierający element w obiekcie DataProvider, który reprezentuje dana komórka. Zwykle właściwość data zawiera standardowe właściwości, w zależności od typu składnika. W obiekcie CellRenderer składnika List lub ComboBox dane zawierają właściwości label, icon i data; w przypadku składnika TileList: właściwości label i source; komórka DataGrid zawiera wartości dla poszczególnych kolumn. Właściwość data może także zawierać dane określone przez użytkownika mające związek z określoną komórką. Użytkownicy mogą rozszerzać klasę CellRenderer, aby składnik przy renderowaniu komórki używał innych właściwości danych.

Ponadto możliwe jest użycie elementów labelField, labelFunction, iconField, iconFunction, sourceField i sourceFunction do określenia właściwości używanych do rysowania odpowiednio etykiety, ikony i źródła.

Implementacja
public function get data():Object
public function set data(value:Object):void

listData

właściwość

listData:ListData

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera lub ustawia właściwości listy zastosowane do komórki, np. wartości index i selected. Te właściwości listy są automatycznie aktualizowane po unieważnieniu komórki.

Implementacja
public function get listData():ListData
public function set listData(value:ListData):void

selected

właściwość

selected:Boolean

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Pobiera lub ustawia wartość typu Boolean wskazującą, czy bieżąca komórka jest zaznaczona. Wartość true oznacza, że komórka jest zaznaczona; wartość false oznacza, że nie jest.

Implementacja
public function get selected():Boolean
public function set selected(value:Boolean):void

x

właściwość

x:Number [tylko do zapisu]

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Ustawia współrzędną x mechanizmu renderującego komórkę

Implementacja
public function set x(value:Number):void

y

właściwość

y:Number [tylko do zapisu]

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Ustawia współrzędną y mechanizmu renderującego komórkę.

Implementacja
public function set y(value:Number):void

Szczegół metody

setMouseState

()

metoda

public function setMouseState(state:String):void

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Ustawia konkretny stan myszy dla bieżącej komórki. Ta metoda umożliwia składnikowi DataGrid ustawienie stan myszy dla całego wiersza komórek, gdy użytkownik operuje na jednej komórce.

Parametry

state:String — Ciąg znaków określający stan myszy, np. "up" lub "over".

setSize

()

metoda

public function setSize(width:Number, height:Number):void

Wersja języka:

ActionScript 3.0

Wersja produktu:

Flash CS3

Wersje środowiska wykonawczego:

Flash Player 9.0.28.0, AIR 1.0

Określa rozmiar danych zgodnie z liczbą pikseli określoną w parametrach width i height.

Parametry

	`width:Number` — Szerokość wyświetlania mechanizmu renderującego w pikselach.

	`height:Number` — Wysokość wyświetlania mechanizmu renderującego w pikselach.

Przykłady Sposób korzystania z tego przykładu

ICellRendererExample.as

Ten przykład ilustruje tworzenie niestandardowego mechanizmu renderującego komórki poprzez zaimplementowanie klasy ICellRenderer.

W celu uruchomienia przykładu należy wykonać poniższe czynności:

Dodaj składniki List i Button do biblioteki.
Zapisz ten kod pod nazwą ICellRendererExample.as w tym samym katalogu, co plik FLA.
W pliku FLA ustaw klasę dokumentu na ICellRendererExample.

package
{ 
    import fl.controls.List;
    import fl.data.DataProvider;
    import fl.events.ListEvent;
    import flash.display.Sprite;
    import flash.events.Event;
    
    public class ICellRendererExample extends Sprite
    {
        public function ICellRendererExample() {
            var dp:DataProvider = new DataProvider();
            var totalEntries:Number = 42;
            var i:Number;
            for(i=0; i<totalEntries; i++) {
                dp.addItem( { label:Math.random(), data:null } );            
            }
            
            var myList = new List();
            myList.setSize(300,300);
            myList.move(10,10);
            myList.setStyle('cellRenderer', MyRenderer);    
            myList.dataProvider = dp;
            addChild(myList);
        }
    }
}

MyRenderer.as

Zapisz następujący kod pod nazwą MyRenderer.as w tym samym katalogu, co plik FLA.

package
{
    import fl.controls.LabelButton;
    import fl.controls.listClasses.ICellRenderer;
    import fl.controls.listClasses.ListData;
    
    public class MyRenderer extends LabelButton implements ICellRenderer {
        private var _listData:ListData;
        private var _data:Object;
        
        public function MyRenderer() {
        }

        public function set listData(newListData:ListData):void {
            _listData = newListData;
            label = "Random: " + _listData.label;
            drawRandomColor();
        }

        private function drawRandomColor():void {
            graphics.beginFill(Math.random()*0xFFFFFF);
            graphics.drawRect(0,0,20,20);
            graphics.endFill();            
        }

        public function get listData():ListData {
            return _listData;
        }

        public function set data(newData:Object):void {
            _data = newData;
        }

        public function get data():Object {
            return _data;
        }
    }
}

Informacje prawne | Zasady prywatności online

ICellRenderer - AS3 Flash

Klasy x

data

listData

selected

x

y

setMouseState

setSize