NetGroup  - AS3

Especifica un número estimado de miembros del grupo basado en la densidad de los elementos locales colindantes y asumiendo una distribución uniforme de direcciones de grupo.

Elementos de API relacionados

Devuelve un objeto NetGroupInfo cuyas propiedades proporcionan estadísticas de calidad de servicio relacionadas con el transporte de datos RTMFP P2P de este objeto NetGroup.

Elementos de API relacionados

Especifica el comienzo del rango de direcciones de grupo para el cual este nodo es el “más cercano” y responsable. El rango se especifica en dirección ascendente en el anillo de direcciones de grupo (mod 2²⁵⁶).

Elementos de API relacionados

Especifica el final del rango de direcciones de grupo para el cual este nodo es el “más cercano” y responsable. El rango se especifica en dirección ascendente en el anillo de direcciones de grupo (mod 2²⁵⁶).

Elementos de API relacionados

Especifica el número de miembros del grupo al que este nodo se conecta directamente.

Elementos de API relacionados

Especifica el modo de recepción de enrutamiento de este nodo como uno de los valores de la clase NetGroupReceiveMode enum.

Elementos de API relacionados

Especifica la estrategia de recogida de duplicación de objetos. El valor es uno de los valores enumerados en la clase NetGroupReplicationStrategy.

Elementos de API relacionados

Construye un objeto NetGroup en el objeto NetConnection especificado y lo combina con el grupo especificado por groupspec.

En la mayoría de los casos, groupspec tiene el potencial de usar el enlaces ascendentes de red en el sistema local. Cuando un objeto NetStream o NetGroup se construye con un groupspec, Flash Player muestra un diálogo Privacidad. El diálogo le preguntará si Flash Player puede utilizar la conexión para compartir datos con un usuario homólogo. Si el usuario hace clic en "Permitir para este dominio", el diálogo no aparece la próxima vez que el usuario se conecte en la aplicación. Si un usuario no permite redes asistidas por pares, todas las funciones del grupo (envío, enrutamiento dirigido, duplicación de objetos y multidifusión) se desactivan. Si se permite, se envía un evento NetStatusEvent al detector de eventos NetConnection con NetGroup.Connect.Success en la propiedad code del objeto info. Si se deniega, la propiedad code es NetGroup.Connect.Rejected. Hasta que no se recibe un evento NetGroup.Connect.Success, se emitirá una excepción si se intenta llamar a cualquier método del objeto NetGroup.

Nota: cuando un cliente se suscribe a una de multidifusión IP nativa, el diálogo Seguridad no aparece.

     new NetGroup(myConnection, myGroupSpecifier.groupspecWithAuthorizations());
     

Elementos de API relacionados

Añade objetos de startIndex a endIndex al conjunto de objetos que este nodo anuncia a sus elementos colindantes como objetos para los que cumplirán las peticiones. De forma predeterminada, el conjunto Have está vacío. Los índices deben ser números enteros entre 0 y 9007199254740992.

Para obtener más información sobre duplicación de objetos, consulte “Replicate an object within a group” en Flash Media Server Developer’s Guide.

Este método envía un evento NetStatusEvent al detector de eventos NetGroup con "NetGroup.Replication.Request" en la propiedad code del objeto info.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Añade un registro manualmente especificando que peerID es un miembro del grupo. Se intenta establecer una conexión inmediata sólo si es necesario para la topología.

Parámetros

Elementos de API relacionados

Añade un elemento colindante manualmente por conexión directa inmediata con el peerID especificado, que ya debe estar en este grupo. Esta conexión directa se puede descargar más adelante si no es necesaria para la topología.

Parámetros

Elementos de API relacionados

Añade objetos de startIndex a endIndex al conjunto de objetos que se va a recuperar. Los índices deben ser números enteros entre 0 y 9007199254740992. De forma predeterminada, el conjunto Want está vacío.

