StorageVolume

Package	flash.filesystem
Classe	public class StorageVolume
Héritage	StorageVolume Object

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Un objet StorageVolume contient des propriétés qui définissent un volume de stockage de masse. Cette valeur s’utilise de deux manières :

La propriété storageVolume d’un objet StorageVolumeChangeEvent représente un objet StorageVolume. Cet objet représente le volume de stockage qui a été monté ou démonté.
La méthode StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() renvoie un vecteur d’objets StorageVolume. Chacun de ces objets StorageVolume représente un volume de stockage monté.

Consulter les exemples

Plus d’exemples

Utilisation des volumes de stockage

Eléments de l’API associés

flash.filesystem.StorageVolumeInfo.getStorageVolumes()
flash.events.StorageVolumeChangeEvent.storageVolume

Propriétés publiques

Masquer les propriétés publiques héritées

Afficher les propriétés publiques héritées

	Propriété		Défini par
		constructor : Object Référence à l’objet de classe ou à la fonction constructeur d’une occurrence donnée d’un objet.	Object
		drive : String [lecture seule] Lettre de lecteur d’un volume sous Windows.	StorageVolume
		fileSystemType : String [lecture seule] Type de système de fichiers sur le volume de stockage (tel que "FAT", "NTFS", "HFS" ou "UFS").	StorageVolume
		isRemovable : Boolean [lecture seule] Indique si le système d’exploitation considère que le volume de stockage peut être retiré (true) ou pas (false).	StorageVolume
		isWritable : Boolean [lecture seule] Indique s’il est possible d’écrire sur un volume (true) ou pas (false).	StorageVolume
		name : String [lecture seule] Nom du volume.	StorageVolume
		rootDirectory : File [lecture seule] Objet File correspondant au répertoire racine du volume.	StorageVolume

Méthodes publiques

Masquer les méthodes publiques héritées

Afficher les méthodes publiques héritées

	Méthode		Défini par
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) Fonction du constructeur.	StorageVolume
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d’un objet est définie.	Object
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l’objet spécifié en tant que paramètre.	Object
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d’une propriété dynamique pour les opérations en boucle.	Object
		toLocaleString():String Renvoie la représentation de chaîne de cet objet, formatée selon les paramètres régionaux en vigueur.	Object
		toString():String Renvoie la représentation sous forme de chaîne de l’objet spécifié.	Object
		valueOf():Object Renvoie la valeur primitive de l’objet spécifié.	Object

Détails de la propriété

drive

propriété

drive:String [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Lettre de lecteur d’un volume sous Windows. Sur d’autres plates-formes, cette propriété est définie sur null.

Implémentation
public function get drive():String

fileSystemType

propriété

fileSystemType:String [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Type de système de fichiers sur le volume de stockage (tel que "FAT", "NTFS", "HFS"ou "UFS").

Implémentation
public function get fileSystemType():String

Exemple ( Comment utiliser cet exemple )

Le code suivant indique le chemin d’accès natif correspondant au répertoire racine, ainsi que le type de système de fichiers de chaque volume de stockage monté :

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

propriété

isRemovable:Boolean [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Indique si le système d’exploitation considère que le volume de stockage peut être retiré (true) ou pas (false).

Le tableau suivant répertorie les valeurs de la propriété StorageVolume.isRemovable pour divers types de périphériques :

Type de périphérique	Mac OS	Windows	Linux
CD/DVD (intégré)	true	true	true
Lecteur flash USB	true	true	true
Disque dur USB	false	false	true
Disque dur FireWire	false	false	true
Volume partagé	true	false	- ¹
Lecteur de réseau	false	false	false
Lecteur de carte de stockage (vide)	- ²	false	- ²
Lecteur de carte de stockage (avec carte SD/CF)	true	true	true

¹ Linux ne possède pas de concept de volume partagé.

² Sous Windows, un lecteur de carte vide est répertorié en tant que périphérique non amovible. Sous Mac OS et Linux, les lecteurs de carte vides ne sont pas répertoriés en tant que volumes de stockage.

Implémentation
public function get isRemovable():Boolean

Exemple ( Comment utiliser cet exemple )

Le code suivant génère une liste des volumes de stockage non amovibles, ainsi qu’une liste des volumes de stockage amovibles :

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

propriété

isWritable:Boolean [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Indique s’il est possible d’écrire sur un volume (true) ou pas (false).

Remarque : vous pouvez déterminer la quantité d’espace disponible sur un volume en appelant la propriété rootDirectory.spaceAvailble de l’objet StorageVolume.

Implémentation
public function get isWritable():Boolean

Eléments de l’API associés

flash.fileSystem.File.spaceAvailable

Exemple ( Comment utiliser cet exemple )

Le code suivant génère une liste des volumes de stockage accessibles en écriture et indique l’espace disponible sur chacun d’eux :

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

for (var i:int = 0; i < volumes.length; i++)
{
    if(volumes[i].isWritable)
    {         
        trace(volumes[i].rootDirectory.nativePath, volumes[i].rootDirectory.spaceAvailable);
    }
}

name

propriété

name:String [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Nom du volume. Si aucun nom n’est défini, cette propriété est définie sur null.

Implémentation
public function get name():String

Exemple ( Comment utiliser cet exemple )

Le code suivant indique le chemin d’accès natif correspondant au répertoire racine, ainsi que le nom du système de fichiers de chaque volume de stockage monté :

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

propriété

rootDirectory:File [lecture seule]

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Objet File correspondant au répertoire racine du volume.

Implémentation
public function get rootDirectory():File

Exemple ( Comment utiliser cet exemple )

Le code suivant indique le chemin d’accès natif correspondant au répertoire racine de chaque volume de stockage monté :

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

Détails du constructeur

()

Constructeur

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

Version du langage:

ActionScript 3.0

Versions du moteur d’exécution:

AIR 2

Fonction du constructeur. En règle générale, vous n’appelez pas la fonction de ce constructeur directement (pour créer de nouveaux objets StorageVolume). Au lieu de cela, vous référencez les objets StorageVolume en accédant à la propriété storageVolume d’un objet StorageVolumeChangeEvent ou en appelant StorageVolumeInfo.storageVolumeInfo.getStorageVolumes().

Paramètres

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

Exemples Comment utiliser cet exemple

StorageVolumeExample.as

Le code suivant répertorie les propriétés de chaque volume de stockage monté :

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

Le code suivant répertorie les propriétés de chaque volume de stockage monté ou démonté. Notez que la propriété storageVolume de l’objet StorageVolumeChangeEvent est uniquement définie pour l’événement storageVolumeMount ; sa valeur est null pour l’événement storageVolumeUnmount :

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

Informations juridiques | Politique de confidentialité en ligne

StorageVolume - AS3

Classes x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume