| Paket | flash.ui |
| Klasse | public final class MouseCursorData |
| Vererbung | MouseCursorData  Object |
| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | Flash Player 10.2, AIR 2.6 |
Um den Mauszeiger anzuzeigen, verwenden Sie die Mouse.registerCursor()-Funktion. Um wieder dem Betriebssystem die Kontrolle über den Mauszeiger zu geben, rufen Sie Mouse.unregisterCursor() auf. Rufen Sie Mouse.supportsNativeCursor auf, um zu testen, welche nativen Mauszeiger auf dem aktuellen Computer unterstützt werden.
Die maximale Mauszeigergröße ist 32x32 Pixel. Transparenz wird bei den meisten Betriebssystemen nicht unterstützt.
Ein nativer Mauszeiger wird direkt über den Mauszeigermechanismus des Betriebssystems implementiert und ist eine effizientere Möglichkeit, ein benutzerdefiniertes Mauszeigerbild anzuzeigen als die Verwendung eines Anzeigeobjekts. Sie können den Mauszeiger animieren, indem Sie mehrere Bilder in der data-Eigenschaft angeben und die Bildrate festlegen.
Der Mauszeiger wird nur innerhalb der Bühnengrenzen angezeigt. Außerhalb der Bühne hat das Betriebssystem die Kontrolle über das Bild des Mauszeigers.
Weitere Informationen
Verwandte API-Elemente
Vererbte öffentliche Eigenschaften ausblenden
Vererbte öffentliche Eigenschaften anzeigen| Eigenschaft | Definiert von | ||
|---|---|---|---|
 | constructor : Object
Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz. | Object | |
| data : Vector.<BitmapData>
Ein Vektor von BitmapData-Objekten, der das Bild bzw. die Bilder für den Mauszeiger enthält. | MouseCursorData | ||
| frameRate : Number
Die Bildrate zum Animieren des Mauszeigers. | MouseCursorData | ||
| hotSpot : Point
Der Kollisionsbereich des Mauszeigers in Pixel. | MouseCursorData | ||
| Methode | Definiert von | ||
|---|---|---|---|
Erstellt ein MouseCursorData-Objekt. | MouseCursorData | ||
|
Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde. | Object | |
|
Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde. | Object | |
|
Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann. | Object | |
|
Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest. | Object | |
|
Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas. | Object | |
|
Gibt das angegebene Objekt als String zurück. | Object | |
|
Gibt den Grundwert des angegebenen Objekts zurück. | Object | |
data | Eigenschaft |
data:Vector.<BitmapData>| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | Flash Player 10.2, AIR 2.6 |
Ein Vektor von BitmapData-Objekten, der das Bild bzw. die Bilder für den Mauszeiger enthält.
Stellen Sie mehrere Bilder bereit und stellen Sie die framerate-Eigenschaft ein, um den Mauszeiger zu animieren.
Die maximale Größe für den Mauszeiger beträgt 32x32 Pixel.
Implementierung
public function get data():Vector.<BitmapData> public function set data(value:Vector.<BitmapData>):voidframeRate | Eigenschaft |
frameRate:Number| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | Flash Player 10.2, AIR 2.6 |
Die Bildrate zum Animieren des Mauszeigers.
Stellen Sie mehrere Bilder für die data-Eigenschaft bereit und legen Sie für die Bildrate einen Wert über 0 fest, um den Mauszeiger zu animieren. Die Mauszeigerbildrate kann sich von der aktuellen SWF-Bildrate unterscheiden.
Implementierung
public function get frameRate():Number public function set frameRate(value:Number):voidhotSpot | Eigenschaft |
hotSpot:Point| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | Flash Player 10.2, AIR 2.6 |
Der Kollisionsbereich des Mauszeigers in Pixel.
Der Kollisionsbereich ist der Punkt des Mauszeigers, unter dem Mausklicks registriert werden. Standardmäßig liegt der Kollisionsbereich in der oberen linken Ecke (0,0).
Implementierung
public function get hotSpot():Point public function set hotSpot(value:Point):voidMouseCursorData | () | Konstruktor |
public function MouseCursorData()| Sprachversion: | ActionScript 3.0 |
| Laufzeitversionen: | Flash Player 10.2, AIR 2.6 |
Erstellt ein MouseCursorData-Objekt.
Um den Mauszeiger anzuzeigen, rufen Sie die Mouse.registerCursor()-Funktion auf.
Verwandte API-Elemente
Das Beispiel verwendet die Zeichnungsbefehle, die durch die Graphics-Klasse verfügbar sin, um acht gedrehte Bilder eines Pfeils zu erstellen. Diese Bilder werden in einen Vektor gebracht und der data-Eigenschaft des MouseCursorData-Objekts zugewiesen. (Beachten Sie, dass Sie auch vorgerenderte Bitmapbilder für Ihre Mauszeiger verwenden können.)
package {
import flash.display.Sprite;
import flash.display.Shape;
import flash.display.BitmapData;
import flash.display.GraphicsPath;
import flash.ui.MouseCursorData;
import flash.ui.Mouse;
import flash.geom.Matrix;
public class MouseCursorDataExample extends Sprite {
//Graphics path data for an arrow
private var cursorPoints:Vector.<Number> = new <Number>[0,8, 16,8, 16,0, 24,12, 16,24, 16,16, 0,16, 0,8];
private var cursorDrawCommands:Vector.<int> = new <int>[1,2,2,2,2,2,2,2];
public function MouseCursorDataExample() {
var mouseCursorData:MouseCursorData = new MouseCursorData();
mouseCursorData.data = makeCursorImages();
mouseCursorData.frameRate = 1;
Mouse.registerCursor( "spinningArrow", mouseCursorData );
Mouse.cursor = "spinningArrow";
}
//Returns a Vector containing 8 cursor images
private function makeCursorImages():Vector.<BitmapData>
{
var cursorData:Vector.<BitmapData> = new Vector.<BitmapData>();
var cursorShape:Shape = new Shape();
cursorShape.graphics.beginFill( 0xff5555, .75 );
cursorShape.graphics.lineStyle( 1 );
cursorShape.graphics.drawPath( cursorDrawCommands, cursorPoints );
cursorShape.graphics.endFill();
var transformer:Matrix = new Matrix();
//Rotate and draw the arrow shape to a BitmapData object for each of 8 frames
for( var i:int = 0; i < 8; i++ )
{
var cursorFrame:BitmapData = new BitmapData( 32, 32, true, 0 );
cursorFrame.draw( cursorShape, transformer );
cursorData.push( cursorFrame );
transformer.translate(-15,-15);
transformer.rotate( 0.785398163 );
transformer.translate(15,15);
}
return cursorData;
}
}
}
Tue Jun 12 2018, 10:04 AM Z