RadioButtonGroup

Pakket	fl.controls
Klasse	public class RadioButtonGroup
Overerving	RadioButtonGroup EventDispatcher Object

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

De klasse RadioButtonGroup definieert een groep componenten RadioButton om als een enkele component te fungeren. Wanneer één keuzerondje is ingeschakeld, kunnen geen andere keuzerondjes uit dezelfde groep worden ingeschakeld.

Bekijk de voorbeelden

Verwante API-elementen

RadioButton
RadioButton.group

Openbare eigenschappen

Overerfde openbare eigenschappen verbergen

Overerfde openbare eigenschappen weergeven

	Eigenschap		Gedefinieerd door
		constructor : Object Verwijzing naar het klasseobject of de constructorfunctie van een bepaalde objectinstantie.	Object
		name : String [alleen-lezen] Hiermee wordt de instantienaam van het keuzerondje opgehaald.	RadioButtonGroup
		numRadioButtons : int [alleen-lezen] Hiermee wordt het aantal keuzerondjes in deze groep keuzerondjes opgehaald.	RadioButtonGroup
		selectedData : Object Hiermee wordt de eigenschap value van het geselecteerde keuzerondje opgehaald of ingesteld.	RadioButtonGroup
		selection : RadioButton Hiermee wordt een verwijzing opgehaald of ingesteld naar het keuzerondje dat momenteel is geselecteerd in de groep keuzerondjes.	RadioButtonGroup

Openbare methoden

Overerfde openbare methoden verbergen

Overerfde openbare methoden weergeven

	Methode		Gedefinieerd door
		RadioButtonGroup(name:String) Hiermee wordt een nieuwe instantie RadioButtonGroup gemaakt.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registreert een gebeurtenislistenerobject bij een object EventDispatcher, zodat de listener een melding van een gebeurtenis ontvangt.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Hiermee wordt een keuzerondje aan de interne array van keuzerondjes toegevoegd voor het indexeren van een groep keuzerondjes om één keuzerondje in een groep keuzerondjes te kunnen selecteren.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Verzendt een gebeurtenis naar de gebeurtenisstroom.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [statisch] Hiermee wordt een verwijzing naar de opgegeven groep keuzerondjes opgehaald.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Hiermee wordt de component RadioButton bij de opgegeven index opgehaald.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Retourneert naar de index van de opgegeven instantie RadioButton.	RadioButtonGroup
		hasEventListener(type:String):Boolean Controleert of het object EventDispatcher listeners heeft geregistreerd voor een specifiek type gebeurtenis.	EventDispatcher
		hasOwnProperty(name:String):Boolean Geeft aan of voor een object een opgegeven eigenschap is gedefinieerd.	Object
		isPrototypeOf(theClass:Object):Boolean Geeft aan of een instantie van de klasse Object zich in de prototypeketen van het object bevindt dat als parameter is opgegeven.	Object
		propertyIsEnumerable(name:String):Boolean Geeft aan of de opgegeven eigenschap bestaat en kan worden opgesomd.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Verwijdert een listener uit het object EventDispatcher.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Hiermee wordt de instantie RadioButton uit de interne lijst met keuzerondjes gewist.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Stelt de beschikbaarheid van een dynamische eigenschap voor lusbewerkingen in.	Object
		toLocaleString():String Geeft de tekenreeksweergave van dit object weer, geformatteerd volgens de locatiespecifieke conventies.	Object
		toString():String Retourneert een tekenreeksrepresentatie van het opgegeven object.	Object
		valueOf():Object Retourneert de primitieve waarde van het opgegeven object.	Object
		willTrigger(type:String):Boolean Controleert of een gebeurtenislistener is geregistreerd bij dit object EventDispatcher of een van de voorouders voor het opgegeven type gebeurtenis.	EventDispatcher

Gebeurtenissen

Klik voor meer informatie over gebeurtenissen.

Overerfde gebeurtenissen verbergen

Overerfde gebeurtenissen weergeven

	Overzicht	Gedefinieerd door
activate	[uitgezonden gebeurtenis] Wordt verzonden wanneer Flash Player of de AIR-toepassing de besturingssysteemfocus krijgt en actief wordt.	EventDispatcher
change	Wordt verzonden wanneer de geselecteerde instantie RadioButton in een groep wordt gewijzigd.	RadioButtonGroup
click	Wordt verzonden wanneer op een instantie RadioButton wordt geklikt.	RadioButtonGroup
deactivate	[uitgezonden gebeurtenis] Wordt verzonden wanneer Flash Player of de AIR-toepassing de systeemfocus verliest en inactief wordt.	EventDispatcher

