BevelFilter  - AS3

Ángulo del bisel. Los valores válidos son de 0 a 360°. El valor predeterminado es 45°.

El valor de angle representa el ángulo de la fuente de luz teórica que ilumina el objeto y determina la posición del efecto con respecto al objeto Si la propiedad distance se define como 0, el efecto no se desplaza del objeto y el resultado es que la propiedad angle no se aplica.

Cantidad de desenfoque horizontal, expresada en píxeles. Los valores válidos son de 0 a 255 (coma flotante). El valor predeterminado es 4. Los valores que son potencia de 2 (como 2, 4, 8, 16 y 32) se optimizan para representarse más rápidamente que otros valores.

Cantidad de desenfoque vertical, expresada en píxeles. Los valores válidos son de 0 a 255 (coma flotante). El valor predeterminado es 4. Los valores que son potencia de 2 (como 2, 4, 8, 16 y 32) se optimizan para representarse más rápidamente que otros valores.

Distancia de desplazamiento del bisel. Los valores válidos son en píxeles (coma flotante). El valor por defecto es 4.

Valor de transparencia alfa del color de resaltado. El valor se especifica como un valor normalizado de 0 a 1. Por ejemplo, 0,25 establece un valor de transparencia del 25%. El valor predeterminado es 1.

Color de resaltado del bisel. Los valores válidos tienen formato hexadecimal, 0xRRGGBB. El valor predeterminado es 0xFFFFFF.

Aplica un efecto de extractor (true), que hace que el relleno del objeto sea transparente y muestra el color de fondo del documento. El valor predeterminado es false (sin extractor).

Número de veces que debe aplicarse el filtro. El valor predeterminado es BitmapFilterQuality.LOW, lo que equivale a aplicar el filtro una vez. El valor BitmapFilterQuality.MEDIUM aplica el filtro dos veces; BitmapFilterQuality.HIGH lo aplica tres veces. Los filtros con valores más bajos se representan con mayor rapidez.

Para la mayoría de las aplicaciones, es suficiente un valor quality de calidad baja, media o alta. Aunque puede utilizar valores numéricos hasta 15 para conseguir efectos distintos, los valores más altos se representan más lentamente. En lugar de aumentar el valor de quality, se suele conseguir un efecto similar, con una representación más rápida, simplemente aumentando los valores de las propiedades blurX y blurY.

Puede utilizar las siguientes constantes BitmapFilterQuality para especificar los valores de la propiedad quality:

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

Valor de transparencia alfa del color de la sombra. Este valor se especifica como un valor normalizado de 0 a 1. Por ejemplo, 0,25 establece un valor de transparencia del 25%. El valor por defecto es 1.

Color de sombra del bisel. Los valores válidos tienen formato hexadecimal, 0xRRGGBB. El valor predeterminado es 0x000000.

Intensidad de la impresión o extensión. Los valores válidos son de 0 a 255. Cuanto más alto sea el valor, más color se imprimirá y mayor será el contraste entre el bisel y el fondo. El valor predeterminado es 1.

Colocación del bisel en el objeto. Los biseles interior y exterior se colocan en los bordes interior y exterior; el bisel completo se coloca en todo el objeto. Los valores válidos son las constantes BitmapFilterType:

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

Inicializa una instancia BevelFilter nueva con los parámetros especificados.

Elementos de API relacionados

Devuelve una copia de este objeto de filtro.

1. Importe las clases necesarias.
2. Declare tres propiedades utilizadas en la función draw(), que dibuja el objeto al que se aplicará el bisel.
3. Cree la función constructora BevelFilterExample(), que realiza lo siguiente:
   • Llama a la función draw(), que se declara más adelante.
   • Declara una variable filter como objeto BitmapFilter y lo asigna al valor devuelto de una llamada a getBitmapFilter().
   • Crea un nuevo objeto Array myFilters y añade la propiedad filter al conjunto. Después asigna myFilters a la propiedad filters del objeto BevelFilterExample. Esto se aplicará a todos los filtros de myFilters que, en este caso, sólo es filter.
4. Cree la función getBitmapFilter para crear y definir las propiedades del filtro.
5. Cree la función draw(). Esta función utiliza métodos de la clase Graphics, a la que se accede mediante la propiedad graphics de la clase Sprite, para dibujar el cuadrado.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}