Mouse  - AS3

Der Name des nativen Cursors.

Gibt an, ob der Computer oder das Gerät einen bleibenden Cursor anzeigt.

Die supportsCursor-Eigenschaft hat für die meisten Desktopcomputer den Wert true und für die meisten mobilen Geräte den Wert false.

Hinweis: Mausereignisse können abgesetzt werden, unabhängig davon, ob diese Eigenschaft den Wert true hat oder nicht. Je nach den physischen Merkmalen des Zeigegeräts verhalten sich Mausereignisse unter Umständen jedoch unterschiedlich.

Verwandte API-Elemente

import flash.events.*;
import flash.display.*;
import flash.ui.Mouse;
import flash.text.TextField;

var supportsCursorTxt:TextField = new TextField();
supportsCursorTxt.width = 200;
supportsCursorTxt.border = true;
addChild(supportsCursorTxt);

addEventListener (MouseEvent.CLICK, getScreenKeyboardType);

function getScreenKeyboardType(e:MouseEvent):void{
    supportsCursorTxt.text= "Supports Cursor is : " + String(flash.ui.Mouse.supportsCursor);

}

if(Mouse.supportsCursor) {
    //Game acts as before
} else {
    if(Capabilities.touchscreenType == TouchscreenType.STYLUS ){
        //The Game has to change so that the character is chasing the location of the stylus as 
        //it's dragged around. Some of the animations will have to change
    }else if(Capabilities.touchscreenType = TouchscreenType.FINGER){
        //Same as above, except that the hit-area is larger for a finger.
    }else{
        //There's no pointing device at all. The developer designs some sort of custom cursor to 
        //be controlled with key presses or similar input
    }
}

Gibt an, ob die aktuelle Konfiguration native Cursor unterstützt.

Blendet den Mauszeiger aus. In der Standardeinstellung ist der Mauszeiger sichtbar.

Hinweis: Sie brauchen Mouse.hide() nur einmal aufzurufen, unabhängig davon, wie oft zuvor Mouse.show() aufgerufen wurde.

Verwandte API-Elemente

Registriert einen nativen Mauszeiger unter dem angegebenen Namen mit den angegebenen Daten.

Parameter

Zeigt den Mauszeiger an. In der Standardeinstellung ist der Mauszeiger sichtbar.

Hinweis: Sie brauchen Mouse.show() nur einmal aufzurufen, unabhängig davon, wie oft zuvor Mouse.hide() aufgerufen wurde.

Verwandte API-Elemente

Hebt die Registrierung des nativen Cursors mit dem angegebenen Namen auf.

Parameter

1. Deklarieren Sie die folgenden Instanzeigenschaften: cursor des Typs „CustomCursor“, child des Typs „CustomButton“ und gutter des Typs „uint“.
2. Weisen Sie child einer neuen CustomButton-Instanz zu, setzen Sie deren x- und y-Koordinaten auf jeweils 10 Pixel, und fügen Sie die Instanz anschließend der Anzeigeliste hinzu. Die CustomButton-Klasse setzt die Eigenschaften downState, upState, overState und hitTestState in „SimpleButton“ außer Kraft. Durch jede dieser Eigenschaften wird ein ButtonDisplayState-Objekt instanziiert, das in Abhängigkeit vom Status der child-Instanz ein anderes Quadrat zeichnet.
3. Die child-Instanz wird anschließend verwendet, um einen MOUSE_OVER-Ereignis-Listener und eine mouseOverHandler()-Listener-Methode mit einem MOUSE_OUT-Ereignis-Listener und der verknüpften mouseOutHandler()-Methode hinzuzufügen.
4. Die Ereignis-Listener funktionieren wie folgt:
   • mouseOverHandler: Blendet den „normalen“ Mauszeiger aus und fügt einen MOUSE_MOVE-Listener hinzu, der die Mausbewegungen mit dem mouseMoveHandler() verarbeitet (Beschreibung siehe unten).
   • mouseOutHandler: Wenn die Maus den Bereich der benutzerdefinierten Schaltfläche verlässt, wird der „normale“ Mauszeiger eingeblendet, der MOUSE_MOVE-Ereignis-Listener wird entfernt, und die Sichtbarkeit des benutzerdefinierten Cursors wird auf false gesetzt.
   • mouseMoveHandler: Bewegt den benutzerdefinierten Cursor an die Stelle, an die der Mauszeiger bewegt wird, und setzt die Sichtbarkeit des benutzerdefinierten Cursors auf true.
5. Im MouseExample-Konstruktor wird die Cursor-Eigenschaft einem neuen CustomCursor-Objekt zugewiesen und anschließend mit addChild() der Anzeigeliste hinzugefügt. Mit der CustomCursor-wird eine kleines nahezu schwarzes Quadrat statt des „normalen“ Mauszeigers gezeichnet, wenn die Maus sich über child befindet.
6. Ein vierter Ereignis-Listener des Typs MOUSE_LEAVE wird mit der verknüpften mouseLeaveHandler()-Methode hinzugefügt. In dieser Methode (die aufgerufen wird, wenn die Maus die Bühne verlässt), wird dem mouseOutHandler() ein neues mouseMove-Listener-Objekt übergeben, das den Mauszeiger vollständig von der Bühne entfernt.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.ui.Mouse;
    import flash.events.*;

    public class MouseExample extends Sprite {
         private var cursor:CustomCursor;
         private var child:CustomButton;
         private var gutter:uint = 10;

        public function MouseExample() {
            child = new CustomButton();
            child.x = gutter;
            child.y = gutter;
            addChild(child);

            child.addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
            child.addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);

            cursor = new CustomCursor();
            addChild(cursor);

            stage.addEventListener(Event.MOUSE_LEAVE, mouseLeaveHandler);
        }

        private function mouseOverHandler(event:MouseEvent):void {
            trace("mouseOverHandler");
            Mouse.hide();
            child.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function mouseOutHandler(event:MouseEvent):void {
            trace("mouseOutHandler");
            Mouse.show();
            child.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            cursor.visible = false;
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            cursor.x = event.localX;
            cursor.y = event.localY;
            event.updateAfterEvent();
            cursor.visible = true;
        }

        private function mouseLeaveHandler(event:Event):void {
            trace("mouseLeaveHandler");
            mouseOutHandler(new MouseEvent(MouseEvent.MOUSE_MOVE));
        }
    }
}

import flash.display.Shape;
import flash.display.SimpleButton;
    
class CustomButton extends SimpleButton {
    var upColor:uint = 0xFFCC00;
    var overColor:uint = 0xCCFF00;
    var downColor:uint = 0x00CCFF;
    var size:uint = 80;
    
    public function CustomButton() {
        downState = new ButtonDisplayState(downColor, size+10);
        overState = new ButtonDisplayState(overColor, size);
        upState = new ButtonDisplayState(upColor, size);
        hitTestState = new ButtonDisplayState(upColor, size);
    }
}

class ButtonDisplayState extends Shape {
    var bgColor:uint;
    var size:uint;
    
    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size = size;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}
    
class CustomCursor extends Shape {
    var bgColor:uint = 0x333333;
    var size:uint = 10;
    
    public function CustomCursor() {
        visible = false;
        draw();
    }
    
    private function draw():void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}