Eigenschapdetails

name	eigenschap

name:String [alleen-lezen]

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt de instantienaam van het keuzerondje opgehaald.

De standaardwaarde is "RadioButtonGroup".

Implementatie
public function get name():String

numRadioButtons

eigenschap

numRadioButtons:int [alleen-lezen]

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt het aantal keuzerondjes in deze groep keuzerondjes opgehaald.

De standaardwaarde is 0.

Implementatie
public function get numRadioButtons():int

selectedData

eigenschap

selectedData:Object

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt de eigenschap value van het geselecteerde keuzerondje opgehaald of ingesteld. Wanneer momenteel geen keuzerondje is geselecteerd, is deze eigenschap null.

Implementatie
public function get selectedData():Object
public function set selectedData(value:Object):void

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld wordt een nieuwe instantie van de component RadioButtonGroup gemaakt en wordt geluisterd naar de gebeurtenis change van de component:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

eigenschap

selection:RadioButton

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt een verwijzing opgehaald of ingesteld naar het keuzerondje dat momenteel is geselecteerd in de groep keuzerondjes.

Implementatie
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld wordt een nieuwe groep met keuzerondjes gemaakt die twee keuzerondjes bevat. Wanneer de instelling van het geselecteerde keuzerondje verandert, worden het label en de waarde van het keuzerondje getraceerd:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Constructordetails

()

Constructor

public function RadioButtonGroup(name:String)

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt een nieuwe instantie RadioButtonGroup gemaakt. Dit gebeurt meestal automatisch wanneer een keuzerondje wordt geïnstantieerd.

Parameters

name:String — De naam van de groep keuzerondjes.

Methodedetails

addRadioButton

()

methode

public function addRadioButton(radioButton:RadioButton):void

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt een keuzerondje aan de interne array van keuzerondjes toegevoegd voor het indexeren van een groep keuzerondjes om één keuzerondje in een groep keuzerondjes te kunnen selecteren. Deze methode wordt automatisch gebruikt door keuzerondjes, maar kan ook handmatig worden gebruikt om een keuzerondje expliciet aan een groep toe te voegen.

Parameters

radioButton:RadioButton — De instantie van RadioButton die aan de huidige groep met keuzerondjes moet worden toegevoegd.

getGroup

()

methode

public static function getGroup(name:String):RadioButtonGroup

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt een verwijzing naar de opgegeven groep keuzerondjes opgehaald.

Parameters

name:String — De naam van de groep waarvoor een verwijzing moet worden opgehaald.

Geretourneerde waarde

RadioButtonGroup — Een verwijzing naar de opgegeven RadioButtonGroup.

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld wordt getoond hoe u bepaalt welk keuzerondje in een groep is geselecteerd:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

methode

public function getRadioButtonAt(index:int):RadioButton

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt de component RadioButton bij de opgegeven index opgehaald.

Parameters

index:int — De index van de component RadioButton in de component RadioButtonGroup, waarbij de index van de eerste component 0 is.

Geretourneerde waarde

RadioButton — De opgegeven component RadioButton.

Gegenereerde uitzondering

RangeError — De opgegeven index is kleiner dan 0 of groter dan of gelijk aan de lengte van de gegevensaanbieder.

getRadioButtonIndex

()

methode

public function getRadioButtonIndex(radioButton:RadioButton):int

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Retourneert naar de index van de opgegeven instantie RadioButton.

Parameters

radioButton:RadioButton — De instantie RadioButton die wordt gezocht in de huidige RadioButtonGroup.

Geretourneerde waarde

int — De index van de opgegeven component RadioButton, of -1 wanneer de opgegeven RadioButton niet kan worden gevonden.

removeRadioButton

()

methode

public function removeRadioButton(radioButton:RadioButton):void

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Hiermee wordt de instantie RadioButton uit de interne lijst met keuzerondjes gewist.

Parameters

radioButton:RadioButton — De instantie RadioButton die u wilt verwijderen.

Gebeurtenisdetails

change

Gebeurtenis

Type gebeurtenisobject: flash.events.Event
eigenschap Event.type = flash.events.Event.CHANGE

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Wordt verzonden wanneer de geselecteerde instantie RadioButton in een groep wordt gewijzigd.

De constante Event.CHANGE definieert de waarde van de eigenschap type van een change-gebeurtenisobject.

Deze gebeurtenis heeft de volgende eigenschappen:

Eigenschap	Waarde
`bubbles`	`true`
`cancelable`	`false`; er is geen standaardgedrag om te annuleren.
`currentTarget`	Het object dat het gebeurtenisobject actief verwerkt met een gebeurtenislistener.
`target`	Het object waarvan de waarde is gewijzigd. Het `target` is niet altijd het object in het weergaveoverzicht dat in de gebeurtenislistener is geregistreerd. Gebruik de eigenschap `currentTarget` voor toegang tot het object in het weergaveoverzicht dat momenteel de gebeurtenis verwerkt.

Voorbeeld ( Hoe dit voorbeeld te gebruiken )

In het volgende voorbeeld worden drie keuzerondjes gemaakt en wordt een gebeurtenislistener toegevoegd voor de gebeurtenis change van de groep van een keuzerondje:

import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Gebeurtenis

Type gebeurtenisobject: flash.events.MouseEvent
eigenschap MouseEvent.type = flash.events.MouseEvent.CLICK

Taalversie:

ActionScript 3.0

Productversie:

Flash CS3

Runtimeversies:

Flash Player 9.0.28.0, AIR 1.0

Wordt verzonden wanneer op een instantie RadioButton wordt geklikt.

Definieert de waarde van de eigenschap type van een gebeurtenisobject click.

Deze gebeurtenis heeft de volgende eigenschappen:

Eigenschap	Waarde
`altKey`	`true` als de Alt-toets actief is (Windows).
`bubbles`	`true`
`buttonDown`	Voor klikgebeurtenissen is deze waarde altijd `false`.
`cancelable`	`false`; er is geen standaardgedrag om te annuleren.
`commandKey`	`true` op de Macintosh als de Command-toets actief is; `false` als deze inactief is. Altijd `false` onder Windows.
`controlKey`	`true` wanneer de Ctrl- of Control-toets actief is of `false` wanneer deze inactief is.
`ctrlKey`	`true` onder Windows of Linux als de Ctrl-toets actief is. `true` op de Macintosh als de Ctrl-toets of Command-toets actief is. Anders is deze `false`.
`currentTarget`	Het object dat het gebeurtenisobject actief verwerkt met een gebeurtenislistener.
`localX`	De horizontale coördinaat waar de gebeurtenis heeft plaatsgevonden ten opzichte van de omvattende sprite, indien de muisvergrendeling is uitgeschakeld.
`localY`	De verticale coördinaat waar de gebeurtenis heeft plaatsgevonden ten opzichte van de omvattende sprite, indien de muisvergrendeling is uitgeschakeld.
`movementX`	De verandering in de horizontale coördinaten van de muispositie sinds de laatste muisgebeurtenis, indien de muisvergrendeling is uitgeschakeld.
`movementY`	De verandering in de verticale coördinaten van de muispositie sinds de laatste muisgebeurtenis, indien de muisvergrendeling is uitgeschakeld.
`shiftKey`	`true` wanneer de Shift-toets actief is of `false` wanneer deze inactief is.
`stageX`	De horizontale coördinaat waar de gebeurtenis heeft plaatsgevonden in algemene werkgebiedcoördinaten.
`stageY`	De verticale coördinaat waar de gebeurtenis heeft plaatsgevonden in algemene werkgebiedcoördinaten.
`target`	De instantie InteractiveObject onder het aanwijsapparaat. Het `target` is niet altijd het object in het weergaveoverzicht dat in de gebeurtenislistener is geregistreerd. Gebruik de eigenschap `currentTarget` voor toegang tot het object in het weergaveoverzicht dat momenteel de gebeurtenis verwerkt.

Voorbeelden Hoe dit voorbeeld te gebruiken

RadioButtonGroupExample.as

In het volgende voorbeeld wordt getoond hoe u vele RadioButton-objecten over diverse groepen beheert.

Voeg de componenten RadioButton en Label toe aan uw bibliotheek.
Sla deze code op als RadioButtonGroupExample.as in dezelfde map als de FLA.
Stel de DocumentClass in de FLA in op RadioButtonGroupExample.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Juridische kennisgeving | Online privacybeleid

RadioButtonGroup - AS3 Flash

Pakkettenx

Taalelementen

Bijlagen

Pakket fl.controls

name

numRadioButtons

selectedData

selection