XMLSignatureValidator  - AS3

El estado de validez de la firma criptográfica calculada sobre el elemento de firma SignedInfo.

El estado puede ser:

• valid: si la firma es válida criptográficamente.
• invalid: si se ha modificado el método digest tras la firma.
• unknown: si no se ha llamado al método verify().

Nota: si digestStatus no es válido, identityStatus y referencesStatus no se comprueban y se consideran unknown.

Estado de validez del certificado de firma.

El estado puede ser:

• valid: el certificado no ha caducado, no se han producido errores en la comprobación de revocación y se ha vinculado a un certificado raíz de confianza.
• unknown: el certificado no ha caducado, no se han producido errores en la comprobación de revocación, pero no se ha vinculado a ningún certificado raíz de confianza. El estado unknown también se activa si no se ha verificado el estado, bien porque no se ha llamado al método verify() o porque la firma criptográfica del elemento SignedInfo (digestStatus) no es válida.
• invalid: el certificado ha caducado o se han producido errores en la comprobación de revocación.

Los certificados añadidos con el método addCertificate() y las propiedades de revocationCheckSetting y useSystemTrustStore pueden definir si un certificado se considera válido o no.

Nota: si identityStatus no es válido, referencesStatus no se comprueba y se considera unknown. Además, las referencias tampoco se comprueban si identityStatus es desconocido, a no ser que referencesValidationSetting sea validOrUnknownIdentity

Elementos de API relacionados

 import flash.security.XMLSignatureValidator;
 
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var identityResult:String = verifier.identityStatus;

La propiedad isSupported se establece en true si la clase XMLSignatureValidator se admite en la plataforma actual; en caso contrario, se establece en false.

El estado de validez de los datos en las referencias del elemento de firma SignedInfo.

El estado puede ser:

• valid: si todas las referencias son válidas.
• invalid: si alguna referencia no es válida.
• unknown: si no está verificado. Las referencias pueden quedar sin verificar en las circunstancias siguientes:
  • no se ha llamado al método verify().
  • la firma criptográfica del elemento SignedInfo (digestStatus) no es válida.
  • el certificado de firma (identityStatus) no es válido.
  • referencesValidationSetting es validIdentity (parámetro predeterminado) y el estado identityStatus del certificado de firma es desconocido.
  • referencesValidationSetting es never.

Importante: los recursos externos no se validan a no ser que hagan referencia directa a un elemento SignedInfo del documento de firma. Los recursos externos a los que hace referencia una referencia secundaria no se validan. Por ejemplo, si una firma XML firma un elemento manifest, sólo se verificará la integridad del propio elemento manifest. Los archivos incluidos en el elemento manifest no se comprueban.

Elementos de API relacionados

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var dataResult:String = verifier.referencesStatus;

Especifica las condiciones en las que se comprueban determinadas referencias.

Utilice las constantes definidas en la clase ReferencesValidationSetting para establecer esta propiedad. Entre los parámetros se incluye:

• ReferencesValidationSetting.VALID_IDENTITY: comprueba referencias sólo si el certificado de firma es válido y enlaza a una raíz de confianza. Este es el valor predeterminado.
• ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY: comprueba referencias si el certificado de firma es válido, incluso si no enlaza a ninguna raíz de confianza.
• ReferencesValidationSetting.NEVER: no comprueba referencias nunca.

Utilice el parámetro predeterminado validIdentity con firmas autorizadas con certificados comerciales o proporcione su propio certificado como anclaje de confianza con el método addCertificate(). Esta configuración impide la sobre carga de comprobación de validez de referencias si el documento firmado se va a rechazar de todas formas.

Utilice el parámetro validOrUnknownIdentity con firmas firmadas con certificados autofirmados. Este parámetro permite validar datos firmados que no hayan sido modificados, pero no garantiza la identidad del firmante.

Utilice el parámetro never para evitar la sobre carga de validación de referencias si dicha validación no es crucial en el contexto de su aplicación.

Elementos de API relacionados

 import flash.security.ReferencesValidationSetting;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;

Especifica el modo en que se comprueba la revocación del certificado.

Utilice las constantes definidas en la clase RevocationSettings para establecer esta propiedad. Entre los parámetros se incluye:

• RevocationCheckSettings.NEVER: no se comprueba la revocación del certificado.
• RevocationCheckSettings.BEST_EFFORT: se comprueba la revocación del certificado en caso de estar disponible su información, y es posible obtener el estado de la revocación. Si no es posible determinar el estado de la revocación, el certificado no se rechaza.
• RevocationCheckSettings.REQUIRED_IF_AVAILABLE: si el certificado contiene información de la revocación, deberá determinarse obligatoriamente su estado para validar el certificado.
• RevocationCheckSettings.ALWAYS_REQUIRED: siempre se comprueba la revocación del certificado. Los certificados sin información de revocación se rechazan.

Elementos de API relacionados

El campo de nombre frecuente del certificado de firma.

 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var commonName:String = verifier.signerCN;

El campo de nombre único del certificado de firma.

 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var distinguishedName:String = verifier.signerDN;

Un conjunto que contiene los OID de usos de clave extendida incluidos en el certificado de firma.

Cada uso de clave extendida se registra en formato de OID numérico.

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var extendedKeyOIDs:Array = verifier.signerExtendedKeyUsages;

Conjunto que contiene los parámetros de confianza del certificado de firma.

Los parámetros de confianza se derivan del sistema y de los OID de uso de claves incorporados en el certificado. Las constantes de las cadenas que representan los parámetros de confianza conocidos se definen en la clase SignerTrustSettings.

El conjunto signerTrustSettings de un certificado unknown o invalid está vacío.

Modificar la raíz no cambia los parámetros de confianza del certificado.

Elementos de API relacionados

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var certificateTrustedFor:Array = verifier.signerTrustSettings;

La implementación de IURIDereferencer.

Se debe proporcionar una implementación de IURIDereferencer antes de intentar verificar una firma.

Elementos de API relacionados

 import com.example.SignedMessageDereferencer; //A custom class implementing IURIDereferencer
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.uriDereferencer = new SignedMessageDereferencer();

Especifica que los certificados del almacén de confianza del sistema se utilizan para la creación del vínculo.

Si es true, las anclas de confianza del almacén de confianza del sistema se utilizan como raíces de confianza. El almacén de confianza del sistema no se utiliza de forma predeterminada.

 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.useSystemTrustStore = true;

Estado de validez de una firma XML verificada.

La firma XML se verifica mediante la validación de la firma criptográfica del elemento SignedInfo, el certificado de firma y lo sdatos asociados por las referencias del elemento SignedInfo. La validez de cada uno de estos elementos se asume individualmente mediante las propiedades digestStatus, identityStatus() y referencesStatus, respectivamente.

La validez de una firma XML puede tener los valores valid (válido), invalid (no válido) o unknown (desconocido). El estado general depende del estado de verificación de los distintos componentes del archivo de firma:

• digestStatus: la validez de la firma criptográfica calculada sobre el elemento SignedInfo.
• identityStatus: la validez del certificado de firma.
• referencesStatus: la validez del método digest de las referencias del elemento de firma SignedInfo.

La validez de firma registrada en la propiedad validityStatus puede ser:

• valid: si referencesStatus, digestStatus y identityStatus son todos valid.
• invalid: si alguno de los estados individuales es invalid.
• unknown: si algún estado individual es unknown.

Elementos de API relacionados

 import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate the signature...
  
 var validationResult:String = verifier.validityStatus;

Crea un objeto XMLSignatureValidator.

Debe establecer la propiedad uriDereferencer antes de llamar al método verify() del nuevo objeto.

Elementos de API relacionados

 
import com.example.EnvelopedDereferencer; //Your custom IURIDereferencer implementation

//Create the object
var verifier:XMLSignatureValidator = new XMLSignatureValidator();

//Provide the IURIDerferencer
verifier.uriDereferencer = new EnvelopedDereferencer(xmlDoc);

//Set validation options
verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;
verifier.revocationCheckSetting = RevocationCheckSettings.NEVER;
verifier.useSystemTrustStore = true;

//Add listeners to handle results
verifier.addEventListener(Event.COMPLETE, verificationComplete);
verifier.addEventListener(ErrorEvent.ERROR, verificationError);

Añade un certificado x509 a la creación del vínculo.

El certificado añadido debe ser un certificado x509 con codificación DER.

Si el parámetro trusted es true, el certificado se considera un ancla de confianza.

Nota: una firma XML puede contener certificados para crear el vínculo de certificados del firmante. De forma predeterminada, la clase XMLSignatureValidator utiliza estos certificados para crear el vínculo, pero no como raíces de confianza.

Parámetros

 import flash.utils.ByteArray;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 var certificate:ByteArray = new ByteArray();
 
 var certFile:File = new File("certificate.cer");
 var certFileStream:FileStream = new FileStream();
 certFileStream.open(certFile, FileMode.READ);
 certFileStream.readBytes(certificate, 0, certFileStream.bytesAvailable);

 verifier.addCertificate(certificate, true);

Verifica la firma especificada.

La verificación es asíncrona. El objeto XMLSignatureValidator distribuye un evento complete cuando la verificación finaliza correctamente, o distribuye un evento error si la verificación no puede completarse por la aparición de errores.

No es posible cancelar el proceso de verificación. Una vez iniciado el proceso de verificación, las llamadas que se realicen al método verify() fallan. Una vez completado el proceso de verificación, puede volver a llamar al método verify().

Nota: dado que XMLSignatureValidator únicamente implemente un subconjunto de la recomendación del W3C para el procesado y sintaxis de firma XML, no todas las firmas que no son XML se pueden verificar.

Parámetros

import flash.filesystem.File;
import flash.filesystem.FileStream;
import com.example.SignedMessageDereferencer; //Your IURIDereferencer implementation
 
const xmlSignatureNS:Namespace = new Namespace( "http://www.w3.org/2000/09/xmldsig#" );

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
verifier.uriDereferencer = new SignedMessageDereferencer();

var signatureFile:File = new File( "path/to/XMLSignatureDocument.xml" );
var sigFileStream:FileStream = new FileStream();
sigFileStream.open( signatureFile, FileMode.READ );

var xmlDoc:XML = XML( sigFileStream.readUTFBytes(sigFileStream.bytesAvailable) );
var xmlSig:XML = XML( xmlDoc..xmlSignatureNS::Signature );

verifier.verify( xmlSig );

Se distribuye una vez completada la verificación.

Un evento complete no implica que la firma sea válida. Verifique la propiedad validityStatus del objeto XMLSignatureValidator para determinar el resultado de la verificación de la firma.

Este evento tiene las propiedades siguientes:

private function verificationComplete(event:Event):void{
    var validator:XMLSignatureValidator = event.target as XMLSignatureValidator;
    trace("Digest status: " + validator.digestStatus);
    trace("Identity status: " + validator.identityStatus);
    trace("Reference status: " + validator.referencesStatus);
    trace("Signature status: " + validator.validityStatus);    
}

Elementos de API relacionados

Se distribuye si no se puede completar la verificación por la aparición de errores.

Este evento tiene las propiedades siguientes:

private function verificationError(event:ErrorEvent):void{
    trace("Verification error: " + event.text);                
}