MouseEvent  - AS3

Gibt an, ob die Alt-Taste aktiviert (true) oder deaktiviert (false) ist. Wird nur für Windows unterstützt. Unter anderen Betriebssystemen ist diese Eigenschaft immer auf false gesetzt.

Gibt an, ob die primäre Maustaste gedrückt (true) ist oder nicht (false).

Gibt an, ob das Mouse-Down-Ereignis Teil einer Sequenz mit mehreren Klicks ist oder nicht. Dieser Parameter hat den Wert null für alle Mausereignisse außer MouseEvent.mouseDown, MouseEvent.mouseUp, MouseEvent.middleMouseDown, MouseEvent.middleMouseUp, MouseEvent.rightMouseDown und MouseEvent.rightMouseUp. Das Warten auf einfache Klicks, Doppelklicks und Sequenzen mit mehreren Klicks ist mit dem clickCount-Parameter möglich. Zum Beispiel haben die ersten Ereignisse MouseEvent.mouseDown und MouseEvent.mouseUp für clickCount den Wert 1 und die zweiten MouseEvent.mouseDown- und MouseEvent.mouseUp-Ereignisse in einer Doppelklicksequenz haben für clickCount den Wert 2. Wenn die Maus ausreichend bewegt wird oder die Mehrfachklicksequenz unterbrochen wird, hat das nächste MouseEvent.mouseDown für clickCount den Wert 1. Das doubleClick-Ereignis wird weiterhin wie erwartet ausgelöst.

Gibt an, ob die Befehlstaste aktiviert ist (nur Mac).

Der Wert der commandKey-Eigenschaft hat denselben Wert wie die ctrlKey-Eigenschaft auf dem Mac. Ist unter Windows und Linux immer „false“.

Gibt an, ob unter Mac OS die Ctrl-Taste oder unter Windows oder Linux die Strg-Taste aktiviert ist.

Gibt unter Windows oder Linux an, ob die Strg-Taste aktiviert (true) oder deaktiviert (false) ist. Unter Mac wird damit angezeigt, ob die Ctrl-Taste oder die Befehlstaste aktiviert ist.

Gibt an, wie viele Zeilen pro Raststellung des Mausrads durchlaufen werden sollen. Ein positiver Deltawert bedeutet einen Bildlauf nach oben. Ein negativer Wert steht für einen Bildlauf nach unten. Typische Werte sind 1 bis 3, wobei ein schnellerer Bildlauf größere Werte zur Folge haben kann. Diese Einstellung hängt von dem Gerät und dem Betriebssystem ab und wird in der Regel vom Benutzer eingestellt. Diese Eigenschaft gilt nur für das Ereignis MouseEvent.mouseWheel.

Wenn true, ist die relatedObject-Eigenschaft aus Gründen, die mit der Sicherheitssandbox zusammenhängen, auf null gesetzt. Ist der Nominalwert von relatedObject ein Verweis auf ein DisplayObject in einer anderen Sandbox, wird relatedObject auf null gesetzt, es sei denn, die Berechtigung gilt über die Sandboxgrenzen hinweg für beide Richtungen. Die Berechtigung wird eingerichtet, indem aus einer SWF-Datei Security.allowDomain() aufgerufen wird oder eine Richtliniendatei vom Server einer Bilddatei bereitgestellt und die LoaderContext.checkPolicyFile-Eigenschaft beim Laden des Bilds gesetzt wird.

Verwandte API-Elemente

Wenn die Maussperre deaktiviert ist, die horizontale Koordinate, bei der das Ereignis aufgetreten ist, in Relation zum Sprite, in dem es enthalten ist. Deaktivieren Sie die Maussperre, in dem Sie Stage.mouseLock auf false einstellen.

Wenn die Maussperre aktiviert ist, sind localX und localY 0. Verwenden Sie movementX und movementY, um die Änderungen an der Mausposition zu bestimmen, wenn die Maussperre aktiviert ist.

Verwandte API-Elemente

Wenn die Maussperre deaktiviert ist, die vertikale Koordinate, bei der das Ereignis aufgetreten ist, in Relation zum Sprite, in dem es enthalten ist. Deaktivieren Sie die Maussperre, in dem Sie Stage.mouseLock auf false einstellen.

Wenn die Maussperre aktiviert ist, sind localX und localY 0. Verwenden Sie movementX und movementY, um die Änderungen an der Mausposition zu bestimmen, wenn die Maussperre aktiviert ist.

Verwandte API-Elemente

Wenn die Maussperre aktiviert ist, die Änderung an der Mausposition in x-Richtung seit dem letzten Mausereignis. Aktivieren Sie die Maussperre, in dem Sie Stage.mouseLock auf true einstellen.

Wenn die Maussperre aktiviert ist:

• localX und localY enthalten 0.
• movementX und movementY enthalten Deltawerte.
• movementX und movementY werden niemals basierend auf der Bühnentransformierung transformiert. Dies bedeutet, dass sie immer Bühnenkoordinaten bleiben.

movementX und movementY sind 0, wenn Stage.mouseLock den Wert false hat.

Verwandte API-Elemente

Wenn die Maussperre aktiviert ist, die Änderung an der Mausposition in y-Richtung seit dem letzten Mausereignis. Aktivieren Sie die Maussperre, in dem Sie Stage.mouseLock auf true einstellen.

Wenn die Maussperre aktiviert ist:

• localX und localY enthalten 0.
• movementX und movementY enthalten Deltawerte.
• movementX und movementY werden niemals basierend auf der Bühnentransformierung transformiert. Dies bedeutet, dass sie immer Bühnenkoordinaten bleiben.

movementX und movementY sind 0, wenn Stage.mouseLock den Wert false hat.

Verwandte API-Elemente

Ein Verweis auf ein Anzeigelistenobjekt, das in Relation zum Ereignis steht. Wenn beispielsweise ein mouseOut-Ereignis auftritt, stellt relatedObject das Anzeigelistenobjekt dar, auf das das Zeigegerät jetzt zeigt. Diese Eigenschaft gilt für die Ereignisse mouseOut, mouseOver, rollOut und rollOver.

Der Wert dieser Eigenschaft kann in zwei Fällen null sein: Wenn es kein verwandtes Objekt gibt oder wenn es eines gibt, dieses aber eine Sicherheitssandbox ist, auf die Sie keinen Zugriff haben. Verwenden Sie die isRelatedObjectInaccessible()-Eigenschaft, um festzustellen, welcher dieser Gründe zutrifft.

Verwandte API-Elemente

Gibt an, ob die Umschalttaste aktiviert (true) oder deaktiviert (false) ist.

Die horizontale Koordinate, an der das Ereignis aufgetreten ist, in globalen Bühnenkoordinaten. Diese Eigenschaft wird berechnet, wenn die Eigenschaft localX eingerichtet wird.

Die vertikale Koordinate, an der das Ereignis aufgetreten ist, in globalen Bühnenkoordinaten. Diese Eigenschaft wird berechnet, wenn die Eigenschaft localY eingerichtet wird.

Erstellt ein Ereignisobjekt, das Informationen über Mausereignisse enthält. Ereignisobjekte werden Ereignis-Listenern als Parameter übergeben.

Erstellt eine Kopie des MouseEvent-Objekts und stellt den Wert jeder Eigenschaft so ein, dass er dem Wert des Originals entspricht.

Gibt eine Zeichenfolge zurück, die alle Eigenschaften des MouseEvent-Objekts enthält. Der String liegt im folgenden Format vor:

[MouseEvent type= value bubbles= value cancelable= value ... delta= value ]

Weist Flash Player oder Adobe AIR nach Abschluss der Verarbeitung dieses Ereignisses zur Wiedergabe an, wenn die Anzeigeliste geändert wurde.

Definiert den Wert der Eigenschaft type eines click-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Die MouseEvent.CONTEXT_MENU-Konstante definiert den Wert der type-Eigenschaft eines contextMenu-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Definiert den Wert der Eigenschaft type eines doubleClick-Ereignisobjekts. Die doubleClickEnabled-Eigenschaft muss true sein, damit ein Objekt das doubleClick-Ereignis auslösen kann.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines middleClick-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines middleMouseDown-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines middleMouseUp-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines mouseDown-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines mouseMove-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

package {
    import flash.display.Sprite;
    import flash.display.Graphics;
    import flash.events.MouseEvent;

    public class MouseEvent_MOUSE_MOVEExample extends Sprite {
        private var innerRect:Sprite = new Sprite();
        
        public function MouseEvent_MOUSE_MOVEExample() {

            graphics.lineStyle(3, 0xFF0000, 1);
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            stage.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);

            innerRect.graphics.lineStyle(1, 0x00FF00, 1);
            innerRect.graphics.beginFill(0xFFFFFF);
            innerRect.graphics.drawRect(10, 10, 200, 200);
            innerRect.graphics.endFill();
            innerRect.addEventListener(MouseEvent.MOUSE_DOWN, innerRectMouseDownHandler);
            innerRect.addEventListener(MouseEvent.MOUSE_UP, innerRectMouseUpHandler);
            addChild(innerRect);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            graphics.moveTo(event.stageX, event.stageY);
            stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }
    
        private function mouseMoveHandler(event:MouseEvent):void {
            graphics.lineTo(event.stageX, event.stageY);
        }    
    
        private function mouseUpHandler(event:MouseEvent):void {
            stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        }

        private function innerRectMouseDownHandler(event:MouseEvent):void {
            innerRect.graphics.moveTo(event.localX, event.localY);
            innerRect.addEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    
        private function innerRectMouseMoveHandler(event:MouseEvent):void {
            innerRect.graphics.lineTo(event.localX, event.localY);
        }    
    
        private function innerRectMouseUpHandler(event:MouseEvent):void {
            innerRect.removeEventListener(MouseEvent.MOUSE_MOVE, innerRectMouseMoveHandler);
        }
    }
}

Definiert den Wert der Eigenschaft type eines mouseOut-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines mouseOver-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines mouseUp-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines mouseWheel-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines releaseOutside-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines rightClick-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines rightMouseDown-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der type-Eigenschaft eines rightMouseUp-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines rollOut-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

Definiert den Wert der Eigenschaft type eines rollOver-Ereignisobjekts.

Dieses Ereignis verfügt über die folgenden Eigenschaften:

Verwandte API-Elemente

1. Im Beispiel werden Eigenschaften für die Größe (100 x 100 Pixel) und die Hintergrundfarbe (Orange) zur späteren Verwendung beim Zeichnen des Quadrats deklariert.
2. Der Konstruktor erstellt das neue ChildSprite-Objekt child. Der Konstruktor zeichnet zuerst ein orangefarbenes Quadrat mit einer Größe von 100 x 100 Pixeln an den Koordinaten (0,0), indem er die Methode draw() aufruft und anschließend sieben Ereignis-Listener bzw. -Abonnenten hinzufügt.
   • click/clickHandler(): Wird ausgelöst, wenn der Benutzer einmal mit der linken Maustaste auf das Quadrat klickt.
   • doubleClick/doubleClickHandler(): Wird ausgelöst, wenn der Benutzer mit der linken Maustaste auf das Quadrat doppelklickt.
   • mouseDown/mouseDownHandler(): Wenn auf das ChildSprite-Objekt (das orangefarbene Quadrat) geklickt wird, wird eine trace()-Meldung angezeigt. ChildSprite.draw() wird aufgerufen, wodurch ein dunkelgelbes Quadrat anstelle des hellblauen aus mouseOverHandler() gezeichnet wird. Mit der Methode mouseDownHandler() werden auch ein mouseMove-Ereignis-Listener und ein mouseMoveHandler()-Abonnent (siehe Beschreibung unten) für die Verarbeitung der Mausbewegungen hinzugefügt. Als Nächstes wird die startDrag()-Methode aufgerufen, die das Ziehen des Sprite-Objekts ermöglicht.
   • mouseOut/mouseOutHandler(): Wird ausgelöst, wenn der Mauszeiger vom Quadrat wegbewegt wird. Die draw()-Methode wird aufgerufen, um die normale Größe und Farbe des Quadrats wiederherzustellen.
   • mouseOver/mouseOverHandler(): Wird ausgelöst, wenn sich der Mauszeiger über dem Quadrat befindet. Mit dieser Methode wird das Quadrat größer und mit dunkelgelber Hintergrundfarbe neu gezeichnet.
   • mouseUp/mouseUpHandler(): Wenn die Maustaste losgelassen wird, wird der mouseMove-Ereignis-Listener entfernt, und stopDrag wird aufgerufen. Hiermit wird das Quadrat an seiner Position fixiert.
   • mouseMove/mouseMoveHandler(): Wird als Teil der mouseDownHandler()-Funktion aufgerufen und ausgelöst, wenn der Benutzer die linke Maustaste gedrückt hält und das Quadrat zieht.
   • mouseWheel/mouseWheelHandler(): Wird ausgelöst, wenn der Benutzer das Mausrad dreht, während sich der Mauszeiger auf dem Quadrat befindet.
3. Die ChildSprite-Instanz child wird der Anzeigeliste mithilfe der Methode addChild(), die ein sofortiges Zeichnen des orangefarbenen Quadrats bewirkt, hinzugefügt.

Hinweise:

• Die MouseEventExample-Klasse muss der Dokumentenstamm sein.
• Bei einigen der oben aufgeführten Ereignis-Listener-Methoden wird eine lokale sprite-Variable deklariert, der die Umwandlung von event.target in den Typ „Sprite“ zugewiesen wird.

package {
    import flash.display.Sprite;

    public class MouseEventExample extends Sprite {
        private var size:uint = 100;
        private var bgColor:uint = 0xFFCC00;

        public function MouseEventExample() {
            var child:ChildSprite = new ChildSprite();
            addChild(child);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class ChildSprite extends Sprite {
    private var size:uint = 50;
    private var overSize:uint = 60;
    private var backgroundColor:uint = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;

    public function ChildSprite() {
        draw(size, size, backgroundColor);
            doubleClickEnabled = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        addEventListener(MouseEvent.DOUBLE_CLICK, doubleClickHandler);
        addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
        addEventListener(MouseEvent.MOUSE_OUT, mouseOutHandler);
        addEventListener(MouseEvent.MOUSE_OVER, mouseOverHandler);
        addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
        addEventListener(MouseEvent.MOUSE_WHEEL, mouseWheelHandler);
    }

    private function draw(w:uint, h:uint, bgColor:uint):void {
        graphics.clear();
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        trace("clickHandler");
    }

    private function doubleClickHandler(event:MouseEvent):void {
        trace("doubleClickHandler");
    }

    private function mouseDownHandler(event:MouseEvent):void {
        trace("mouseDownHandler");
        draw(overSize, overSize, downColor);

        var sprite:Sprite = Sprite(event.target);
        sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.startDrag();
    }

    private function mouseMoveHandler(event:MouseEvent):void {
        trace("mouseMoveHandler");
        event.updateAfterEvent();
    }

    private function mouseOutHandler(event:MouseEvent):void {
        trace("mouseOutHandler");
        draw(size, size, backgroundColor);
    }

    private function mouseOverHandler(event:MouseEvent):void {
        trace("mouseOverHandler");
        draw(overSize, overSize, overColor);
    }

    private function mouseWheelHandler(event:MouseEvent):void {
        trace("mouseWheelHandler delta: " + event.delta);
    }

    private function mouseUpHandler(event:MouseEvent):void {
        trace("mouseUpHandler");
        var sprite:Sprite = Sprite(event.target);
        sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
        sprite.stopDrag();
        draw(overSize, overSize, overColor);
    }
}