RadioButtonGroup

Paquete	fl.controls
Clase	public class RadioButtonGroup
Herencia	RadioButtonGroup EventDispatcher Object

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

La clase RadioButtonGroup define un grupo de componentes RadioButton para que actúen como un solo componente. Si se selecciona un botón de opción, ya no se pueden seleccionar más botones de opción del mismo grupo.

Ver los ejemplos

Elementos de API relacionados

RadioButton
RadioButton.group

Propiedades públicas

Ocultar propiedades públicas heredadas

Mostrar propiedades públicas heredadas

	Propiedad		Definido por
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		name : String [solo lectura] Obtiene el nombre de la instancia del botón de opción.	RadioButtonGroup
		numRadioButtons : int [solo lectura] Obtiene el número de botones de opción de este grupo de botones de opción.	RadioButtonGroup
		selectedData : Object Obtiene o define la propiedad value del botón de opción seleccionado.	RadioButtonGroup
		selection : RadioButton Obtiene o define una referencia al botón de opción seleccionado en el grupo de botones de opción.	RadioButtonGroup

Métodos públicos

Ocultar métodos públicos heredados

Mostrar métodos públicos heredados

	Método		Definido por
		RadioButtonGroup(name:String) Crea una nueva instancia de RadioButtonGroup.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registra un objeto de detector de eventos con un objeto EventDispatcher, de modo que el detector reciba la notificación de un evento.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Añade un botón de opción al conjunto interno de botones de opción para la indización del grupo de botones de opción, que permite seleccionar un único botón de opción en un grupo de botones de este tipo.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Distribuye un evento en el flujo del evento.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [estática] Recupera una referencia al grupo de botones de opción especificado.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Recupera el componente RadioButton en la ubicación de índice especificada.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Devuelve el índice de la instancia de RadioButton especificada.	RadioButtonGroup
		hasEventListener(type:String):Boolean Comprueba si el objeto EventDispatcher tiene detectores registrados para un tipo concreto de evento.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Elimina un detector del objeto EventDispatcher.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Borra la instancia RadioButton de la lista interna de botones de opción.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		toLocaleString():String Devuelve la representación de cadena de este objeto, con formato según las convenciones específicas de configuración regional.	Object
		toString():String Devuelve la representación de cadena del objeto especificado.	Object
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object
		willTrigger(type:String):Boolean Comprueba si hay registrado un detector de eventos con este objeto EventDispatcher o con cualquiera de sus ascendientes para el tipo de evento concreto.	EventDispatcher

Eventos

Haga clic para obtener más información sobre los eventos

Ocultar eventos heredados

Mostrar eventos heredados

	Resumen	Definido por
activate	[evento broadcast] Se distribuye cuando Flash Player o AIR pasan a estar activos.	EventDispatcher
change	Se distribuye si cambia la instancia de RadioButton seleccionada en un grupo.	RadioButtonGroup
click	Se distribuye al hacer clic en una instancia de RadioButton.	RadioButtonGroup
deactivate	[evento broadcast] Se distribuye cuando Flash Player o de AIR pasan a estar inactivos.	EventDispatcher

Información sobre propiedades

name

propiedad

