CameraRoll  - AS3

Determine si se le ha concedido a la aplicación el permiso para acceder al carrete.

Elementos de API relacionados

Si se admite el método CameraRoll.addBitmapData(). Actualmente la función sólo se admite en aplicaciones de AIR en dispositivos móviles.

Informa sobre la compatibilidad del método CameraRoll.browseForImage(). Actualmente la función sólo se admite en aplicaciones de AIR en dispositivos móviles.

Crea un objeto CameraRoll.

Sólo hay un único medio en la biblioteca admitido por ActionScript. Todos los objetos CameraRoll se guardan en el mismo repositorio de imágenes.

Añade una imagen al Carrete de la cámara del dispositivo.

Para comprobar en tiempo de ejecución si la aplicación admite el método CameraRoll.addBitmapData(), compruebe la propiedad CameraRoll.supportsAddBitmapData.

Parámetros

Abre un diálogo para buscar imágenes que permite al usuario seleccionar una imagen en el carrete de la cámara del dispositivo.

Cuando el usuario selecciona una imagen, esta instancia de CameraRoll distribuye un evento select que contiene un objeto MediaEvent. Utilice la propiedad data del objeto MediaEvent para cargar la imagen. La propiedad data es un objeto MediaPromise que se puede cargar con el método loadFilePromise() de la clase Loader. Tenga en cuenta que el objeto MediaPromise contiene un objeto de archivo válido en algunas plataformas (Blackberry Tablet OS), pero no en otros (iOS y Android). Cuando se utiliza el método loadFilePromise(), se carga la imagen correctamente en todas las plataformas. Para acceder a los datos sin procesar desde el objeto de medios, puede abrir el origen de datos suministrado por la promesa de medios y leer los datos con los métodos de la interfaz IDataInput.

Para comprobar en tiempo de ejecución si la aplicación admite el método CameraRoll.browseForImage(), compruebe la propiedad CameraRoll.supportsBrowseForImage.

En iOS (y sólo en el iPad) puede solicitar un tamaño específico para el diálogo del navegador de imágenes. También puede especificar un área de la pantalla en la que no desea que se solape el diálogo del navegador de imágenes. Esta petición sólo funciona en el iPad, porque en ese dispositivo el navegador de imágenes no ocupa toda la pantalla.

Para solicitar opciones de tamaño y posición para el navegador de imágenes (iPad), transfiera un objeto CameraRollBrowseOptions a browseForImage(). Si no hay parámetros, este método coloca el diálogo en la esquina superior izquierda de la pantalla, utilizando las dimensiones del diálogo según los valores predeterminados del sistema.

Parámetros

Más información

Elementos de API relacionados

package flash.media.examples
{
        import flash.media.CameraRoll;
        import flash.media.MediaPromise;
        import flash.media.MediaType;
        import flash.events.MediaEvent;
        import flash.events.Event;
        import flash.display.Loader;
        import flash.display.Sprite;
        import flash.events.IOErrorEvent;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
        
        public class CameraRollTest extends Sprite{
            private var mediaSource:CameraRoll = new CameraRoll();
            
            public function CameraRollTest() {
                this.stage.align = StageAlign.TOP_LEFT;
                this.stage.scaleMode = StageScaleMode.NO_SCALE;
                
                if( CameraRoll.supportsBrowseForImage )
                {
                    log( "Browsing for image..." );
                    mediaSource.addEventListener( MediaEvent.SELECT, imageSelected );
                    mediaSource.addEventListener( Event.CANCEL, browseCanceled );
                    
                    mediaSource.browseForImage();
                }
                else
                {
                    log( "Browsing in camera roll is not supported.");
                }
            }
            
            private var imageLoader:Loader; 
            private function imageSelected( event:MediaEvent ):void
            {
                log( "Image selected..." );
                
                var imagePromise:MediaPromise = event.data;
                
                imageLoader = new Loader();
                if( imagePromise.isAsync )
                {
                    log( "Asynchronous media promise." );
                    imageLoader.contentLoaderInfo.addEventListener( Event.COMPLETE, imageLoaded );
                    imageLoader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, imageLoadFailed );
                    imageLoader.loadFilePromise( imagePromise );
                }
                else
                {
                    log( "Synchronous media promise." );
                    imageLoader.loadFilePromise( imagePromise );
                    this.addChild( imageLoader );
                }
            }
            
            private function browseCanceled( event:Event ):void
            {
                log( "Image browse canceled." );
            }
            
            private function imageLoaded( event:Event ):void
            {
                log( "Image loaded asynchronously." );
                this.addChild( imageLoader );
            }
            
            private function imageLoadFailed( event:Event ):void
            {
                log( "Image load failed." );
            }
            
            private function log( text:String ):void
            {
                trace( text );
            }
            
        }
        
    }

Solicita permiso para acceder a la biblioteca o al “carrete” de medios del sistema.

Se distribuye cuando el usuario cancela una operación de navegación por imagen sin haber seleccionado ninguna imagen.

Este evento tiene las propiedades siguientes:

Indica que una operación addBitmapData() se ha completado correctamente.

Este evento tiene las propiedades siguientes:

El evento error se distribuye cuando se produce un error.

Las fuentes de errores incluyen:

• No se puede abrir un navegador de imágenes.
• Un navegador de imágenes ya está en uso.
• La aplicación de AIR intenta buscar una imagen mientras está en segundo plano.
• No se puede añadir una imagen a la biblioteca de medios.
• Se ha llamado a un método que no se admite en el dispositivo.
• La aplicación de AIR intenta cargar una imagen remota sin una conexión a Internet.

Este evento tiene las propiedades siguientes:

Se distribuye cuando la aplicación pide permiso para acceder al carrete. Compruebe el valor del estado de la propiedad para determinar si el permiso se ha concedido o denegado.

Elementos de API relacionados

Se distribuye cuando un usuario selecciona una imagen en la biblioteca de medios del dispositivo.

El objeto MediaEvent distribuido para este evento proporciona acceso a los medios elegidos.

Define el valor de la propiedad type para un objeto de evento MediaEvent Este evento tiene las propiedades siguientes: