JSON  - AS3

Prend en charge une chaîne au format JSON et renvoie un objet ActionScript qui représente cette valeur. Les objets, tableaux, chaînes, nombres, valeurs booléennes et valeurs null JSON correspondent aux valeurs ActionScript suivantes, comme indiqué ci-dessous :

Le paramètre reviver est une fonction qui prend deux paramètres : une clé et une valeur. Vous pouvez utiliser cette fonction pour transformer ou filtrer chaque paire clé/valeur telle qu’elle est analysée. Si vous fournissez une fonction reviver, c’est votre valeur transformée ou filtrée pour chaque paire qui est renvoyée dans la fonction de sortie parse(), et non la valeur d’analyse par défaut. Si la fonction reviver renvoie undefined pour une paire, la propriété est supprimée du résultat final.

Lorsque l’argument transmis au paramètre reviver n’est pas une fonction, ActionScript renvoie une exception TypeError avec l’ID d’erreur kJSONInvalidReviver. Il publie également un message d’erreur localisé.

Si la fonction parse() rencontre des clés dupliquées au sein d’un objet, la clé en double trouvée en dernier fournit la valeur pour toutes les occurrences précédentes de cette clé.

Paramètres

Renvoie une chaîne, au format JSON, qui représente une valeur ActionScript. La méthode stringify peut prendre trois paramètres.

Le paramètre value est requis. Ce paramètre est une valeur ActionScript. En règle générale, il s’agit d’un objet ou un tableau, mais il peut également s’agir d’une chaîne, d’une valeur booléenne, d’un nombre ou d’une valeur nulle.

Le paramètre replacer facultatif peut être une fonction ou un tableau de chaînes ou de numéros. S’il s’agit d’une fonction, celle-ci prend deux paramètres : une clé et d’une valeur. Vous pouvez utiliser cette fonction pour transformer ou filtrer chaque paire clé/valeur telle qu’elle est analysée. Si vous fournissez une fonction replacer, c’est votre valeur transformée ou filtrée pour chaque paire qui est renvoyée dans la fonction de sortie parse(), et non la valeur d’analyse par défaut. Si la fonction replacer renvoie undefined pour toute paire, la propriété est supprimée du résultat final. Si la fonction replacer est un tableau, il est utilisé comme filtre pour désigner les propriétés à inclure dans la sortie.

Lorsque l’argument transmis au paramètre replacer n’est ni un tableau ni une fonction, ActionScript renvoie une exception TypeError avec l’ID d’erreur kJSONInvalidReplacer. Il publie également un message d’erreur localisé.

Le paramètre space facultatif est une chaîne ou nombre qui permet à l’espace blanc d’être inséré dans la chaîne renvoyée pour améliorer la lisibilité. Les entrées dans les objets JSON et les tableaux JSON générés sont séparées par un espace issu du paramètre space. Cet espace comporte toujours entre 0 et 10 caractères. Si l’espace est une chaîne, l’espace dérivé correspond aux dix premiers caractères de cette chaîne. Si l’espace est un nombre non négatif x, l’espace correspond à x caractères d’espacement, jusqu’à un maximum de dix espaces. Lorsque l’argument transmis au paramètre space n’est pas une chaîne, mais un nombre, il est converti en chaîne en vue d’être utilisé en tant qu’espace dans la sortie. L’exécution se poursuit.

Lorsque la méthode stringify() rencontre une structure cyclique, elle renvoie une exception TypeError avec l’ID d’erreur kJSONCyclicStructure. Il publie également un message d’erreur localisé.

Paramètres

1. Le constructeur de JSONExample attribue une chaîne au membre text de la super classe et initialise un compteur interne.
2. De plus, la classe définit un tableau qui peut contenir des objets JSONExample ayant été exportés dans JSON.
3. JSONExample définit également une méthode toJSON() et une méthode revive(). La méthode toJSON() est appelée par JSON.stringify() pour sérialiser les objets JSONExample sur JSON. La méthode revive() peut être appelée à partir des méthodes JSON.parse() pour restaurer l'objet JSONExample intégral. Cette restauration est réalisée à l'aide d'un ID donné pour récupérer l'objet d'origine à partir du tableau d'objets revivable.
4. Le script qui utilise la définition de classe crée un objet qui contient deux objets TextField et un objet JSONExample. Il crée également un tableau d'objets revivable pour le stockage d'objets TextField ayant été exportés dans JSON.
5. La fonction replacer de JSON.stringify() filtre les objets TextField hors de la chaîne JSON. A la place de chaque objet supprimé, replacer fournit un repère avec un ID qui peut être utilisé ultérieurement pour extraire l'objet. D'autre part, les objets JSONExample passent à travers en fonction de leur codage natif JSON.
6. La fonction reviver de la méthode parse() recrée l'objet original en récupérant tous les objets TextField et JSONExample référencés.

 
 package {
    import flash.text.TextField;
    public class JSONExample extends TextField
    {
        static var nextId = 10000;
        static var revivable_objects:Array = [];
            public var id;

        public function JSONExample(s:String){
            super.text = s;
            id = ++nextId;
        }
        public function toJSON(k):*
        {
            // To be called internally by the JSON.stringify() method.
            // Save the original object internally.
            // Write out only a generated ID and the text value.
            revivable_objects[id] = this;
            return {"classJSONExample":{"reviveId":id,"contents":this.text}};
        }
        public static function revive(id:int):JSONExample
        {
            // For explicit use in the JSON.parse() method.
            // Revives the object using the ID obtained from the JSON string.
            return revivable_objects[id];
        }
    }
}

import flash.text.TextField;

var lastId = 20000;
var tf1:TextField = new TextField();
tf1.text = "Lorem ipsum";
var tf2:TextField = new TextField();
tf2.text = "Laughing cows";
var nt:JSONExample = new JSONExample("It was the best of times; it was the worst of times.");

var obj:Object = {a:tf1, b:nt, c:tf2};
var revivable_objects:Array = new Array();

var json_out = JSON.stringify(obj, function(k,v){
        if (v is JSONExample)
        {
            // Send JSONExample objects to the JSON output.
            // Note that stringify() calls JSONExample.toJSON() to serialize this object.
            return v;
        }
        if (v is TextField)
        {
            // Remove TextField objects from the JSON output.
            // Save the original object for reviving later.
            // Return a new object containing an identification marker
            // and the original object's revival ID.
            revivable_objects[++lastId] = v;
            return {"classTextField":{"reviveId":lastId}};
        }
        return v;
    }
);
               
trace("json_out: " + json_out);

var json_in = JSON.parse(json_out, function(k,v) {
        if ("classTextField" in v) { // special marker tag from stringify() replacer code
            // Retrieve the original object based on the ID stored in the stringify() replacer function.
            var id = v["classTextField"].reviveId;
            return revivable_objects[id];
        } else if ("classJSONExample" in v){
            // Retrieve the original object based on the ID generated in JSONExample.toJSON().
            return JSONExample.revive(v["classJSONExample"].reviveId);
        }
        return v;
    }
);

if (json_in.a)
{
    if (json_in.a.hasOwnProperty("text"))
        {
            trace("json_in.a: " + json_in.a.text);
        }
}
if (json_in.b)
{
    if (json_in.b.hasOwnProperty("text"))
        {
            trace("json_in.b: " + json_in.b.text);
        }
}

if (json_in.c)
{
    if (json_in.c.hasOwnProperty("text"))
        {
            trace("json_in.c: " + json_in.c.text);
        }
}