Para obtener más información sobre duplicación de objetos, consulte “Replicate an object within a group” en Flash Media Server Developer’s Guide.

Este método envía un evento NetStatusEvent al detector de eventos NetGroup con NetGroup.Replication.Fetch.SendNotify en la propiedad info.code. Este evento es seguido por un evento NetGroup.Replication.Fetch.Failed o NetGroup.Replication.Fetch.Result.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Se desconecta del grupo y cierra este NetGroup. Este NetGroup no se puede utilizar después de llamar a este método.

Convierte un peerID en una dirección de grupo adecuada para su uso con el método sendToNearest().

Parámetros

Elementos de API relacionados

Deniega a una solicitud recibida en NetGroup.Replication.Request de NetStatusEvent para un objeto previamente anunciado con addHaveObjects(). El solicitante puede volver a pedir este objeto a no ser que (o hasta que) se extraiga del conjunto Have.

Para obtener más información sobre duplicación de objetos, consulte “Replicate an object within a group” en Flash Media Server Developer’s Guide.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Envía un mensaje a todos los miembros del grupo. Para llamar a este método, la propiedad GroupSpecifier.postingEnabled debe ser true en el groupspec transferido al constructor NetGroup. Para obtener más información, consulte “Post messages to a group” en Flash Media Server Developer’s Guide.

Todos los mensajes deben ser exclusivos; un mensaje idéntico a otro publicados anteriormente tal vez no se propague. Utilice un número secuencial para que los mensajes sean exclusivos.

La entrega de mensajes no se ordena. La entrega de mensajes no se garantiza.

Los mensajes se serializan en AMF. El mensaje puede ser de uno de los siguientes tipos: Objecto, int, Number o String. El mensaje no puede ser un objeto MovieClip.

Este método envía un evento NetStatusEvent al detector de eventos NetGroup con "NetGroup.Posting.Notify" en la propiedad info.code. El evento "NetGroup.Posting.Notify" se distribuye a NetGroup tanto en el cliente como en el servidor.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

package  {

    import flash.display.Sprite;
    import flash.events.TextEvent;
    import flash.events.MouseEvent;
    import flash.events.NetStatusEvent;
    import fl.events.ComponentEvent;
    import fl.controls.Label;
    import fl.controls.Button;
    import fl.controls.TextInput;
    import fl.controls.TextArea;
    import flash.text.TextFieldAutoSize;
    import flash.net.*;

    public class NetGroupPostExample extends Sprite{

        private var connectButton:Button;
        private var disconnectButton:Button;
        private var groupNameText:TextInput;
        private var userNameText:TextInput;
        private var chatText:TextInput;
        private var statusLog:TextArea;
        private var groupLabel:Label;
        private var userLabel:Label;

        private var netConnection:NetConnection = null;
        private var netGroup:NetGroup = null;
        private var sequenceNumber:uint = 0;
        private var connected:Boolean = false;
        private var joinedGroup:Boolean = false;

        private const SERVER:String = "rtmfp://fms.example.com/someapp";

        public function NetGroupPostExample() {
            DoUI();
        }

        // Writes messages to the TextArea.
        private function StatusMessage(msg:Object):void{
            statusLog.text += msg;
            statusLog.verticalScrollPosition = statusLog.textHeight;
            statusLog.validateNow();
        }

        // Handles all NetStatusEvents for the NetConnection and the NetGroup.
        // This code includes cases it doesn't handle so you can see the cases
        // and their info objects for learning purposes.
        private function NetStatusHandler(e:NetStatusEvent):void{
            StatusMessage(e.info.code + "\n");
            switch(e.info.code){
                case "NetConnection.Connect.Success":
                    connectButton.enabled = false;
                    disconnectButton.enabled = true;
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                    OnDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;

                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }
        // Creates a NetConnection to Flash Media Server if the app isn't already connected
        // and if there's a group name in the TextInput field.
        private function DoConnect(e:MouseEvent):void{
            if(!connected && (groupNameText.length > 0)){
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                // To connect to Flash Media Server, pass the server name.
                netConnection.connect(SERVER);
            }
            else
            {
                StatusMessage("Enter a group name");
            }
        }

        // Called in the "NetConnection.Connect.Success" case in the NetStatusEvent handler.
        private function OnConnect():void{

            StatusMessage("Connected\n");
            connected = true;

            // Create a GroupSpecifier object to pass to the NetGroup constructor.
            // The GroupSpecifier determines the properties of the group
            var groupSpecifier:GroupSpecifier;
            groupSpecifier = new GroupSpecifier("aslrexample/" + groupNameText.text);
            groupSpecifier.postingEnabled = true;
            groupSpecifier.serverChannelEnabled = true;

            netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
            netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

            StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");

        }

        private function OnNetGroupConnect():void{
            joinedGroup = true;
        }

        private function DoDisconnect(e:MouseEvent):void{
            if(netConnection){
                netConnection.close();
            }
        }

        private function OnDisconnect():void{
            StatusMessage("Disconnected\n");
            netConnection = null;
            netGroup = null;
            connected = false;
            joinedGroup = false;
            connectButton.enabled = true;
            disconnectButton.enabled = false;
        }

        private function ClearChatText():void{
            chatText.text = "";
        }

        // Called when you the chatText field has focus and you press Enter.
        private function DoPost(e:ComponentEvent):void{
            if(joinedGroup){
                var message:Object = new Object;
                message.user = userNameText.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);
                StatusMessage("==> " + chatText.text + "\n");
            } else {
                StatusMessage("Click Connect before sending a chat message");
            }
            ClearChatText();
        }

        private function OnPosting(message:Object):void{
            StatusMessage("<" + message.user + "> " + message.text + "\n");
        }

        private function DoUI():void {

            groupLabel = new Label();
            groupLabel.move(20, 10);
            groupLabel.autoSize = TextFieldAutoSize.LEFT
            groupLabel.text = "Group name:"
            addChild(groupLabel);

            groupNameText = new TextInput();
            groupNameText.move(90, 10);
            groupNameText.text = "channel" + (int(Math.random() * 899) + 101);
            addChild(groupNameText);

            connectButton = new Button();
            connectButton.addEventListener(MouseEvent.CLICK, DoConnect);
            connectButton.move(205, 10);
            connectButton.label = "Connect";
            addChild(connectButton);

            disconnectButton = new Button();
            disconnectButton.addEventListener(MouseEvent.CLICK, DoDisconnect);
            disconnectButton.move(310, 10);
            disconnectButton.label = "Disconnect";
            disconnectButton.enabled = false;
            addChild(disconnectButton);

            statusLog = new TextArea();
            statusLog.move(30, 38);
            statusLog.width = 360;
            statusLog.height = 215;
            statusLog.editable = false;
            addChild(statusLog);

            userLabel = new Label();
            userLabel.move(20, 270);
            userLabel.autoSize = TextFieldAutoSize.LEFT
            userLabel.text = "User name:"
            addChild(userLabel);

            userNameText = new TextInput();
            userNameText.move(80, 270);
            userNameText.text = "user " + int(Math.random() * 65536);
            addChild(userNameText);

            chatText = new TextInput();
            chatText.addEventListener(ComponentEvent.ENTER, DoPost);
            chatText.move(185, 270);
            chatText.maxChars = 255;
            chatText.width = 215;
            addChild(chatText);

        }

        public function onPlayStatus(info:Object):void {}
        public function onMetaData(info:Object):void {}
        public function onCuePoint(info:Object):void {}
        public function onTextData(info:Object):void {}

    }

}

Elimina objetos de startIndex a endIndex del conjunto de objetos que este nodo anuncia a sus elementos colindantes como objetos para los que cumplirán las peticiones. Los índices deben ser números enteros entre 0 y 9007199254740992.

Para obtener más información sobre duplicación de objetos, consulte “Replicate an object within a group” en Flash Media Server Developer’s Guide.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Elimina los objetos de startIndex a endIndex del conjunto de objetos para recuperar. Los índices deben ser números enteros entre 0 y 9007199254740992.

Para obtener más información sobre duplicación de objetos, consulte “Replicate an object within a group” en Flash Media Server Developer’s Guide.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Envía un mensaje a todos los elementos colindantes. Devuelve NetGroupSendResult.SENT si al menos se ha seleccionado un elemento colindante.

Para obtener más información sobre los mensajes de enrutamiento, consulte “Route messages directly to a peer” en Flash Media Server Developer’s Guide.

Cuando un nodo recibe un mensaje, se envía un evento NetStatusEvent al detector de eventos de NetGroup con NetGroup.SendTo.Notify en la propiedad code del objeto info.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Envía un mensaje al elemento colindante (o nodo local) más cercano a la dirección de grupo especificada. Considera elementos colindantes de todo el anillo. Devuelve NetGroupSendResult.SENT si el mensaje se envió correctamente a su destino.

Para obtener más información sobre los mensajes de enrutamiento, consulte “Route messages directly to a peer” en Flash Media Server Developer’s Guide.

Cuando un nodo recibe un mensaje, se envía un evento NetStatusEvent al detector de eventos de NetGroup con NetGroup.SendTo.Notify en la propiedad code del objeto info.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Envía un mensaje al elemento colindante especificado por el parámetro sendMode. Devuelve NetGroupSendResult.SENT si el mensaje se envió correctamente al destino solicitado.

Para obtener más información sobre los mensajes de enrutamiento, consulte “Route messages directly to a peer” en Flash Media Server Developer’s Guide.

Cuando un nodo recibe un mensaje, se envía un evento NetStatusEvent al detector de eventos de NetGroup con NetGroup.SendTo.Notify en la propiedad code del objeto info.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Cumple la petición tal como se recibió por NetGroup.Replication.Requestde NetStatusEvent para un objeto previamente anunciado con el método addHaveObjects(). El objeto puede ser: Object, int, Number y String. El objeto no puede ser MovieClip.

Para obtener más información sobre duplicación de objetos, consulte “Replicate an object within a group” en Flash Media Server Developer’s Guide.

NOTA: pruebe el evento NetGroup.Neighbor.Connect antes de llamar a este método.

Parámetros

Elementos de API relacionados

Se distribuye cuando un objeto NetGroup informa sobre su estado o situación de error. El evento netStatus contiene una propiedad info. El evento incluye una propiedad info que contiene información sobre el evento, por ejemplo, si el intento de conexión se realizó correctamente o si falló.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Cuando se ejecuta la aplicación, puede introducir cualquier nombre de grupo en el campo de entrada de texto. La clase GroupSpecifier utiliza el nombre (junto con las propiedades GroupSpecifier que se hayan definido) para crear una cadena que es el nombre exclusivo indefinido del grupo. Para conectar con otro cliente al grupo, el cliente debe utilizar el mismo nombre de grupo. Por ejemplo, si el cliente A utiliza el nombre de grupo "malla", otros clientes que quieran comunicarse con el cliente A también deberán utilizar el nombre de grupo "malla". Si el cliente B utiliza el nombre del grupo "cometa", se conectará correctamente, pero que no creará un nuevo grupo y no podrá comunicarse con el cliente A ni con ningún miembro del grupo "malla".

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="100%" height="100%" applicationComplete="OnApplicationComplete()">
    <mx:Script>
        <![CDATA[
            private var netConnection:NetConnection = null;
            private var netStream:NetStream = null;
            private var netGroup:NetGroup = null;
            private var video:Video = null;
            private var sequenceNumber:uint = 0;
            private var resizeTimer:Timer = null;

            private const SERVER:String = "rtmfp://fms.example.com/someapp";

            [Bindable] private var connected:Boolean = false;
            [Bindable] private var joinedGroup:Boolean = false;

            private function OnApplicationComplete():void
            {
                userName.text = "user " + int(Math.random() * 65536);

                groupName.text = "channel" + (int(Math.random() * 899) + 101);

                resizeTimer = new Timer(2000.0);
                resizeTimer.addEventListener(TimerEvent.TIMER, DoResizeVideo);
                resizeTimer.start();
            }

            private function StatusMessage(msg:Object):void
            {
                statusLog.text += msg;
                statusLog.verticalScrollPosition = statusLog.textHeight;
                statusLog.validateNow();
            }

            private function NetStatusHandler(e:NetStatusEvent):void
            {
                StatusMessage(e.info.code);
                switch(e.info.code)
                {
                case "NetConnection.Connect.Success":
                    OnConnect();
                    break;

                case "NetConnection.Connect.Closed":
                case "NetConnection.Connect.Failed":
                case "NetConnection.Connect.Rejected":
                case "NetConnection.Connect.AppShutdown":
                case "NetConnection.Connect.InvalidApp":
                    OnDisconnect();
                    break;

                case "NetStream.Connect.Success": // e.info.stream
                    OnNetStreamConnect();
                    break;

                case "NetStream.Connect.Rejected": // e.info.stream
                case "NetStream.Connect.Failed": // e.info.stream
                    DoDisconnect();
                    break;

                case "NetGroup.Connect.Success": // e.info.group
                    OnNetGroupConnect();
                    break;

                case "NetGroup.Connect.Rejected": // e.info.group
                case "NetGroup.Connect.Failed": // e.info.group
                    DoDisconnect();
                    break;

                case "NetGroup.Posting.Notify": // e.info.message, e.info.messageID
                    OnPosting(e.info.message);
                    break;


                case "NetStream.MulticastStream.Reset":
                case "NetStream.Buffer.Full":
                    DoResizeVideo();
                    break;

                case "NetGroup.SendTo.Notify": // e.info.message, e.info.from, e.info.fromLocal
                case "NetGroup.LocalCoverage.Notify": //
                case "NetGroup.Neighbor.Connect": // e.info.neighbor
                case "NetGroup.Neighbor.Disconnect": // e.info.neighbor
                case "NetGroup.MulticastStream.PublishNotify": // e.info.name
                case "NetGroup.MulticastStream.UnpublishNotify": // e.info.name
                case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
                case "NetGroup.Replication.Fetch.Failed": // e.info.index
                case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
                case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
                default:
                    break;
                }
            }

            private function DoConnect():void
            {
                StatusMessage("Connecting to \"" + SERVER + "\" ...\n");
                netConnection = new NetConnection();
                netConnection.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);
                netConnection.connect(SERVER);
            }

            private function OnConnect():void
            {
                var groupSpecifier:GroupSpecifier;

                StatusMessage("Connected\n");
                connected = true;

                groupSpecifier = new GroupSpecifier("max2009lab/" + groupName.text);
                groupSpecifier.multicastEnabled = true;
                groupSpecifier.postingEnabled = true;
                groupSpecifier.serverChannelEnabled = true;

                netStream = new NetStream(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netStream.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                netGroup = new NetGroup(netConnection, groupSpecifier.groupspecWithAuthorizations());
                netGroup.addEventListener(NetStatusEvent.NET_STATUS, NetStatusHandler);

                StatusMessage("Join \"" + groupSpecifier.groupspecWithAuthorizations() + "\"\n");
            }

            private function OnNetStreamConnect():void
            {
                netStream.client = this;

                var mic:Microphone = Microphone.getMicrophone();
                if(mic)
                {
                    mic.codec = SoundCodec.SPEEX;
                    mic.setSilenceLevel(0);

                    netStream.attachAudio(mic);

                    StatusMessage("got microphone\n");
                }

                var camera:Camera = Camera.getCamera();
                if(camera)
                {
                    camera.setMode(320, 240, 10);
                    camera.setQuality(30000, 0);
                    camera.setKeyFrameInterval(15);

                    videoDisplay.attachCamera(camera);
                    videoDisplay.maintainAspectRatio = true;

                    netStream.attachCamera(camera);

                    StatusMessage("got camera\n");
                }

                netStream.publish("stream");
            }

            private function OnNetGroupConnect():void
            {
                joinedGroup = true;
            }

            private function DoDisconnect():void
            {
                if(netConnection)
                    netConnection.close();
                videoDisplay.attachCamera(null);
            }

            private function OnDisconnect():void
            {
                StatusMessage("Disconnected\n");
                netConnection = null;
                netStream = null;
                netGroup = null;
                connected = false;
                joinedGroup = false;
            }

            private function ClearChatText():void
            {
                chatText.text = "";
            }

            private function DoPost():void
            {
                var message:Object = new Object;

                message.user = userName.text;
                message.text = chatText.text;
                message.sequence = sequenceNumber++;
                message.sender = netConnection.nearID;

                netGroup.post(message);

                StatusMessage("==> " + chatText.text + "\n");

                chatText.callLater(ClearChatText);
            }

            private function OnPosting(message:Object):void
            {
                StatusMessage("<" + message.user + "> " + message.text + "\n");
            }

            private function DoResizeVideo(ignored:* = null):void
            {
                if(video)
                {
                    if( (0 == video.videoHeight)
                     || (0 == video.videoWidth)
                    )
                    {
                        video.height = videoDisplay.height;
                        video.width = videoDisplay.width;
                        video.x = 0;
                        video.y = 0;
                    }
                    else
                    {
                        var videoAspect:Number = Number(video.videoWidth) / Number(video.videoHeight);
                        var displayAspect:Number = Number(videoDisplay.width) / Number(videoDisplay.height);
                        var adjustFactor:Number;

                        if(videoAspect >= displayAspect) // video is wider than display
                        {
                            adjustFactor = Number(video.videoWidth) / Number(videoDisplay.width);
                            video.width = videoDisplay.width;
                            video.height = int(Number(video.videoHeight) / adjustFactor);
                            video.x = 0;
                            video.y = int((videoDisplay.height - video.height) / 2);
                        }
                        else
                        {
                            adjustFactor = Number(video.videoHeight) / Number(videoDisplay.height);
                            video.height = videoDisplay.height;
                            video.width = int(Number(video.videoWidth) / adjustFactor);
                            video.x = int((videoDisplay.width - video.width) / 2);
                            video.y = 0;
                        }
                    }
                }
            }

            public function onPlayStatus(info:Object):void {}
            public function onMetaData(info:Object):void {}
            public function onCuePoint(info:Object):void {}
            public function onTextData(info:Object):void {}

            public function ValidateConnectAllowed(isConnected:Boolean, groupNameText:String):Boolean
            {
                return (!isConnected) && (groupNameText.length > 0);
            }
        ]]>
    </mx:Script>

    <mx:VBox top="10" right="10" left="10" bottom="10" verticalGap="6">
        <mx:HBox width="100%">
            <mx:Text text="Group:"/>
            <mx:TextInput id="groupName" width="100%" text="default" enabled="{!connected}"/>
            <mx:Button label="Connect" click="DoConnect()" enabled="{ValidateConnectAllowed(connected, groupName.text)}" />
            <mx:Button label="Disconnect" click="DoDisconnect()" enabled="{connected}" />
        </mx:HBox>
        <mx:VideoDisplay id="videoDisplay" width="320" height="240" resize="DoResizeVideo()"/>
        <mx:TextArea id="statusLog" width="100%" height="100%"/>
        <mx:HBox width="100%">
            <mx:TextInput id="userName" width="160" />
            <mx:TextInput id="chatText" width="100%" enabled="{joinedGroup}" enter="DoPost()"/>
        </mx:HBox>
    </mx:VBox>

</mx:Application>