XMLDocument

Paquete	flash.xml
Clase	public class XMLDocument
Herencia	XMLDocument XMLNode Object

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

La clase XMLDocument representa el objeto XML heredado que estaba presente en ActionScript 2.0. En ActionScript 3.0 ha pasado a llamarse XMLDocument para evitar conflictos de nombres con la nueva clase XML de ActionScript 3.0. En ActionScript 3.0, se recomienda utilizar la nueva clase XML de nivel superior y sus clases relacionadas, que admiten E4X (ECMAScript para XML).

La clase XMLDocument, así como las clases XMLNode y XMLNodeType, siguen presentes para permitir la compatibilidad con versiones anteriores. La funcionalidad para cargar documentos XML se encuentra ahora en la clase URLLoader.

Ver los ejemplos

Elementos de API relacionados

flash.net.URLLoader
Clase XML

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		attributes : Object Objeto que contiene todos los atributos de la instancia XMLNode especificada.	XMLNode
		childNodes : Array [solo lectura] Conjunto de los elementos secundarios del objeto XMLNode especificado.	XMLNode
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		docTypeDecl : Object = null Especifica información sobre la declaración DOCTYPE del documento XML.	XMLDocument
		firstChild : XMLNode Evalúa el objeto XMLDocument especificado y hace referencia al primer elemento secundario de la lista de elementos secundarios del nodo principal.	XMLNode
		idMap : Object Objeto que contiene los nodos del XML que tienen asignado un atributo id.	XMLDocument
		ignoreWhite : Boolean = false Cuando se establece con el valor true, los nodos de texto que contienen sólo espacio en blanco se descartan durante el proceso de análisis.	XMLDocument
		lastChild : XMLNode Valor XMLNode que hace referencia al último elemento secundario de la lista de elementos secundarios del nodo.	XMLNode
		localName : String [solo lectura] La parte de nombre local del nombre del nodo XML.	XMLNode
		namespaceURI : String [solo lectura] Si el nodo XML tiene un prefijo, namespaceURI es el valor de la declaración xmlns para ese prefijo (el URI), que normalmente se denomina URI de espacio de nombres.	XMLNode
		nextSibling : XMLNode Valor XMLNode que hace referencia al siguiente elemento secundario de la lista de elementos secundarios del nodo principal.	XMLNode
		nodeName : String Cadena que representa el nombre del nodo del objeto XMLNode.	XMLNode
		nodeType : uint Un valor de constante nodeType, que puede ser XMLNodeType.ELEMENT_NODE para un elemento XML o XMLNodeType.TEXT_NODE para un nodo de texto.	XMLNode
		nodeValue : String Valor de nodo del objeto XMLDocument.	XMLNode
		parentNode : XMLNode Valor de XMLNode que hace referencia al nodo principal del objeto XML especificado o devuelve null si el nodo no tiene elemento principal.	XMLNode
		prefix : String [solo lectura] La parte de prefijo del nombre del nodo XML.	XMLNode
		previousSibling : XMLNode Valor XMLNode que hace referencia al elemento secundario anterior de la lista de elementos secundarios del nodo principal.	XMLNode
		xmlDecl : Object = null Cadena que especifica información sobre una declaración XML de un documento.	XMLDocument

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		XMLDocument(source:String = null) Crea un nuevo objeto XMLDocument.	XMLDocument
		appendChild(node:XMLNode):void Añade el nodo especificado a la lista secundaria del objeto XML.	XMLNode
		cloneNode(deep:Boolean):XMLNode Construye y devuelve un nuevo nodo XML del mismo tipo, nombre, valor y atributos que el objeto XML especificado.	XMLNode
		createElement(name:String):XMLNode Crea un nuevo objeto XMLNode con el nombre especificado en el parámetro.	XMLDocument
		createTextNode(text:String):XMLNode Crea un nuevo nodo de texto XML con el texto especificado.	XMLDocument
		getNamespaceForPrefix(prefix:String):String Devuelve el valor URI de espacio de nombres asociado con el prefijo especificado para el nodo.	XMLNode
		getPrefixForNamespace(ns:String):String Devuelve el prefijo de nombre asociado con el valor URI de espacio de nombres especificado para el nodo.	XMLNode
		hasChildNodes():Boolean Indica si el objeto XMLNode especificado tiene nodos secundarios.	XMLNode
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		insertBefore(node:XMLNode, before:XMLNode):void Inserta un nodo secundario en la lista de secundarios del objeto XML, delante del nodo beforeNode.	XMLNode
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		parseXML(source:String):void Analiza el texto XML especificado en el parámetro de valor y llena el objeto XMLDocument especificado con el árbol XML resultante.	XMLDocument
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		removeNode():void Quita el objeto XML especificado de su elemento principal.	XMLNode
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		toLocaleString():String Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional.	Object
		toString():String [override] Devuelve una representación de cadena del objeto XML.	XMLDocument
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object

Información sobre propiedades

docTypeDecl

propiedad

public var docTypeDecl:Object = null

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Especifica información sobre la declaración DOCTYPE del documento XML. Una vez que el texto XML se ha analizado en un objeto XMLDocument, la propiedad XMLDocument.docTypeDecl del objeto XMLDocument se define como el texto de la declaración DOCTYPE del documento XML (por ejemplo, <!DOCTYPE greeting SYSTEM "hello.dtd">). Esta propiedad se define utilizando una representación de cadena de la declaración DOCTYPE, no un objeto de nodo XMLNode.

El analizador XML de ActionScript heredado no es un analizador validador. El analizador lee la declaración DOCTYPE, que se almacena en la propiedad XMLDocument.docTypeDecl, pero no se lleva a cabo ninguna validación DTD.

Si no se ha encontrado ninguna declaración DOCTYPE durante la operación de análisis, la propiedad XMLDocument.docTypeDecl se define como null. El método XML.toString() genera el contenido de XML.docTypeDecl inmediatamente después de la declaración XML almacenada en XML.xmlDecl y antes que cualquier otro texto del objeto XML. Si XMLDocument.docTypeDecl es null, no se genera ninguna declaración DOCTYPE.

idMap

propiedad

public var idMap:Object

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Un objeto con los nodos del archivo XML que tienen un atributo id asignado. Los nombres de las propiedades del objeto (cada una contiene un nodo) corresponden a los valores de los atributos id.

Estudie el siguiente objeto XMLDocument:

     <employee id='41'>
         <name>
             John Doe
         </name>
         <address>
             601 Townsend St.
         </address>
     </employee>
     
     <employee id='42'>
         <name>
             Jane Q. Public
         </name>
     </employee>
     <department id="IT">
         Information Technology
     </department>

En este ejemplo, la propiedad idMap para este XMLDocument es un objeto con tres propiedades: 41, 42 y IT. Cada una de estas propiedades es un nodo XMLNode que tiene el correspondiente valor id. Por ejemplo, la propiedad IT del objeto idMap es este nodo:

     <department id="IT">
         Information Technology
     </department>

Debe utilizar el método parseXML() en el objeto XMLDocument para que se cree una instancia de la propiedad idMap.

Si hay más de un XMLNode con el mismo valor de id, la propiedad correspondiente del objeto idNode es la del último nodo analizado. Por ejemplo:

     var x1:XML = new XMLDocument("<a id='1'><b id='2' /><c id='1' /></a>");
     x2 = new XMLDocument();
     x2.parseXML(x1);
     trace(x2.idMap['1']);

El resultado será el nodo <c>:

     <c id='1' />

ignoreWhite

propiedad

public var ignoreWhite:Boolean = false

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Cuando se establece con el valor true, los nodos de texto que contienen sólo espacio en blanco se descartan durante el proceso de análisis. Los nodos de texto con espacio en blanco al principio o al final no se ven afectados. El valor predeterminado es false.

Puede establecer la propiedad ignoreWhite para objetos XMLDocument individuales, como se muestra en el siguiente código:

     my_xml.ignoreWhite = true;

xmlDecl

propiedad

public var xmlDecl:Object = null

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Cadena que especifica información sobre una declaración XML de un documento. Una vez que el documento XML se ha analizado e incorporado a un objeto XMLDocument, esta propiedad se establece con el texto de la declaración XML del documento. Esta propiedad se establece utilizando una representación de cadena de la declaración XML, no un objeto de nodo XMLNode. Si no se ha encontrado ninguna declaración XML durante la operación de análisis, la propiedad se define como null. El método XMLDocument.toString() devuelve el contenido de la propiedad XML.xmlDecl antes que ningún otro texto del objeto XML. Si la propiedad XML.xmlDecl contiene null, no se proporciona ninguna declaración XML.

Información sobre constructores

()

Información sobre

public function XMLDocument(source:String = null)

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Crea un nuevo objeto XMLDocument. Deberá utilizar el constructor para crear un objeto XMLDocument antes de llamar a cualquier método de la clase XMLDocument.

Nota: utilice los métodos createElement() y createTextNode() para añadir elementos y nodos de texto a un árbol de documentos XML.

Parámetros

source:String (default = null) — Texto XML analizado para crear el nuevo objeto XMLDocument.

Elementos de API relacionados

XMLDocument.createElement()
XMLDocument.createTextNode()

Información sobre métodos

createElement

()

método

public function createElement(name:String):XMLNode

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Crea un nuevo objeto XMLNode con el nombre especificado en el parámetro. El nuevo nodo carece inicialmente de elemento principal, de elementos secundarios o de elementos del mismo nivel. El método devuelve una referencia al objeto XMLNode de nueva creación que representa al elemento. Este método y XMLDocument.createTextNode() son los métodos constructor para crear nodos de un objeto XMLDocument.

Parámetros

name:String — El nombre de etiqueta del elemento XMLDocument que se va a crear.

Valor devuelto

XMLNode — Objeto XMLNode.

Elementos de API relacionados

XMLDocument.createTextNode()

createTextNode

()

método

public function createTextNode(text:String):XMLNode

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Crea un nuevo nodo de texto XML con el texto especificado. El nuevo nodo carece inicialmente de elemento principal, de elementos secundarios o de elementos del mismo nivel. Este método devuelve una referencia al objeto XMLDocument que representa al nuevo nodo de texto. Este método y XMLDocument.createElement() son los métodos constructor para crear nodos de un objeto XMLDocument.

Parámetros

text:String — Texto utilizado para crear el nuevo nodo de texto.

Valor devuelto

XMLNode — Objeto XMLNode.

Elementos de API relacionados

XMLDocument.createElement()

parseXML

()

método

public function parseXML(source:String):void

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Analiza el texto XML especificado en el parámetro value y llena el objeto XMLDocument especificado con el árbol XML resultante. Se descartarán los árboles existentes en el objeto XMLDocument.

Parámetros

source:String — El texto XML que se analizará y transferirá al objeto XMLDocument especificado.

toString

()

método

override public function toString():String

Versión del lenguaje:

ActionScript 3.0

Versiones de motor de ejecución:

AIR 1.0, Flash Player 9, Flash Lite 4

Devuelve una representación de cadena del objeto XML.

Valor devuelto

String — Una representación de cadena del objeto XML.

Ejemplos Cómo utilizar este ejemplo

XMLDocumentExample.as

En el ejemplo siguiente, se utilizan las clases XMLDocument y XMLNode para analizar y dar formato a un documento XML. En lugar de cargar un archivo XML externo, el ejemplo utiliza la clase XML de nivel superior para crear el documento XML y luego lo analiza.

package {
    import flash.display.Sprite;
    import flash.xml.XMLDocument;
    import flash.xml.XMLNode;
    import flash.xml.XMLNodeType;

    public class XMLDocumentExample extends Sprite {
        public function XMLDocumentExample() {
            var result:XMLDocument = new XMLDocument();
            result.ignoreWhite = true;
            result.parseXML(getXMLString());

            var books:Array = parseBooks(result.firstChild);
            trace("books: \n" + books);
        }

        private function parseBooks(node:XMLNode):Array {
            var books:Array = new Array();

            var kids:Array = node.childNodes;
            for each(var item:XMLNode in kids) {
                parseBook(item, books);
            }

            return books;
        }

        private function parseBook(node:XMLNode, books:Array):void {
            var item:Book = new Book();
            item.setPublisher(node.attributes.publisher);
            item.setName(node.attributes.name);
            books.push(item);
        }

        private function getXMLString():String {
            var list:XML = <books>
                                <book publisher="Addison-Wesley" name="Design Patterns" />
                                <book publisher="Addison-Wesley" name="The Pragmatic Programmer" />
                                <book publisher="Addison-Wesley" name="Test Driven Development" />
                                <book publisher="Addison-Wesley" name="Refactoring to Patterns" />
                                <book publisher="O'Reilly Media" name="The Cathedral & the Bazaar" />
                                <book publisher="O'Reilly Media" name="Unit Test Frameworks" />
                            </books>;
            return list.toXMLString();
        }
    }

}
class Book {
    private var publisher:String;
    private var name:String;

    public function setPublisher(publisher:String):void {
        this.publisher = publisher;
    }

    public function setName(name:String):void {
        this.name = name;
    }

    public function toString():String {
        return "[Book name: " + name + " publisher: " + publisher + "]\n";
    }
}

Avisos legales | Política de privacidad en línea

XMLDocument - AS3

Paquetesx

Elementos del lenguaje

Apéndices

Paquete flash.xml

docTypeDecl

idMap

ignoreWhite

xmlDecl

XMLDocument

createElement

createTextNode

parseXML

toString