LinkElement  - AS3

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.LinkElement;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.formats.TextLayoutFormat;
    
    public class LinkElementExample extends Sprite
    {
        public function LinkElementExample()
        {
            var textFlow:TextFlow = new TextFlow();
            var textLayoutFormat:TextLayoutFormat = new TextLayoutFormat();
          
            textLayoutFormat.fontFamily = "Arial, Helvetica, _sans";
            textLayoutFormat.fontSize = 18;
            textFlow.hostFormat = textLayoutFormat;

            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var link:LinkElement = new LinkElement();
            var span2:SpanElement = new SpanElement();
            var inf:Object = {color:0xFF0000};   
            p.linkHoverFormat = inf;
            span1.text = "Text that includes a link to "; 
            link.href = "http://www.adobe.com";
            var linkSpan:SpanElement = new SpanElement();
            linkSpan.text = "Adobe's website";
            link.addChild(linkSpan);
            span2.text = ". Notice the custom formatting when the cursor hovers " + 
                    "over the link.";
            p.addChild(span1);
            p.addChild(link);
            p.addChild(span2);
            textFlow.addChild(p);
            textFlow.flowComposer.addController(new ContainerController(this,stage.stageWidth, stage.stageHeight));
            textFlow.flowComposer.updateAllControllers();
        }
    }
}

package flashx.textLayout.elements.examples
{
    import flash.display.Sprite;
    
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.LinkElement;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.events.FlowElementMouseEvent;
    import flashx.textLayout.formats.TextLayoutFormat;
    
    public class LinkElementEventExample extends Sprite
    {
        public function LinkElementEventExample()
        {
            var textFlow:TextFlow = new TextFlow();
          
            textFlow.fontFamily = "Arial, Helvetica, _sans";
            textFlow.fontSize = 18;
            textFlow.paddingLeft = textFlow.paddingRight = textFlow.paddingTop = 20;

            var p:ParagraphElement = new ParagraphElement();
            var span1:SpanElement = new SpanElement();
            var link:LinkElement = new LinkElement();
            var span2:SpanElement = new SpanElement();
            span1.text = "Text that includes a link to "; 
            link.href = "event:changeTextFlowColor";
            var linkSpan:SpanElement = new SpanElement();
            linkSpan.text = "custom event code"
            link.addChild(linkSpan);
            span2.text = ". Clicking the link changes the default color of the TextFlow";
            p.addChild(span1);
            p.addChild(link);
            p.addChild(span2);
            textFlow.addChild(p);
            textFlow.flowComposer.addController(new ContainerController(this,stage.stageWidth, stage.stageHeight));
            textFlow.flowComposer.updateAllControllers();
            textFlow.addEventListener("changeTextFlowColor",changeTextFlowColor)
        }

        private function changeTextFlowColor(e:FlowElementMouseEvent):void
        {
            var textFlow:TextFlow = e.flowElement.getTextFlow();
            textFlow.color = textFlow.color == 0x00ff00 ? 0 : 0x00ff00;
            textFlow.flowComposer.updateAllControllers();
        }
    }
}