Trabajo con cinemática inversa

La cinemática inversa (IK) permite crear animaciones reales uniendo distintas piezas de modo que puedan moverse entre sí con realismo.

Por ejemplo, se puede utilizar la cinemática inversa para mover una pierna hasta una posición determinada articulando los movimientos necesarios de las uniones de la pierna para lograr la postura deseada. La cinemática inversa utiliza una arquitectura de huesos unidos entre sí en una estructura denominada esqueleto IK. El paquete fl.ik sirve para crear animaciones de movimientos naturales y realistas. Permite animar varios esqueletos IK a la perfección sin necesidad de tener conocimientos físicos de algoritmos de cinemática inversa.

Puede crear el esqueleto IK con sus huesos y uniones correspondientes en Flash Professional. Luego puede acceder a las clases de IK para animarlos en tiempo de ejecución.

Consulte la sección Uso de cinemática inversa en el manual Uso de Flash Professional para obtener instrucciones detalladas sobre la creación de un esqueleto IK.

Una vez creado el esqueleto IK en Flash Professional, utilice las clases de fl.ik para limitar su movimiento, realizar un seguimiento de sus eventos o animarlo en tiempo de ejecución.

En la siguiente figura se muestra un clip de película denominado Rueda. El eje es una instancia de un objeto IKArmature denominado Eje . La clase IKMover mueve el esqueleto en sincronía con la rotación de la rueda. El hueso IKBone ( ikBone2 ) del esqueleto se une a la rueda en su unión de cola.

A.

Rueda

B.

Eje

C.

ikBone2

En tiempo de ejecución, la rueda gira asociada a la interpolación de movimiento __motion_Wheel descrita en Descripción de la animación . Un objeto IKMover inicia y controla el movimiento del eje. En la siguiente figura se muestran dos instantáneas del esqueleto del eje asociado a la rueda giratoria en distintos fotogramas de la rotación.

import fl.ik.* 
 
var tree:IKArmature = IKManager.getArmatureByName("Axle"); 
var bone:IKBone = tree.getBoneByName("ikBone2"); 
var endEffector:IKJoint = bone.tailJoint; 
var pos:Point = endEffector.position; 
 
var ik:IKMover = new IKMover(endEffector, pos); 
ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 
 
Wheel.addEventListener(Event.ENTER_FRAME, frameFunc); 
 
function frameFunc(event:Event) 
{ 
    if (Wheel != null) 
    { 
        var mat:Matrix = Wheel.transform.matrix; 
        var pt = new Point(90, 0); 
        pt = mat.transformPoint(pt); 
         
        ik.moveTo(pt); 
    } 
}

Las clases IK utilizadas para mover el eje son:

Para obtener información detallada y completa sobre estas clases, consulte el paquete ik .

En primer lugar, declare variables para el esqueleto, el hueso y la unión que formen parte del grupo de piezas que desea mover.

El siguiente código utiliza el método getArmatureByName() de la clase IKManager para asignar el valor del esqueleto Axle a la variable tree de IKArmature. El esqueleto Axle se ha creado previamente con Flash Professional.

var tree:IKArmature = IKManager.getArmatureByName("Axle");

De forma similar, el siguiente código utiliza el método getBoneByName() de la clase IKArmature para asignar a la variable IKBone el valor del hueso ikBone2 .

var bone:IKBone = tree.getBoneByName("ikBone2");

La unión de cola del hueso ikBone2 es la parte del esqueleto que se une a la rueda giratoria.

La siguiente línea declara la variable endEffector y le asigna la propiedad tailjoint del hueso ikBone2 :

var endEffector:IKJoint = home.tailjoint;

var pos:Point = endEffector.position;

En este ejemplo, pos corresponde a la posición de la unión al final del eje, donde se conecta con la rueda. El valor original de esta variable se obtiene a partir de la propiedad position del objeto IKJoint.

Una instancia de la clase IKMover mueve el eje.

var ik:IKMover = new IKMover(endEffector, pos);

