| Paquete | fl.data |
| Clase | public class DataProvider |
| Herencia | DataProvider  EventDispatcher Object |
| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Un proveedor de datos es una colección lineal de elementos que sirve como origen de datos como, por ejemplo, un conjunto. Cada elemento de un proveedor de datos es un objeto u objeto XML que contiene uno o varios campos de datos. Puede acceder a los elementos que contiene un proveedor de datos a través del índice, usando el método DataProvider.getItemAt().
Propiedades públicas
Ocultar propiedades públicas heredadas
Mostrar propiedades públicas heredadas| Propiedad | Definido por | ||
|---|---|---|---|
 | constructor : Object
Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada. | Object | |
| length : uint [solo lectura]
Número de elementos contenidos en el proveedor de datos. | DataProvider | ||
Métodos públicos
| Método | Definido por | ||
|---|---|---|---|
DataProvider(value:Object = null)
Crea un nuevo objeto DataProvider utilizando una lista, una instancia XML o un conjunto de objetos de datos como origen de datos. | DataProvider | ||
| addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
Registra un objeto de detector de eventos con un objeto EventDispatcher, de modo que el detector reciba la notificación de un evento. | EventDispatcher | |
Añade un elemento al final del proveedor de datos. | DataProvider | ||
Añade un nuevo elemento al proveedor de datos en el índice especificado. | DataProvider | ||
Añade varios elementos al final de DataProvider y distribuye un evento DataChangeType.ADD. | DataProvider | ||
Añade varios elementos al proveedor de datos en el índice especificado y distribuye un evento DataChangeType.ADD. | DataProvider | ||
Crea una copia del objeto DataProvider actual. | DataProvider | ||
Concatena los elementos especificados al final del proveedor de datos actual. | DataProvider | ||
|
Distribuye un evento en el flujo del evento. | EventDispatcher | |
Devuelve el elemento del índice especificado. | DataProvider | ||
Devuelve el índice del elemento especificado. | DataProvider | ||
|
Comprueba si el objeto EventDispatcher tiene detectores registrados para un tipo concreto de evento. | EventDispatcher | |
|
Indica si un objeto tiene definida una propiedad especificada. | Object | |
Invalida todos los elementos de datos que el objeto DataProvider contiene y distribuye un evento DataChangeEvent.INVALIDATE_ALL. | DataProvider | ||
Invalida el elemento especificado. | DataProvider | ||
Invalida el elemento del índice especificado. | DataProvider | ||
|
Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro. | Object | |
Añade los datos especificados que contiene el proveedor de datos y quita los elementos duplicados. | DataProvider | ||
|
Indica si existe la propiedad especificada y si es enumerable. | Object | |
Elimina todos los elementos del proveedor de datos y distribuye un evento DataChangeType.REMOVE_ALL. | DataProvider | ||
|
Elimina un detector del objeto EventDispatcher. | EventDispatcher | |
Quita el elemento especificado del proveedor de datos y distribuye un evento DataChangeType.REMOVE. | DataProvider | ||
Elimina el elemento en el índice especificado y distribuye un evento DataChangeType.REMOVE. | DataProvider | ||
Sustituye un elemento existente por un elemento nuevo y distribuye un evento DataChangeType.REPLACE. | DataProvider | ||
Sustituye el elemento en el índice especificado y distribuye un evento DataChangeType.REPLACE. | DataProvider | ||
|
Establece la disponibilidad de una propiedad dinámica para operaciones de bucle. | Object | |
Ordena los elementos contenidos en el proveedor de datos y distribuye un evento DataChangeType.SORT. | DataProvider | ||
Ordena los elementos contenidos en el proveedor de datos según el campo especificado y distribuye un evento DataChangeType.SORT. | DataProvider | ||
Crea una representación de objetos Array de los datos contenidos en el proveedor de datos. | DataProvider | ||
|
Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional. | Object | |
[override]
Crea una representación de cadena de los datos contenidos en el proveedor de datos. | DataProvider | ||
|
Devuelve el valor simple del objeto especificado. | Object | |
|
Comprueba si hay registrado un detector de eventos con este objeto EventDispatcher o con cualquiera de sus ascendientes para el tipo de evento concreto. | EventDispatcher | |
Eventos
| Evento | Resumen | Definido por | ||
|---|---|---|---|---|
| [evento broadcast] Se distribuye cuando Flash Player o AIR pasan a estar activos. | EventDispatcher | ||
| Se distribuye después de que cambien los datos. | DataProvider | |||
| [evento broadcast] Se distribuye cuando Flash Player o de AIR pasan a estar inactivos. | EventDispatcher | ||
| Se distribuye antes de que cambien los datos. | DataProvider | |||
Información sobre propiedades
length | propiedad |
length:uint [solo lectura] | Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Número de elementos contenidos en el proveedor de datos.
Implementación
public function get length():uintEjemplo ( Cómo utilizar este ejemplo )
En el ejemplo siguiente, se crea una instancia del componente List y se cambia el tamaño de la lista para que coincida con el número de elementos de su proveedor de datos:
import fl.controls.List;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({label:"Item 1"});
dp.addItem({label:"Item 2"});
dp.addItem({label:"Item 3"});
dp.addItem({label:"Item 4"});
var myList:List = new List();
myList.dataProvider = dp;
myList.rowHeight = 35;
myList.rowCount = dp.length;
myList.move(10, 10);
addChild(myList);
Información sobre constructores
DataProvider | () | Información sobre |
public function DataProvider(value:Object = null)| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Crea un nuevo objeto DataProvider utilizando una lista, una instancia XML o un conjunto de objetos de datos como origen de datos.
Parámetrosvalue:Object (default = null) |
Ejemplo ( Cómo utilizar este ejemplo )
En el ejemplo siguiente, se crea un nuevo proveedor de datos con el método
addItem():
import fl.controls.ComboBox;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({label:"item 1a"});
dp.addItem({label:"item 2a"});
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
En el ejemplo siguiente, se llena un proveedor de datos con un objeto Array:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var arr:Array = new Array();
arr.push({label:"item 1b"});
arr.push({label:"item 2b"});
var dp:DataProvider = new DataProvider(arr);
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
En el ejemplo siguiente, se llena un proveedor de datos con un objeto XML con atributos:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var xml:XML = <items>
<item label="item 1c" />
<item label="item 2c" />
</items>;
var dp:DataProvider = new DataProvider(xml);
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
En el ejemplo siguiente, se llena un proveedor de datos con un objeto XML con nodos secundarios:
import fl.controls.ComboBox;
import fl.data.DataProvider;
var xml:XML = <items>
<item>
<label>item 1d</label>
</item>
<item>
<label>item 2d</label>
</item>
</items>;
var dp:DataProvider = new DataProvider(xml);
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
Información sobre métodos
addItem | () | método |
public function addItem(item:Object):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Añade un elemento al final del proveedor de datos.
Parámetros
item:Object — Elemento que se añadirá al final del proveedor de datos actual.
|
Elementos de API relacionados
Ejemplo ( Cómo utilizar este ejemplo )
En el ejemplo siguiente, se crea un nuevo proveedor de datos con el método
addItem():
import fl.controls.ComboBox;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({label:"item 1a"});
dp.addItem({label:"item 2a"});
var myComboBox:ComboBox = new ComboBox()
myComboBox.dataProvider = dp;
myComboBox.move(10, 10);
addChild(myComboBox);
addItemAt | () | método |
public function addItemAt(item:Object, index:uint):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Añade un nuevo elemento al proveedor de datos en el índice especificado. El índice que se ha especificado se omitirá si supera la longitud del proveedor de datos.
Parámetros
item:Object — Objeto que contiene los datos para el elemento que se va a añadir.
| |
index:uint — Índice en el que se va a añadir el elemento.
|
Emite
RangeError — El índice especificado es inferior a 0 o mayor o igual que la longitud del proveedor de datos.
|
Elementos de API relacionados
addItems | () | método |
public function addItems(items:Object):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Añade varios elementos al final de DataProvider y distribuye un evento DataChangeType.ADD. Los elementos se añaden en el orden en que se especifican.
Parámetros
items:Object — Elementos que se van a añadir al proveedor de datos.
|
Elementos de API relacionados
Ejemplo ( Cómo utilizar este ejemplo )
En el ejemplo siguiente, se utiliza el método
addItems() para añadir varios elementos al proveedor de datos:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var arr:Array = [{col1:"1.A", col2:"1.B"}, {col1:"2.A", col2:"2.B"}]
var dp:DataProvider = new DataProvider();
dp.addItems(arr);
trace(dp.length); // 2
var c1:DataGridColumn = new DataGridColumn("col1");
var c2:DataGridColumn = new DataGridColumn("col2");
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.dataProvider = dp;
myDataGrid.setSize(200, 160);
myDataGrid.move(10, 10);
addChild(myDataGrid);
addItemsAt | () | método |
public function addItemsAt(items:Object, index:uint):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Añade varios elementos al proveedor de datos en el índice especificado y distribuye un evento DataChangeType.ADD.
Parámetros
items:Object — Elementos que se van a añadir al proveedor de datos.
| |
index:uint — Índice en el que se van a insertar los elementos.
|
Emite
RangeError — El índice especificado es inferior a 0 o mayor o igual que la longitud del proveedor de datos.
|
Elementos de API relacionados
clone | () | método |
public function clone():DataProvider| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Crea una copia del objeto DataProvider actual.
Valor devueltoDataProvider — Nueva instancia de este objeto DataProvider.
|
concat | () | método |
public function concat(items:Object):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Concatena los elementos especificados al final del proveedor de datos actual. Este método distribuye un evento DataChangeType.ADD.
Parámetros
items:Object — Elementos que se van a añadir al proveedor de datos.
|
Elementos de API relacionados
getItemAt | () | método |
public function getItemAt(index:uint):Object| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Devuelve el elemento del índice especificado.
Parámetros
index:uint — Ubicación del elemento que se va a devolver.
|
Object — Elemento en el índice especificado.
|
Emite
RangeError — El índice especificado es inferior a 0 o mayor o igual que la longitud del proveedor de datos.
|
Elementos de API relacionados
getItemIndex | () | método |
public function getItemIndex(item:Object):int| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Devuelve el índice del elemento especificado.
Parámetros
item:Object — Elemento que se va a ubicar.
|
int — Índice del elemento especificado o -1 si no se encuentra el elemento.
|
Elementos de API relacionados
invalidate | () | método |
public function invalidate():void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Invalida todos los elementos de datos que el objeto DataProvider contiene y distribuye un evento DataChangeEvent.INVALIDATE_ALL. Los elementos se invalidan después de que se cambien; DataProvider vuelve a dibujar los elementos invalidados automáticamente.
Elementos de API relacionados
invalidateItem | () | método |
public function invalidateItem(item:Object):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Invalida el elemento especificado. Un elemento se invalida después de que se cambie; DataProvider vuelve a dibujar el elemento invalidado automáticamente.
Parámetros
item:Object — Elemento que se va a invalidar.
|
Elementos de API relacionados
invalidateItemAt | () | método |
public function invalidateItemAt(index:int):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Invalida el elemento del índice especificado. Un elemento se invalida después de que se cambie; DataProvider vuelve a dibujar el elemento invalidado automáticamente.
Parámetros
index:int — Índice del elemento que se va a invalidar.
|
Emite
RangeError — El índice especificado es inferior a 0 o mayor o igual que la longitud del proveedor de datos.
|
Elementos de API relacionados
merge | () | método |
public function merge(newData:Object):void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Añade los datos especificados que contiene el proveedor de datos y quita los elementos duplicados. Este método distribuye un evento DataChangeType.ADD.
Parámetros
newData:Object — Datos que se van a combinar con el proveedor de datos.
|
Elementos de API relacionados
removeAll | () | método |
public function removeAll():void| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Elimina todos los elementos del proveedor de datos y distribuye un evento DataChangeType.REMOVE_ALL.
Elementos de API relacionados
removeItem | () | método |
public function removeItem(item:Object):Object| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Quita el elemento especificado del proveedor de datos y distribuye un evento DataChangeType.REMOVE.
Parámetros
item:Object — Elemento que se va a quitar.
|
Object — Elemento que se ha eliminado.
|
Elementos de API relacionados
removeItemAt | () | método |
public function removeItemAt(index:uint):Object| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Elimina el elemento en el índice especificado y distribuye un evento DataChangeType.REMOVE.
Parámetros
index:uint — Índice del elemento que se va a eliminar.
|
Object — Elemento que se ha eliminado.
|
Emite
RangeError — El índice especificado es inferior a 0 o mayor o igual que la longitud del proveedor de datos.
|
Elementos de API relacionados
replaceItem | () | método |
public function replaceItem(newItem:Object, oldItem:Object):Object| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Sustituye un elemento existente por un elemento nuevo y distribuye un evento DataChangeType.REPLACE.
Parámetros
newItem:Object — Elemento que se va a sustituir.
| |
oldItem:Object — Elemento de sustitución.
|
Object — Elemento que se ha sustituido.
|
Emite
RangeError — El elemento no se ha podido encontrar en el proveedor de datos.
|
Elementos de API relacionados
replaceItemAt | () | método |
public function replaceItemAt(newItem:Object, index:uint):Object| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Sustituye el elemento en el índice especificado y distribuye un evento DataChangeType.REPLACE.
Parámetros
newItem:Object — Elemento de sustitución.
| |
index:uint — Índice del elemento que se va a sustituir.
|
Object — Elemento que se ha sustituido.
|
Emite
RangeError — El índice especificado es inferior a 0 o mayor o igual que la longitud del proveedor de datos.
|
Elementos de API relacionados
sort | () | método |
public function sort(... sortArgs):*| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Ordena los elementos contenidos en el proveedor de datos y distribuye un evento DataChangeType.SORT.
Parámetros
... sortArgs — Argumentos que se utilizan para la ordenación.
|
* — El valor de devolución depende de si el método recibe algún argumento. Para más información, consulte el método Array.sort(). Este método devuelve 0 cuando la propiedad sortOption se ha definido en Array.UNIQUESORT.
|
Elementos de API relacionados
sortOn | () | método |
public function sortOn(fieldName:Object, options:Object = null):*| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Ordena los elementos contenidos en el proveedor de datos según el campo especificado y distribuye un evento DataChangeType.SORT. El campo especificado puede ser una cadena o un conjunto de valores de cadena que designan varios campos para ordenar en orden de precedencia.
Parámetros
fieldName:Object — Campo de elemento por el que se va a ordenar. Este valor puede ser una cadena o un conjunto de valores de cadena.
| |
options:Object (default = null) |
* — El valor de devolución depende de si el método recibe algún argumento. Para obtener más información, consulte el método Array.sortOn(). Si la propiedad sortOption se ha definido en Array.UNIQUESORT, este método devuelve 0.
|
Elementos de API relacionados
toArray | () | método |
public function toArray():Array| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Crea una representación de objetos Array de los datos contenidos en el proveedor de datos.
Valor devueltoArray — Representación de objetos Array de los datos contenidos en el proveedor de datos.
|
toString | () | método |
override public function toString():String| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Crea una representación de cadena de los datos contenidos en el proveedor de datos.
Valor devueltoString — Representación de cadena de los datos contenidos en el proveedor de datos.
|
Información sobre eventos
dataChange | Evento |
Tipo de objeto de evento:
propiedad DataChangeEvent.type =
fl.events.DataChangeEventpropiedad DataChangeEvent.type =
fl.events.DataChangeEvent.DATA_CHANGE| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Se distribuye después de que cambien los datos.
Define el valor de la propiedadtype para un objeto de evento dataChange.
Este evento tiene las propiedades siguientes:
| Propiedad | Valor |
|---|---|
bubbles | false |
cancelable | false; no hay ningún comportamiento predeterminado que cancelar. |
changeType | Identifica el tipo de cambio realizado. |
currentTarget | Objeto que procesa de forma activa el objeto de evento con un detector de eventos. |
endIndex | Identifica el índice del último elemento cambiado. |
items | Conjunto que enumera los elementos que se han cambiado. |
startIndex | Identifica el índice del primer elemento cambiado. |
target | Error que distribuyó el evento. El destino no es siempre el objeto que detecta el evento. Utilice la propiedad currentTarget para acceder al objeto que detecta el evento. |
Elementos de API relacionados
preDataChange | Evento |
Tipo de objeto de evento:
propiedad DataChangeEvent.type =
fl.events.DataChangeEventpropiedad DataChangeEvent.type =
fl.events.DataChangeEvent.PRE_DATA_CHANGE| Versión del lenguaje: | ActionScript 3.0 |
| Versión de producto: | Flash CS3 |
| Versiones de motor de ejecución: | Flash Player 9.0.28.0, AIR 1.0 |
Se distribuye antes de que cambien los datos.
Define el valor de la propiedadtype para un objeto de evento preDataChange. Este objeto de evento se distribuye antes de que se realicen cambios a los datos del componente.
Este evento tiene las propiedades siguientes:
| Propiedad | Valor |
|---|---|
bubbles | false |
cancelable | false; no hay ningún comportamiento predeterminado que cancelar. |
changeType | Identifica el tipo de cambio que se va a realizar. |
currentTarget | Objeto que procesa de forma activa el objeto de evento con un detector de eventos. |
endIndex | Identifica el índice del último elemento que se va a cambiar. |
items | Conjunto que enumera los elementos que se van a cambiar. |
startIndex | Identifica el índice del primer elemento que se va a cambiar. |
target | Error que distribuyó el evento. El destino no es siempre el objeto que detecta el evento. Utilice la propiedad currentTarget para acceder al objeto que detecta el evento. |
Elementos de API relacionados
Ejemplos Cómo utilizar este ejemplo
DataProviderExample.as
En este ejemplo, se muestra cómo se pueden utilizar los proveedores de datos para mostrar el contenido de varias cuadrículas de datos.
Para realizar el ejemplo, siga estos pasos:
- Añada los componentes Label, Button, ComboBox, TextInput y DataGrid a la biblioteca.
- Guarde este código como DataProviderExample.as en el mismo directorio que el archivo FLA.
- Defina la clase Document como DataProviderExample en el archivo FLA.
package
{
import fl.controls.Button;
import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.Label;
import fl.controls.TextInput;
import fl.data.DataProvider;
import flash.display.Sprite;
import flash.events.*;
import flash.text.TextFieldAutoSize;
public class DataProviderExample extends Sprite
{
private var southern:DataGrid;
private var northern:DataGrid;
private var world:DataGrid;
private var southernRoster:DataProvider;
private var northernRoster:DataProvider;
private var leagueCB:ComboBox;
private var nameTI:TextInput;
private var goalsTI:TextInput;
private var submitBtn:Button;
public function DataProviderExample() {
southernRoster = new DataProvider();
northernRoster = new DataProvider();
createDataGrids();
createUI();
}
private function createUI():void {
var description:Label = new Label();
description.text = "Enter player's name, goals scored, and hemisphere of origin:";
description.autoSize = TextFieldAutoSize.LEFT;
nameTI = new TextInput();
goalsTI = new TextInput();
var submitBtn:Button = new Button();
submitBtn.label = "Submit Player";
submitBtn.addEventListener(MouseEvent.CLICK, submitPlayer);
leagueCB = new ComboBox();
leagueCB.addItem( { label:"Northern", data: 0 } );
leagueCB.addItem( { label:"Southern", data: 1 } );
description.move(10,10);
nameTI.move(10,40);
nameTI.setSize(150,24);
goalsTI.move(170,40);
goalsTI.setSize(40,24);
leagueCB.move(220,40);
leagueCB.setSize(120,24);
submitBtn.move(350,40);
goalsTI.restrict = "0123456789";
addChild(description);
addChild(leagueCB);
addChild(submitBtn);
addChild(nameTI);
addChild(goalsTI);
}
private function submitPlayer(e:MouseEvent):void {
if(nameTI.text != "" && goalsTI.text != "") {
var targetRoster:DataProvider;
if(leagueCB.selectedItem.label == "Southern") {
targetRoster = southernRoster;
}
else {
targetRoster = northernRoster;
}
targetRoster.addItem( { Name: nameTI.text, Goals: goalsTI.text } );
var worldRoster:DataProvider = southernRoster.clone();
worldRoster.merge(northernRoster);
worldRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
southernRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
northernRoster.sortOn("Goals", Array.NUMERIC | Array.DESCENDING);
world.dataProvider = worldRoster;
nameTI.text = "";
goalsTI.text = "";
}
}
private function createDataGrids():void {
southern = new DataGrid();
northern = new DataGrid();
world = new DataGrid();
southern.move(10,100);
northern.move(180,100);
world.move(350,100);
southern.setSize(170, 250);
northern.setSize(170, 250);
world.setSize(170, 250);
southern.columns =
northern.columns =
world.columns = [ "Name", "Goals" ];
southern.dataProvider = southernRoster;
northern.dataProvider = northernRoster;
addChild(southern);
addChild(northern);
addChild(world);
var northernLabel:Label = new Label();
northernLabel.autoSize = TextFieldAutoSize.LEFT;
northernLabel.text = "Southern Hemisphere";
northernLabel.move(10,75);
addChild(northernLabel);
var southernLabel:Label = new Label();
southernLabel.autoSize = TextFieldAutoSize.LEFT;
southernLabel.text = "Northern Hemisphere";
southernLabel.move(180,75);
addChild(southernLabel);
var majorLabel:Label = new Label();
majorLabel.autoSize = TextFieldAutoSize.LEFT;
majorLabel.text = "World";
majorLabel.move(350,75);
addChild(majorLabel);
}
}
}
Tue Jun 12 2018, 02:12 PM Z