QName  - AS3

El nombre local del objeto QName.

Identificador uniforme de recurso (URI) del objeto QName.

Crea un objeto QName que es una copia de otro objeto QName. Si el parámetro que se pasa al constructor es un objeto QName, se creará una copia del objeto QName. Si el parámetro no es un objeto QName, el parámetro se convertirá en una cadena y se asignará a la propiedad localName de la nueva instancia QName. Si el parámetro es undefined no se ha especificado, se creará un nuevo objeto QName con la propiedad localName definida como una cadena vacía.

Nota: esta clase muestra dos entradas de constructor porque cada forma acepta parámetros diferentes. El constructor se comporta de forma diferente dependiendo del tipo y el número de parámetros pasados, como se detalla en cada entrada. ActionScript 3.0 no admite la sobrecarga de métodos o constructores.

Crea un objeto QName con un URI de un objeto Namespace y un localName de un objeto QName. Si el parámetro no tiene el tipo de datos esperado, el parámetro se convertirá en una cadena y se asignará a la propiedad correspondiente del nuevo objeto QName. Por ejemplo, si ambos parámetros son cadenas, se devolverá un nuevo objeto QName con una propiedad uri definida con el primer parámetro y una propiedad localName definida con el segundo parámetro. Dicho de otro modo, las siguientes variantes de orden, entre otras muchas, son formas válidas del constructor:

QName (uri:Namespace, localName:String);
QName (uri:String, localName: QName);
QName (uri:String, localName: String);

Si pasa null para el parámetro uri, la propiedad uri del nuevo objeto QName se define como null.

Nota: esta clase muestra dos entradas de constructor porque cada forma acepta parámetros diferentes. El constructor se comporta de forma diferente dependiendo del tipo y el número de parámetros pasados, como se detalla en cada entrada. ActionScript 3.0 no admite la sobrecarga de métodos o constructores.

Devuelve una cadena formada por el URI y el nombre local del objeto QName separados por "::".

El formato depende de la propiedad uri del objeto QName:

If uri == "" 
		toString returns localName
	else if uri == null
		toString returns *::localName 
	else
		toString returns uri::localName

Devuelve el objeto QName.

1. Crear una instancia de Namespace y, después, utilizarla como entrada para el constructor QName. Este método es el recomendado si se quiere utilizar la propiedad Namespace.prefix para otros fines más adelante.
2. Crear una instancia de QName con un valor de cadena simple para el parámetro uri en el constructor QName.

El código hace lo siguiente:

1. Define una variable XML llamada rssXML.
2. Crea un nuevo objeto Namespace con el prefijo dc.
3. Crea un nuevo objeto QName con el objeto Namespace y el nombre local creator.
4. Llama al método showDescendants(), que utiliza el método XML.descendants() para obtener una instancia de XMLList que contenga todos los elementos descendientes cuyo nombre completo coincida con la instancia de QName determinada.
5. Muestra el nombre completo y el valor de texto de cada elemento de la lista mediante un bucle for each.
6. Crea otro objeto QName utilizando un valor de cadena para el parámetro uri y el nombre local date.
7. Vuelve a llamar al método showDescendants() para mostrar el nombre y el valor de texto de los elementos descendientes.

package
{
    import flash.display.Sprite;
    
    public class QNameExample extends Sprite
    {
        public function QNameExample()
        {
            var rssXML:XML =  <rdf:RDF
              xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
              xmlns="http://purl.org/rss/1.0/"
              xmlns:dc="http://purl.org/dc/elements/1.1/">
              <channel rdf:about="http://www.xml.com/cs/xml/query/q/19">
                <title>Test RSS</title>
                <link>http://www.adobe.com/</link>
                <description>This is a test RSS document.</description>
                <language>en-us</language>
                <items>
                  <rdf:Seq>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flash/"/>
                <rdf:li rdf:resource="http://www.adobe.com/devnet/flex/"/>
                  </rdf:Seq>
                </items>
              </channel>
              <item rdf:about="http://www.adobe.com/devnet/flash/">
                <title>Flash Developer Center</title>
                <link>http://www.adobe.com/devnet/flash/</link>
                <description>Welcome to the Flash Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-08-08</dc:date>    
              </item>
              <item rdf:about="http://www.adobe.com/devnet/flex/">
                <title>Flex Developer Center</title>
                <link>http://www.adobe.com/devnet/flex/</link>
                <description>Welcome to the Flex Developer Center</description>
                <dc:creator>Adobe</dc:creator>
                <dc:date>2005-10-16</dc:date>    
              </item>
            </rdf:RDF>;
            
            var dcNamespace:Namespace = new Namespace("dc", "http://purl.org/dc/elements/1.1/");
            var creatorQName:QName = new QName(dcNamespace, "creator");
            trace(creatorQName.uri); // http://purl.org/dc/elements/1.1/
            trace(creatorQName.localName); // creator
            
            showDescendants(rssXML, creatorQName);
            
            var dateQName:QName = new QName("http://purl.org/dc/elements/1.1/", "date");
            trace(dateQName.uri); // http://purl.org/dc/elements/1.1/
            trace(dateQName.localName); // date
            
            showDescendants(rssXML, dateQName);
        }
        
        public function showDescendants(xmlData:XML, qualifiedName:QName):void
        {
            var decendantList:XMLList = xmlData.descendants(qualifiedName);
            
            for each (var element:XML in decendantList)
            {
                trace(element.name()); // the fully qualified name, 
                                       // like "http://purl.org/dc/elements/1.1/::creator"
                trace(element); // the simple text value of each element, like "Adobe"
            }                
        }
    }
}