StorageVolume

パッケージ	flash.filesystem
クラス	public class StorageVolume
継承	StorageVolume Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

StorageVolume オブジェクトには、マスストレージボリュームを定義するプロパティが用意されています。このクラスは、次の 2 つの方法で使用できます。

StorageVolumeChangeEvent オブジェクトの storageVolume プロパティは StorageVolume オブジェクトです。このオブジェクトは、マウントまたはマウント解除されたストレージボリュームを表します。
StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() メソッドは、StorageVolume オブジェクトのベクターを返します。これらの StorageVolume オブジェクトはそれぞれ、マウントされたストレージボリュームを表します。

例を表示

パブリックプロパティ

継承されるパブリックプロパティを隠す

継承されるパブリックプロパティを表示

	プロパティ		定義元
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクター関数への参照です。	Object
		drive : String [読み取り専用] Windows のボリュームドライブ文字です。	StorageVolume
		fileSystemType : String [読み取り専用] ストレージボリュームのファイルシステムのタイプ（「FAT」、「NTFS」、「HFS」、「UFS」など）	StorageVolume
		isRemovable : Boolean [読み取り専用] オペレーティングシステムがストレージボリュームを取り外し可能（true）と見なすか、取り外し不可（false）と見なすかを示します。	StorageVolume
		isWritable : Boolean [読み取り専用] ボリュームの書き込み可（true） / 不可（false）を示します。	StorageVolume
		name : String [読み取り専用] ボリュームの名前です。	StorageVolume
		rootDirectory : File [読み取り専用] ボリュームのルートディレクトリに対応する File オブジェクトです。	StorageVolume

パブリックメソッド

継承されるパブリックメソッドを隠す

継承されるパブリックメソッドを表示

	メソッド		定義元
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) コンストラクター関数です。	StorageVolume
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメーターとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		toLocaleString():String ロケール固有の規則に従って書式設定された、このオブジェクトのストリング表現を返します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

プロパティの詳細

drive

プロパティ

drive:String [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

Windows のボリュームドライブ文字です。他のプラットフォーム上では、このプロパティは null に設定されます。

実装
public function get drive():String

fileSystemType

プロパティ

fileSystemType:String [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

ストレージボリュームのファイルシステムのタイプ（「FAT」、「NTFS」、「HFS」、「UFS」など）

実装
public function get fileSystemType():String

例 ( この例の使用方法 )

次のコードでは、マウントされた各ストレージボリュームのルートディレクトリへのネイティブパスおよびファイルシステムのタイプを一覧で表示します。

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

プロパティ

isRemovable:Boolean [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

オペレーティングシステムがストレージボリュームを取り外し可能（true）と見なすか、取り外し不可（false）と見なすかを示します。

次の表に、さまざまなタイプのデバイスについて、StorageVolume.isRemovable 値を一覧で示します。

デバイスのタイプ	Mac OS	Windows	Linux
CD/DVD（内蔵）	true	true	true
USB フラッシュドライブ	true	true	true
USB ハードドライブ	false	false	true
FireWire ハードドライブ	false	false	true
共有ボリューム	true	false	- ¹
ネットワークドライブ	false	false	false
ストレージカードリーダー（空）	- ²	false	- ²
ストレージカードリーダー（SD/CF カード付き）	true	true	true

¹ Linux には共有ボリュームという概念がありません。

² Windows では、空のカードリーダーは非リムーバブルデバイスとして表示されます。Mac OS および Linux では、空のカードリーダーはストレージボリュームとして表示されません。

実装
public function get isRemovable():Boolean

例 ( この例の使用方法 )

次のコードでは、削除不可のストレージボリュームのリスト、削除可のストレージボリュームの順に出力します。

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

プロパティ

isWritable:Boolean [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

ボリュームの書き込み可（true） / 不可（false）を示します。

注意：StorageVolume オブジェクトの rootDirectory.spaceAvailble プロパティを呼び出して、ボリューム上の使用可能な領域を確認できます。

実装
public function get isWritable():Boolean

name

プロパティ

name:String [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

ボリュームの名前です。名前がない場合、このプロパティは null に設定されます。

実装
public function get name():String

例 ( この例の使用方法 )

次のコードでは、マウントされた各ストレージボリュームのルートディレクトリへのネイティブパスおよびファイルシステム名（存在する場合）を一覧で表示します。

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

プロパティ

rootDirectory:File [読み取り専用]

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

ボリュームのルートディレクトリに対応する File オブジェクトです。

実装
public function get rootDirectory():File

例 ( この例の使用方法 )

次のコードでは、マウントされた各ストレージボリュームのルートディレクトリへのネイティブパスを一覧で表示します。

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

コンストラクターの詳細

()

コンストラクター

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 2

コンストラクター関数です。一般に、このコンストラクター関数を直接呼び出して、新しい StorageVolume オブジェクトを作成することはありません。代わりに、StorageVolumeChangeEvent オブジェクトの storageVolume プロパティにアクセスするか、StorageVolumeInfo.storageVolumeInfo.getStorageVolumes を呼び出して、StorageVolume オブジェクトを参照します。

パラメーター

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

例この例の使用方法

StorageVolumeExample.as

次のコードでは、マウントされた各ストレージボリュームのプロパティを一覧で表示します。

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

次のコードでは、マウントまたはマウント解除される各ストレージボリュームのプロパティを一覧で表示します。StorageVolumeChangeEvent の storageVolume プロパティは、storageVolumeMount イベントに対してのみ設定され、storageVolumeUnmount イベントでは null になります。

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

法律上の注意 | プライバシーポリシー

StorageVolume - AS3

クラス x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume