FocusEvent  - AS3

Especifica la dirección de selección para un evento focusIn.

Elementos de API relacionados

Si es true, la propiedad relatedObject se establece como null por motivos relacionados con entornos limitados de seguridad. Si el valor nominal de relatedObject es una referencia a un objeto DisplayObject en otro entorno limitado, relatedObject se establece como null a no ser que disponga de permiso en ambas direcciones dentro de los límites del entorno limitado. Puede establecer los permisos llamando a Security.allowDomain() desde un archivo SWF, o bien proporcionando un archivo de política desde el servidor de un archivo de imagen y estableciendo la propiedad LoaderContext.checkPolicyFile al cargar la imagen.

Elementos de API relacionados

El valor de código de la tecla presionada para desencadenar un evento keyFocusChange.

Referencia a la instancia InteractiveObject complementaria que se ve afectada por el cambio de la selección. Por ejemplo, si se produce un evento focusOut, relatedObject representa a la instancia InteractiveObject que pasa a estar seleccionada.

El valor de esta propiedad puede ser null en dos casos: si no hay ningún objeto relacionado, o si lo hay, pero se encuentra en un entorno limitado de seguridad al que no tiene acceso. Utilice la propiedad isRelatedObjectInaccessible() para determinar cuál de estas razones es la pertinente.

Elementos de API relacionados

Indica si se activa el modificador de la tecla Mayús, en cuyo caso el valor es true. De lo contrario, el valor es false. Esta propiedad sólo se utiliza si el evento FocusEvent es de tipo keyFocusChange.

Crea un objeto de evento con información específica relacionada con los eventos Focus. Los objetos de evento se transfieren como parámetros a los detectores de eventos.

Elementos de API relacionados

Crea una copia del objeto FocusEvent y define el valor de cada propiedad para que coincida con el del objeto original.

Devuelve una cadena con todas las propiedades del objeto FocusEvent. La cadena tiene el siguiente formato:

[FocusEvent type=value bubbles=value cancelable=value relatedObject=value shiftKey=value] keyCode=value]

Define el valor de la propiedad type de un objeto de evento focusIn.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento focusOut.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento keyFocusChange.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

Define el valor de la propiedad type de un objeto de evento mouseFocusChange.

Este evento tiene las propiedades siguientes:

Elementos de API relacionados

1. Declara las propiedades child (de tipo Sprite) y childCount (de tipo uint).
2. Un bucle for crea cinco cuadrados de color azul claro en (0,0). Comienza asignando child a una nueva instancia de CustomSprite. Cada vez que se crea un objeto CustomSprite, ocurre lo siguiente:
   • La propiedad size de tipo uint se define en 50 píxeles y bgColor se establece en color azul claro.
   • Las propiedades buttonMode y useHandCursor de la clase Sprite se definen como true en el constructor.
   • Se crea una instancia de un detector de eventos de tipo click, junto con el suscriptor asociado clickHandler(). El método suscriptor crea una variable local target de tipo Sprite y le asigna cualquiera de los cuadros en los que se haya hecho clic. La selección del escenario se asigna a target.
   • Se llama al método draw(), que crea un cuadrado de 50 x 50 píxeles llamando a los métodos beginFill(), drawRect() y endFill() de la clase Graphics y a las propiedades de la instancia.
3. En el bucle for, se llama al método configureListeners(), que crea instancias de tres detectores/suscriptores de eventos:
   • focusIn/focusInHandler() se distribuye después del evento click para cualquier objeto de lista (cuadro) en el que se haga clic.
   • focusOut/focusOutHandler() se distribuye cuando se hace clic en otro cuadro o si la selección deja de estar en el escenario (por ejemplo, haciendo clic fuera de Flash Player).
   • keyFocusChange/keyFocusChangeHandler() se distribuye si se utiliza el tabulador o las teclas de flecha izquierda y derecha para seleccionar un objeto de la lista de visualización. Sin embargo, el método keyFocusChangeHandler() atrapa las teclas de flecha izquierda y flecha derecha y llama al método preventDefault() para desactivarlas.
4. En el bucle for, cada cuadrado se añade a la lista de visualización y se muestra (en la misma área) por medio de addChild().
5. El constructor llama a refreshLayout(), que distribuye los cuadrados naranjas en la parte superior (y = 0) de la pantalla con 5 píxeles de separación entre cada cuadrado.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}