TextFormat

패키지	flash.text
클래스	public class TextFormat
상속	TextFormat Object
하위 클래스	UITextFormat

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9, Flash Lite 4

TextFormat 클래스는 문자 서식 정보를 나타냅니다. TextFormat 클래스를 사용하면 텍스트 필드에 특정 텍스트 서식을 만들 수 있습니다. 정적 텍스트 필드와 동적 텍스트 필드 모두에 텍스트 서식을 적용할 수 있습니다. TextFormat 클래스의 속성은 장치 글꼴과 포함된 글꼴에 모두 적용됩니다. 그러나 포함된 글꼴의 경우 굵은 텍스트나 기울임체 텍스트를 표현하려면 실제로는 특수 글꼴이 필요합니다. 포함된 글꼴을 사용하여 굵은 텍스트나 기울임체 텍스트를 표시하려면 해당 글꼴을 굵게 변형한 글꼴과 기울임체로 변형한 글꼴을 포함시켜야 합니다.

TextFormat 객체의 속성을 설정하려면 먼저 new TextFormat() 생성자를 사용하여 이 객체를 만들어야 합니다. TextField.defaultTextFormat 속성이나 TextField.setTextFormat() 메서드를 사용하여 텍스트 필드에 TextFormat 객체를 적용할 때는 정의된 속성만 적용됩니다. TextField.defaultTextFormat 속성을 사용하여 서식을 적용한 후 TextField에 텍스트를 추가해야 하고, setTextFormat() 메서드를 사용하여 서식을 추가하기 전에 TextField에 텍스트를 추가해야 합니다. TextFormat 속성에 값을 지정하지 않으면 Flash Player의 자체 기본 서식이 사용되므로 이 속성의 기본값은 null입니다. 속성의 값이 null인 경우 Flash Player에서 각 속성에 사용하는 기본 서식은 다음과 같습니다.

align = "left"

blockIndent = 0

bold = false

bullet = false

color = 0x000000

font = "Times New Roman"(Mac OS X의 경우 기본 글꼴은 Times)

indent = 0

italic = false

kerning = false

leading = 0

leftMargin = 0

letterSpacing = 0

rightMargin = 0

size = 12

tabStops = [] (빈 배열)

target = "" (빈 문자열)

underline = false

url = "" (빈 문자열)

각 속성의 기본 서식은 각 속성 설명 부분에도 나와 있습니다.

예제 보기

공용 속성

상속되는 공용 속성 숨기기

상속되는 공용 속성 표시

	속성		정의 주체
		align : String 단락의 정렬을 나타냅니다.	TextFormat
		blockIndent : Object 블록 들여쓰기를 픽셀 단위로 나타냅니다.	TextFormat
		bold : Object 텍스트를 굵게 표시할지 여부를 지정합니다.	TextFormat
		bullet : Object 텍스트가 불릿 목록의 일부임을 나타냅니다.	TextFormat
		color : Object 텍스트의 색상을 나타냅니다.	TextFormat
		constructor : Object 지정된 객체 인스턴스의 클래스 객체 또는 생성자 함수에 대한 참조입니다.	Object
		font : String 이 텍스트 서식의 텍스트 글꼴 이름을 나타내는 문자열입니다.	TextFormat
		indent : Object 왼쪽 여백에서 단락의 첫 문자 사이의 들여쓰기를 나타냅니다.	TextFormat
		italic : Object 이 텍스트 서식의 텍스트가 기울임체인지 여부를 나타냅니다.	TextFormat
		kerning : Object 자간의 활성화 여부를 true 또는 false로 나타내는 부울 값입니다.	TextFormat
		leading : Object 행 사이의 세로 간격(행간)을 나타내는 정수입니다.	TextFormat
		leftMargin : Object 단락의 왼쪽 여백(픽셀 단위)입니다.	TextFormat
		letterSpacing : Object 모든 문자 사이에 균등하게 분배되는 간격을 나타내는 수입니다.	TextFormat
		rightMargin : Object 단락의 오른쪽 여백(픽셀 단위)입니다.	TextFormat
		size : Object 이 텍스트 서식에서 텍스트의 픽셀 크기입니다.	TextFormat
		tabStops : Array 사용자 정의 탭 정지를 음이 아닌 정수의 배열로 지정합니다.	TextFormat
		target : String 하이퍼링크가 표시되는 대상 윈도우를 나타냅니다.	TextFormat
		underline : Object 이 텍스트 서식을 사용하는 텍스트에 밑줄을 그을지 여부를 true 또는 false로 나타냅니다.	TextFormat
		url : String 이 텍스트 서식의 텍스트에 대한 대상 URL을 나타냅니다.	TextFormat

