URLLoaderDataFormat - Adobe ActionScript® 3（AS3 ）API リファレンス

パッケージ	flash.net
クラス	public final class URLLoaderDataFormat
継承	URLLoaderDataFormat Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

URLLoaderDataFormat クラスは、ダウンロードされるデータの受信方法を指定する値を提供します。

例を表示

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

パブリック定数

	定数		定義元
		BINARY : String = "binary" [静的] ダウンロードされるデータを生のバイナリデータとして受信することを指定します。	URLLoaderDataFormat
		TEXT : String = "text" [静的] ダウンロードされるデータをテキストとして受信することを指定します。	URLLoaderDataFormat
		VARIABLES : String = "variables" [静的] ダウンロードされるデータを URL エンコード形式の変数として受信することを指定します。	URLLoaderDataFormat

定数の詳細

BINARY

定数

public static const BINARY:String = "binary"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

ダウンロードされるデータを生のバイナリデータとして受信することを指定します。

TEXT

定数

public static const TEXT:String = "text"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

ダウンロードされるデータをテキストとして受信することを指定します。

VARIABLES

定数

public static const VARIABLES:String = "variables"

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0, Flash Player 9, Flash Lite 4

ダウンロードされるデータを URL エンコード形式の変数として受信することを指定します。

例この例の使用方法

URLLoaderDataFormatExample.as

次の例では、URLLoaderDataFormatExample クラスを使用して、実行時にロードされるファイルのデータフォーマットとステータス情報を表示します。ここでは以下の手順を実行します。

クラスコンストラクターが loader という URLLoader インスタンスと、ロードされるファイルの場所と名前である request という URLRequest インスタンスを作成します。
loader オブジェクトが configureListeners() メソッドに渡されます。このメソッドは、サポートされる各 URLLoader イベントのリスナーを追加します。
- completeHandler()：complete イベントをリッスンします。このイベントは "TextFile.txt" が正常にロードされた後に送出されます。
- openHandler()：open イベントをリッスンします。このイベントは "TextFile.txt" の（Flash Player への）ダウンロードの開始時に送出されます。
- progressHandler()：progress イベントをリッスンします。このイベントはダウンロード処理を実行中にデータを受信したときに送出されます。
- securityErrorHandler()：securityError イベントをリッスンします。このイベントは、ローカルでの再生に関するセキュリティを誤って設定してテキストファイルにアクセスした場合に送出されます。
- httpStatusHandler()：httpStatusHandler イベントをリッスンします。この場合は "TextFile.txt" がローカル側にあるので、このイベントは送出されません。
- ioErrorHandler()：ioError イベントをリッスンします。このイベントは、例えばファイルが存在しないなど、ファイルに関して深刻な問題がある場合のみ発生します。
次に request オブジェクトが loader.load() メソッドに渡されます。このメソッドは、DisplayObject オブジェクトを使用してテキストファイルをメモリにロードします。

注意：

「ローカルでの再生に関するセキュリティ」を「ローカルファイルにのみアクセスする」に設定して SWF ファイルをコンパイルする必要があります。
この例では、"TextFile.txt" という名前のファイルが SWF ファイルと同じディレクトリに配置されている必要があります。この例を参照し、バイナリまたは URL エンコードデータファイルを識別する場合は、正しいデータ形式でファイルを提供し、"TextFile.txt" を新しいファイルの名前と場所に変更する必要があります。


package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderDataFormatExample extends Sprite {
        private var source:String = "TextFile.txt";
        private var dataFormat:String = URLLoaderDataFormat.TEXT;
        private var loader:URLLoader;
        
        public function URLLoaderDataFormatExample () {
            loader = new URLLoader();
            loader.dataFormat = dataFormat;
            configureListeners(loader);
            var request:URLRequest = new URLRequest(source);
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Error loading requested document: " + source);
            }
        }

        private function configureListeners(dispatcher:URLLoader):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            switch(loader.dataFormat) {
                case URLLoaderDataFormat.TEXT :
                    trace("completeHandler (text): " + loader.data);
                    break;
                case URLLoaderDataFormat.BINARY :
                    trace("completeHandler (binary): " + loader.data);
                    break;
                case URLLoaderDataFormat.VARIABLES :
                    trace("completeHandler (variables): " + loader.data);
                    break;
            }
        }

        private function httpStatusHandler(event:Event):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}

法律上の注意 | プライバシーポリシー

URLLoaderDataFormat - AS3

クラス x

BINARY

TEXT

VARIABLES