Las propiedades de la clase IKMover permiten limitar el movimiento de un esqueleto. Puede limitar el movimiento basado en la distancia, en las iteraciones o en el tiempo del movimiento.

Las siguientes parejas de propiedades refuerzan estos límites. La pareja consta de una valor booleano que indica si el movimiento está limitado y un entero que especifica dicho límite:

De forma predeterminada, todos los valores booleanos se establecen en false , por lo que el movimiento no se limita a no ser que se defina explícitamente un valor booleano como true . Para aplicar un límite, establezca la propiedad adecuada en true y después especifique un valor para la propiedad de entero correspondiente. Si establece el límite en un valor sin definir su propiedad Boolean correspondiente, el límite se obviará. En este caso, el motor IK sigue moviendo el objeto hasta llegar a otro límite o a la posición de destino del objeto IKMover.

ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 

La cinemática inversa de Flash Professional CS5 admite muelles de hueso. El muelle de hueso se puede establecer durante la edición y los atributos del muelle del hueso se pueden añadir o modificar en tiempo de ejecución. El muelle es una propiedad del hueso y sus uniones. Cuenta con dos atributos: IKJoint.springStrength , que establece la cantidad de muelle y IKJoint.springDamping , que añade resistencia al valor de intensidad y afecta al grado de descomposición del muelle.

La intensidad del muelle es un valor porcentual desde 0 (totalmente rígido, predeterminado) a 100 (muy suelto y controlado por física). Los huesos con muelle reaccionan al movimiento de su unión. Si no se activa ninguna otra traslación (rotación, x o y), los valores del muelle no se aplicarán.

La atenuación del muelle es un valor porcentual desde 0 (sin resistencia, predeterminado) a 100 (mucha atenuación). La atenuación cambia la cantidad de tiempo que transcurre entre el movimiento inicial del hueso y su vuelta a la posición de reposo.

Se puede verificar si los muelles están habilitados para un objeto IKArmature comprobando su propiedad IKArmature.springsEnabled . Las demás propiedades y métodos del muelle pertenecen a los objetos IKJoint independientes. Se puede habilitar una unión para la rotación angular y traslación a lo largo de los ejes x e y. Se puede situar un ángulo del muelle de la unión de rotación con IKJoint.setSpringAngle y una posición del muelle de la unión de traslación con IKJoint.setSpringPt .

Este ejemplo selecciona un hueso por nombre e identifica su valor tailJoint. El código prueba el esqueleto para ver si los muelles están habilitados y posteriormente establece las propiedades del muelle para la unión.

var arm:IKArmature = IKManager.getArmatureAt(0); 
var bone:IKBone = arm.getBoneByName("c"); 
var joint:IKJoint = bone.tailJoint; 
if (arm.springsEnabled) { 
    joint.springStrength = 50; //medium spring strength 
    joint.springDamping = 10; //light damping resistance 
    if (joint.hasSpringAngle) { 
        joint.setSpringAngle(30); //set angle for rotational spring 
    } 
}

La clase IKEvent permite crear un objeto de evento que contenga información sobre eventos IK. La información de IKEvent describe un movimiento que ha finalizado por haberse superado el tiempo especificado, la distancia o el límite de iteraciones.

El siguiente código muestra un detector de eventos y un controlador para realizar el seguimiento de los eventos de límite de tiempo. Este controlador de eventos informa sobre el tiempo, la distancia, el número de iteraciones y las propiedades de unión de un evento activado cuando se supera el límite de tiempo de IKMover.

var ikmover:IKMover = new IKMover(endjoint, pos); 
ikMover.limitByTime = true; 
ikMover.timeLimit = 1000; 
 
ikmover.addEventListener(IKEvent.TIME_LIMIT, timeLimitFunction); 
 
function timeLimitFunction(evt:IKEvent):void 
{ 
    trace("timeLimit hit"); 
    trace("time is " + evt.time); 
    trace("distance is " + evt.distance); 
    trace("iterationCount is " + evt.iterationCount); 
    trace("IKJoint is " + evt.joint.name); 
}