name:String [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Obtiene el nombre de la instancia del botón de opción.

El valor predeterminado es "RadioButtonGroup".

Implementación
public function get name():String

numRadioButtons

propiedad

numRadioButtons:int [solo lectura]

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Obtiene el número de botones de opción de este grupo de botones de opción.

El valor predeterminado es 0.

Implementación
public function get numRadioButtons():int

selectedData

propiedad

selectedData:Object

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Obtiene o define la propiedad value del botón de opción seleccionado. Si no hay seleccionado ningún botón de opción, esta propiedad será null.

Implementación
public function get selectedData():Object
public function set selectedData(value:Object):void

Ejemplo ( Cómo utilizar este ejemplo )

En el ejemplo siguiente, se crea un componente RadioButtonGroup nuevo y se detecta el evento change:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

propiedad

selection:RadioButton

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Obtiene o define una referencia al botón de opción seleccionado en el grupo de botones de opción.

Implementación
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Ejemplo ( Cómo utilizar este ejemplo )

En el ejemplo siguiente, se crea un grupo de botones de opción nuevo con dos botones de opción. Si cambia el botón de opción seleccionado, se realiza el seguimiento de su etiqueta y valor:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Información sobre constructores

()

Información sobre

public function RadioButtonGroup(name:String)

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Crea una nueva instancia de RadioButtonGroup. Esta acción se suele realizar automáticamente al crear una instancia de un botón de opción.

Parámetros

name:String — Nombre del grupo de botones de opción.

Información sobre métodos

addRadioButton

()

método

public function addRadioButton(radioButton:RadioButton):void

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Añade un botón de opción al conjunto interno de botones de opción para la indización del grupo de botones de opción, que permite seleccionar un único botón de opción en un grupo de botones de este tipo. Este método se utiliza automáticamente mediante los botones de opción, pero también se puede usar de forma manual para añadir explícitamente un botón de opción a un grupo.

Parámetros

radioButton:RadioButton — Instancia RadioButton que se añade al grupo de botones de opción actual.

getGroup

()

método

public static function getGroup(name:String):RadioButtonGroup

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Recupera una referencia al grupo de botones de opción especificado.

Parámetros

name:String — Nombre del grupo para el que se recupera una referencia.

Valor devuelto

RadioButtonGroup — Referencia al componente RadioButtonGroup especificado.

Ejemplo ( Cómo utilizar este ejemplo )

En el ejemplo siguiente, se muestra cómo determinar el botón de opción seleccionado en un grupo:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

método

public function getRadioButtonAt(index:int):RadioButton

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Recupera el componente RadioButton en la ubicación de índice especificada.

Parámetros

index:int — Índice del componente RadioButton en el componente RadioButtonGroup, donde el índice del primer componente es 0.

Valor devuelto

RadioButton — Componente RadioButton especificado.

Emite

RangeError — El índice especificado es inferior a 0 o mayor o igual que la longitud del proveedor de datos.

getRadioButtonIndex

()

método

public function getRadioButtonIndex(radioButton:RadioButton):int

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Devuelve el índice de la instancia de RadioButton especificada.

Parámetros

radioButton:RadioButton — Instancia de RadioButton que se va a localizar en el grupo actual de botones de opción.

Valor devuelto

int — Índice del componente RadioButton especificado, o -1 si no se encuentra dicho componente.

removeRadioButton

()

método

public function removeRadioButton(radioButton:RadioButton):void

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Borra la instancia RadioButton de la lista interna de botones de opción.

Parámetros

radioButton:RadioButton — Instancia de RadioButton que se va a quitar.

Información sobre eventos

change

Evento

Tipo de objeto de evento: flash.events.Event
propiedad Event.type = flash.events.Event.CHANGE

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Se distribuye si cambia la instancia de RadioButton seleccionada en un grupo.

La constante Event.CHANGE define el valor de la propiedad type de un objeto de evento change.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`true`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	Objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto al que se ha modificado su valor. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Ejemplo ( Cómo utilizar este ejemplo )

En el ejemplo siguiente, se crean tres botones de opción y se añade un detector de eventos para el evento change de un grupo de botones de opción:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Evento

Tipo de objeto de evento: flash.events.MouseEvent
propiedad MouseEvent.type = flash.events.MouseEvent.CLICK

Versión del lenguaje:

ActionScript 3.0

Versión de producto:

Flash CS3

Versiones de motor de ejecución:

Flash Player 9.0.28.0, AIR 1.0

Se distribuye al hacer clic en una instancia de RadioButton.

Define el valor de la propiedad type de un objeto de evento click.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`altKey`	`true` si la tecla Alt está activa (Windows).
`bubbles`	`true`
`buttonDown`	Para eventos de clic, este valor es siempre `false`.
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`commandKey`	`true` en Mac, si la tecla Comando está activa; `false` si está inactiva. Siempre es `false` en Windows.
`controlKey`	`true` si la tecla Control o Ctrl está activa; `false` si está inactiva.
`ctrlKey`	`true` en Windows o Linux, si la tecla Ctrl está activa. `true` en Mac, si la tecla Ctrl o Comando está activa. En caso contrario, `false`.
`currentTarget`	Objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`localX`	La coordenada horizontal en la que se produce el evento relacionado con la clase Sprite contenida, si el bloqueo del ratón está desactivado.
`localY`	La coordenada vertical en la que se produce el evento relacionado con la clase Sprite contenida, si el bloqueo del ratón está desactivado.
`movementX`	El cambio en las coordenadas horizontales de la posición del ratón desde el último evento de ratón, si el bloqueo del ratón está activado.
`movementY`	El cambio en las coordenadas verticales de la posición del ratón desde el último evento de ratón, si el bloqueo del ratón está activado.
`shiftKey`	`true` si la tecla Mayús está activa; `false` si está inactiva.
`stageX`	La coordenada horizontal en la que se produce el evento en las coordenadas globales del escenario.
`stageY`	La coordenada vertical en la que se produce el evento en las coordenadas globales del escenario.
`target`	La instancia InteractiveObject en el dispositivo de señalización. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Ejemplos Cómo utilizar este ejemplo

RadioButtonGroupExample.as

En este ejemplo, se muestra cómo administrar numerosos objetos RadioButton en varios grupos

Añada los componentes RadioButton y Label a la biblioteca.
Guarde este código como RadioButtonGroupExample.as en el mismo directorio que el archivo FLA.
Establece la clase DocumentClass del archivo FLA como RadioButtonGroupExample.

package
{
    import flash.text.TextFieldAutoSize;
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import fl.controls.Label;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Avisos legales | Política de privacidad en línea

RadioButtonGroup - AS3 Flash

Clases x

name

numRadioButtons

selectedData

selection