공용 메서드

상속되는 공용 메서드 숨기기

상속되는 공용 메서드 표시

	메서드		정의 주체
		TextFormat(font:String = null, size:Object = null, color:Object = null, bold:Object = null, italic:Object = null, underline:Object = null, url:String = null, target:String = null, align:String = null, leftMargin:Object = null, rightMargin:Object = null, indent:Object = null, leading:Object = null) 지정된 속성으로 TextFormat 객체를 만듭니다.	TextFormat
		hasOwnProperty(name:String):Boolean 지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.	Object
		isPrototypeOf(theClass:Object):Boolean Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.	Object
		propertyIsEnumerable(name:String):Boolean 지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.	Object
		toLocaleString():String 로캘별 규칙에 따라 서식이 지정된 이 객체의 문자열 표현을 반환합니다.	Object
		toString():String 지정된 객체의 문자열 표현을 반환합니다.	Object
		valueOf():Object 지정된 객체의 프리미티브 값을 반환합니다.	Object

속성 세부 정보

align

속성

align:String

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

단락의 정렬을 나타냅니다. TextFormatAlign 상수 값을 사용할 수 있습니다.

기본값: TextFormatAlign.LEFT.

구현
public function get align():String
public function set align(value:String):void

오류

ArgumentError — 지정된 align이 flash.text.TextFormatAlign의 멤버가 아닙니다.

관련 API 요소

flash.text.TextFormatAlign

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

blockIndent

속성

blockIndent:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

블록 들여쓰기를 픽셀 단위로 나타냅니다. 블록 들여쓰기는 텍스트 블록 전체 즉, 모든 텍스트 행에 적용됩니다. 반대로, 일반 들여쓰기(TextFormat.indent)는 각 단락의 첫 행에만 적용됩니다. 이 속성이 null이면 TextFormat 객체는 블록 들여쓰기를 지정하지 않습니다. 즉, 블록 들여쓰기가 0으로 설정됩니다.

구현
public function get blockIndent():Object
public function set blockIndent(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

bold

속성

bold:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

텍스트를 굵게 표시할지 여부를 지정합니다. 기본값은 텍스트를 굵게 표시하지 않는 null입니다. 이 값이 true이면 텍스트가 굵은체로 표시됩니다.

구현
public function get bold():Object
public function set bold(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

bullet

속성

bullet:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

텍스트가 불릿 목록의 일부임을 나타냅니다. 불릿 목록에서 텍스트의 각 단락을 들여쓰고, 각 단락의 첫 줄 왼쪽에 불릿 기호를 표시합니다. 기본값은 불릿 목록을 사용하지 않는 null입니다.

구현
public function get bullet():Object
public function set bullet(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

color

속성

color:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

텍스트의 색상을 나타냅니다. 세 개의 8비트 RGB 구성 요소를 포함하는 숫자입니다. 예를 들어 0xFF0000은 빨강이고 0x00FF00은 녹색입니다. 기본값은 null입니다. 이 경우 Flash Player에서 검은색(0x000000)이 사용됩니다.

구현
public function get color():Object
public function set color(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

font

속성

font:String

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

이 텍스트 서식의 텍스트 글꼴 이름을 나타내는 문자열입니다. 기본값은 null입니다. 이 경우 Flash Player에서 텍스트에 Times New Roman 글꼴이 사용됩니다.

구현
public function get font():String
public function set font(value:String):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

indent

속성

indent:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

왼쪽 여백에서 단락의 첫 문자 사이의 들여쓰기를 나타냅니다. 기본값은 들여쓰기를 사용하지 않는 null입니다.

구현
public function get indent():Object
public function set indent(value:Object):void

관련 API 요소

flash.text.TextFormat.blockIndent

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

italic

속성

italic:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

이 텍스트 서식의 텍스트가 기울임체인지 여부를 나타냅니다. 기본값은 기울임체를 사용하지 않는 null입니다.

구현
public function get italic():Object
public function set italic(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

kerning

속성

kerning:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9.

자간의 활성화 여부를 true 또는 false로 나타내는 부울 값입니다. 자간을 사용하면 텍스트의 가독성을 높이기 위해 특정 문자 쌍 사이의 픽셀이 조정됩니다. 큰 글꼴의 머리글과 같이 필요한 경우에만 자간을 사용하는 것이 좋습니다. 자간은 포함된 글꼴에만 지원됩니다.

Verdana 같은 일부 글꼴과 Courier New 같은 단일 간격 글꼴은 자간을 지원하지 않습니다.

기본값은 자간을 사용하지 않는 null입니다.

구현
public function get kerning():Object
public function set kerning(value:Object):void

leading

속성

leading:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

행 사이의 세로 간격(행간)을 나타내는 정수입니다. 기본값은 행간이 0임을 나타내는 null입니다.

구현
public function get leading():Object
public function set leading(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

leftMargin

속성

leftMargin:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

단락의 왼쪽 여백(픽셀 단위)입니다. 기본값은 왼쪽 여백이 0픽셀임을 나타내는 null입니다.

구현
public function get leftMargin():Object
public function set leftMargin(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

letterSpacing

속성

letterSpacing:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9.

모든 문자 사이에 균등하게 분배되는 간격을 나타내는 수입니다. 값은 각 문자 뒤에 추가되는 픽셀의 수를 지정합니다. 기본값은 문자 간격으로 0 픽셀이 사용됨을 나타내는 null입니다. 1.75와 같은 소수를 사용할 수 있습니다.

구현
public function get letterSpacing():Object
public function set letterSpacing(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

rightMargin

속성

rightMargin:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

단락의 오른쪽 여백(픽셀 단위)입니다. 기본값은 오른쪽 여백이 0픽셀임을 나타내는 null입니다.

구현
public function get rightMargin():Object
public function set rightMargin(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

size

속성

size:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

이 텍스트 서식에서 텍스트의 픽셀 크기입니다. 기본값은 크기가 12임을 나타내는 null입니다.

구현
public function get size():Object
public function set size(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

tabStops

속성

tabStops:Array

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

사용자 정의 탭 정지를 음이 아닌 정수의 배열로 지정합니다. 각 탭 위치는 픽셀 단위로 지정됩니다. 사용자 정의 탭 정지가 지정되지 않은 경우(null) 기본 탭 정지는 평균 문자 폭인 4입니다.

구현
public function get tabStops():Array
public function set tabStops(value:Array):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

target

속성

target:String

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

하이퍼링크가 표시되는 대상 윈도우를 나타냅니다. 대상 윈도우가 빈 문자열이면 텍스트는 기본 대상 윈도우 _self에 표시됩니다. 사용자 정의 이름을 선택하거나 다음 네 개의 이름 중 하나를 선택할 수 있습니다. _self는 현재 윈도우의 현재 프레임을 지정하고, _blank는 새로운 윈도우를 지정하고, _parent는 현재 프레임의 부모를 지정하고, _top은 현재 윈도우의 최상위 프레임을 지정합니다. TextFormat.url 속성이 빈 문자열이거나 null이면 이 속성을 가져오거나 설정할 수는 있지만 아무 효과도 없습니다.

구현
public function get target():String
public function set target(value:String):void

관련 API 요소

flash.text.TextFormat.url

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

underline

속성

underline:Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

이 텍스트 서식을 사용하는 텍스트에 밑줄을 그을지 여부를 true 또는 false로 나타냅니다. 이렇게 밑줄을 표시하는 것은 <U> 태그로 밑줄을 표시하는 것과 유사하지만, 태그를 사용할 경우 디센더를 제대로 건너뛰지 않기 때문에 진정한 밑줄은 아닙니다. 기본값은 밑줄을 사용하지 않는 null입니다.

구현
public function get underline():Object
public function set underline(value:Object):void

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

url

속성

url:String

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

이 텍스트 서식의 텍스트에 대한 대상 URL을 나타냅니다. url 속성이 빈 문자열이면 텍스트에 하이퍼링크가 없습니다. 기본값은 텍스트에 하이퍼링크가 없음을 나타내는 null입니다.

참고: 하이퍼링크가 작동하려면 지정된 텍스트 서식이 적용된 텍스트에 htmlText 속성을 설정해야 합니다.

구현
public function get url():String
public function set url(value:String):void

관련 API 요소

flash.text.TextField.htmlText

예제
예제 사용 방법
이 속성을 사용하는 방법은 TextFormat() constructor 예제를 참조하십시오.

생성자 세부 정보

()

생성자

public function TextFormat(font:String = null, size:Object = null, color:Object = null, bold:Object = null, italic:Object = null, underline:Object = null, url:String = null, target:String = null, align:String = null, leftMargin:Object = null, rightMargin:Object = null, indent:Object = null, leading:Object = null)

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 1.0, Flash Player 9., Flash Lite 4

지정된 속성으로 TextFormat 객체를 만듭니다. 그런 다음 TextFormat 객체의 속성을 변경하여 텍스트 필드의 서식을 변경할 수 있습니다.

매개 변수를 null로 설정하여 정의되지 않았음을 나타낼 수 있습니다. 모든 매개 변수는 선택 사항입니다. 따라서 생략된 매개 변수는 null로 간주됩니다.

매개 변수

	`font:String` (default = `null`) — 텍스트의 글꼴 이름 문자열입니다.

	`size:Object` (default = `null`) — 크기를 픽셀 단위로 나타내는 정수입니다.

	`color:Object` (default = `null`) — 이 텍스트 서식을 사용하는 텍스트의 색상입니다. 세 개의 8비트 RGB 구성 요소를 포함하는 숫자입니다. 예를 들어 0xFF0000은 빨강이고 0x00FF00은 녹색입니다.

	`bold:Object` (default = `null`) — 텍스트가 굵은체로 표시되는지 여부를 나타내는 부울 값입니다.

	`italic:Object` (default = `null`) — 텍스트가 기울임체로 표시되는지 여부를 나타내는 부울 값입니다.

	`underline:Object` (default = `null`) — 텍스트에 밑줄을 그을지 여부를 나타내는 부울 값입니다.

	`url:String` (default = `null`) — 이 텍스트 서식의 텍스트가 하이퍼링크로 연결되는 URL입니다. `url`이 빈 문자열이면 텍스트에 하이퍼링크가 없습니다.

	`target:String` (default = `null`) — 하이퍼링크가 표시되는 대상 윈도우입니다. 대상 윈도우가 빈 문자열이면 텍스트는 기본 대상 윈도우 `_self`에 표시됩니다. `url` 매개 변수가 빈 문자열 또는 `null` 값으로 설정되어 있으면 이 속성을 가져오거나 설정할 수는 있지만 아무 효과도 없습니다.

	`align:String` (default = `null`) — 단락의 정렬을 나타내는 TextFormatAlign 값입니다.

	`leftMargin:Object` (default = `null`) — 단락의 왼쪽 여백을 픽셀 단위로 나타냅니다.

	`rightMargin:Object` (default = `null`) — 단락의 오른쪽 여백을 픽셀 단위로 나타냅니다.

	`indent:Object` (default = `null`) — 왼쪽 여백에서 단락 첫 문자까지의 들여쓰기를 나타내는 정수입니다.

	`leading:Object` (default = `null`) — 행 사이의 세로 간격을 나타내는 숫자입니다.

예제 ( 예제 사용 방법 )

다음 예제에서 사용자는 다른 텍스트 필드의 내용에 적용될 다른 텍스트 서식 옵션을 목록에서 선택할 수 있습니다. 사용자가 텍스트 필드의 내용을 클릭하면 서식이 기본(원래) 서식으로 되돌아갑니다.

formatTextField 텍스트 필드는 모든 TextField 클래스 속성 옵션(kerning 제외)을 별도의 행에 열거합니다. 사용자가 formatTextField 텍스트 필드에 있는 행을 클릭하면 formatTextFieldClickHandler() 메서드가 트리거됩니다.

formatTextFieldClickHandler() 메서드는 TextField.getLineIndexAtPoint() 메서드를 호출해 클릭한 행의 인덱스를 가져오고 TextField.getLineText() 메서드를 호출해 해당 행의 내용을 가져옵니다. switch 문이 해당 행의 내용을 확인하고 그에 따라 newformat TextFormat 객체의 속성을 설정합니다. 그 후에 setTextFormat() 메서드가 contentTextField 텍스트 필드의 텍스트 서식을 새로운 서식으로 설정합니다. 사용자는 다른 formatTextField 행을 클릭해 다양한 서식을 contentTextField 텍스트 필드에 적용할 수 있습니다 탭 설정은 행의 각 탭에 대한 별도의 탭 정지를 정의하는 하나의 배열입니다. url 또는 target 행을 선택할 경우 사용자는 contentTextField 텍스트 필드를 클릭해 링크를 활성화하고 대상 URL(Flex 홈 페이지)의 내용을 표시해야 합니다. target 속성의 기본값은 "_self"이며 사용자가 url 행을 선택할 경우 현재의 창에 내용이 표시된다는 의미입니다. target 속성이 작동하려면 URL이 url 속성에 설정되어 있어야 합니다.

사용자가 contentTextField 텍스트 필드를 클릭하면 contentTextFieldClickHandler() 메서드가 트리거되어 필드의 서식과 newFormat TextFormat 객체를 텍스트 필드의 기본(원래) 서식으로 설정합니다. 이렇게 하면 사용자의 모든 서식 변경 사항이 지워집니다.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

예제 예제 사용 방법

TextFormatExample.as

다음 예제에서는 기본 위치(x = 0, y = 0)를 사용하여 텍스트를 표시하는 TextFieldExample 클래스를 만듭니다. 이는 다음 단계로 이루어집니다.

TextField 유형의 label 속성을 만듭니다.
클래스 생성자에서 configureLabel() 함수를 호출합니다.
configureLabel() 함수에서는 먼저 새 TextField 객체를 만들어 label에 할당한 다음 매개 변수를 다음과 같이 설정합니다.
- 텍스트 필드를 왼쪽으로 정렬합니다.
- 배경 칠을 활성화합니다.
- 테두리를 활성화합니다.
다음으로 configureLabel()에서 로컬 변수 format을 만들어 새 TextFormat 인스턴스에 할당합니다. 이때 매개 변수를 다음과 같이 설정합니다.
- Font type = Verdana
- Font Color = solid red
- Font size = 10
- Font underline = true
레이블의 defaultTextFormat 속성을 format으로 설정하고 label 인스턴스를 표시 목록에 추가합니다. 처음에는 스테이지에 텍스트가 없는 텍스트 필드(흰색 배경의 작은 상자)가 표시됩니다.
마지막으로 생성자로 돌아온 다음 "Hello World and welcome to the show"라는 텍스트가 x = 0, y = 0 좌표에 표시되도록 setLabel()을 호출하여 레이블 텍스트를 설정합니다.

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}

법적 고지 사항 | 온라인 개인 정보 보호 정책

TextFormat - AS3

패키지x

언어 요소

부록

패키지 flash.text

align

blockIndent

bold

bullet

color

font

indent

italic

kerning

leading

leftMargin

letterSpacing

rightMargin

size

tabStops

target

underline

url

TextFormat