Screen - Adobe ActionScript® 3 (AS3 ) API-Referenz

Paket	flash.display
Klasse	public final class Screen
Vererbung	Screen EventDispatcher Object

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0

Die Screen-Klasse stellt Informationen über die Anzeigebildschirme bereit, die für diese Anwendung verfügbar sind.

Bei Bildschirmen handelt es sich um unabhängige Desktop-Bereiche innerhalb eines möglicherweise größeren virtuellen Desktops. Der Ursprung des virtuellen Desktops ist die obere linke Ecke des vom Betriebssystem festgelegten Hauptbildschirms. Deshalb können die Koordinaten für die Begrenzungen eines einzelnen Anzeigebildschirms negativ sein. Der virtuelle Desktop kann auch Bereiche enthalten, die sich nicht in einem der Anzeigebildschirme befinden.

Die Screen-Klasse enthält statische Klassenmitglieder für den Zugriff auf die verfügbaren Bildschirmobjekte sowie Instanzmitglieder für den Zugriff auf die Eigenschaften eines einzelnen Bildschirms. Bildschirminformationen sollten nicht zwischengespeichert werden, da sie jederzeit von einem Benutzer geändert werden können.

Beachten Sie, dass die Bildschirme und die an den Computer angeschlossenen Monitore sich nicht unbedingt 1:1 entsprechen. Beispielsweise kann ein Bildschirm auf zwei Monitoren angezeigt werden.

Die Screen-Klasse kann nicht direkt instanziiert werden. Aufrufe des new Screen()-Konstruktors geben eine ArgumentError-Ausnahme aus.

Beispiele anzeigen

Öffentliche Eigenschaften

Vererbte öffentliche Eigenschaften ausblenden

Vererbte öffentliche Eigenschaften anzeigen

	Eigenschaft		Definiert von
		bounds : Rectangle [schreibgeschützt] Die Begrenzungen dieses Bildschirms.	Screen
		colorDepth : int [schreibgeschützt] Die Farbtiefe dieses Bildschirms in Bit.	Screen
		constructor : Object Ein Verweis auf das Klassenobjekt oder die Konstruktorfunktion für eine angegebene Objektinstanz.	Object
		mainScreen : Screen [statisch] [schreibgeschützt] Die primäre Anzeige.	Screen
		mode : ScreenMode Der aktuelle Bildschirmmodus des Bildschirmobjekts.	Screen
		modes : Array [schreibgeschützt] Das Array der Bildschirmmodus-Objekte im Bildschirmobjekt.	Screen
		screens : Array [statisch] [schreibgeschützt] Das Array der derzeit verfügbaren Bildschirme.	Screen
		visibleBounds : Rectangle [schreibgeschützt] Die Begrenzungen des Bereichs auf diesem Bildschirm, in dem Fenster sichtbar sind.	Screen

Öffentliche Methoden

Vererbte öffentliche Methoden ausblenden

Vererbte öffentliche Methoden anzeigen

	Methode		Definiert von
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registriert ein Ereignis-Listener-Objekt bei einem EventDispatcher-Objekt, sodass der Listener über ein Ereignis benachrichtigt wird.	EventDispatcher
		dispatchEvent(event:Event):Boolean Sendet ein Ereignis in den Ereignisablauf.	EventDispatcher
		getScreensForRectangle(rect:Rectangle):Array [statisch] Gibt den (möglicherweise leeren) Satz der Bildschirme zurück, die das angegebene Rechteck schneiden.	Screen
		hasEventListener(type:String):Boolean Überprüft, ob das EventDispatcher-Objekt Listener für einen bestimmten Ereignistyp registriert hat.	EventDispatcher
		hasOwnProperty(name:String):Boolean Gibt an, ob für ein Objekt eine bestimmte Eigenschaft definiert wurde.	Object
		isPrototypeOf(theClass:Object):Boolean Gibt an, ob eine Instanz der Object-Klasse in der Prototypkette des Objekts vorhanden ist, das als Parameter angegeben wurde.	Object
		propertyIsEnumerable(name:String):Boolean Gibt an, ob die angegebene Eigenschaft vorhanden ist und durchlaufen werden kann.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Entfernt einen Listener aus dem EventDispatcher-Objekt.	EventDispatcher
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Legt die Verfügbarkeit einer dynamischen Eigenschaft für Schleifenoperationen fest.	Object
		toLocaleString():String Gibt die Stringdarstellung dieses Objekts zurück, formatiert entsprechend den Konventionen des Gebietsschemas.	Object
		toString():String Gibt das angegebene Objekt als String zurück.	Object
		valueOf():Object Gibt den Grundwert des angegebenen Objekts zurück.	Object
		willTrigger(type:String):Boolean Überprüft, ob bei diesem EventDispatcher-Objekt oder bei einem seiner Vorgänger ein Ereignis-Listener für einen bestimmten Ereignistyp registriert ist.	EventDispatcher

Ereignisse

Klicken Sie, um weitere Informationen zu Ereignissen zu erhalten.

Vererbte Ereignisse ausblenden

Vererbte Ereignisse anzeigen

	Ereignis		Übersicht	Definiert von
		activate	[broadcast event] Wird ausgelöst, wenn Flash Player oder eine AIR-Anwendung den Betriebssystemfokus erhält und aktiv wird.	EventDispatcher
		deactivate	[broadcast event] Wird ausgelöst, wenn Flash Player- oder die AIR-Anwendung den Fokus verliert und inaktiv wird.	EventDispatcher

Eigenschaftendetails

bounds

Eigenschaft

bounds:Rectangle [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0

Die Begrenzungen dieses Bildschirms.

Die Bildschirmposition ist relativ zum virtuellen Desktop.

Unter Linux-Systemen, die bestimmte Fenstermanager verwenden, gibt diese Eigenschaft die Grenzen des Desktops, nicht die sichtbaren Grenzen des Bildschirms zurück.

Implementierung
public function get bounds():Rectangle

Beispiel ( Verwendung dieses Beispiels )

Das folgende Beispiel zeigt, wie die Begrenzungen eines Bildschirms abgerufen werden (in diesem Fall der primäre Anzeigebildschirm):

import flash.display.Screen;
import flash.geom.Rectangle;

var mainScreen:Screen = Screen.mainScreen;
var screenBounds:Rectangle = mainScreen.bounds;

colorDepth

Eigenschaft

colorDepth:int [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0

Die Farbtiefe dieses Bildschirms in Bit.

Implementierung
public function get colorDepth():int

Beispiel ( Verwendung dieses Beispiels )

Das folgende Beispiel zeigt, wie die Farbtiefe eines Bildschirms abgerufen wird (in diesem Fall der primäre Anzeigebildschirm):


var mainScreen:Screen = Screen.mainScreen;
var colors:uint = mainScreen.colorDepth;

mainScreen

Eigenschaft

mainScreen:Screen [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0

Die primäre Anzeige.

Implementierung
public static function get mainScreen():Screen

Beispiel ( Verwendung dieses Beispiels )

Das folgende Beispiel zeigt, wie das Screen-Objekt abgerufen wird, das den Hauptbildschirm dieses Computers repräsentiert:


var primaryScreen:Screen = Screen.mainScreen;

mode

Eigenschaft

mode:ScreenMode

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 29.0

Der aktuelle Bildschirmmodus des Bildschirmobjekts. Die Eigenschaft Modus gibt den aktuellen Bildschirmmodus eines bestimmten Bildschirmgeräts an.

Implementierung
public function get mode():ScreenMode
public function set mode(value:ScreenMode):void

modes

Eigenschaft

modes:Array [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 29.0

Das Array der Bildschirmmodus-Objekte im Bildschirmobjekt. Die Eigenschaft Modi gibt unterstützte Bildschirmmodi des bestimmten Bildschirmgeräts an.

Implementierung
public function get modes():Array

screens

Eigenschaft

screens:Array [schreibgeschützt]

Sprachversion:

ActionScript 3.

Laufzeitversionen:

AIR 1.0

Das Array der derzeit verfügbaren Bildschirme.

Eine Änderung des zurückgegebenen Arrays hat keinerlei Auswirkungen auf die verfügbaren Bildschirme.

Implementierung
public static function get screens():Array

Beispiel ( Verwendung dieses Beispiels )

Das folgende Beispiel zeigt, wie das Array mit den verfügbaren Bildschirmen abgerufen wird:


var screenArray:Array = Screen.screens;

visibleBounds

Eigenschaft

visibleBounds:Rectangle [schreibgeschützt]

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0

Die Begrenzungen des Bereichs auf diesem Bildschirm, in dem Fenster sichtbar sind.

Die visibleBounds eines Bildschirms schließen unter Windows die Taskleiste (und andere angedockte Desktopleisten) aus, ebenso wie die Menüleiste und, abhängig von den Systemeinstellungen, das Dock unter Mac OS X. Bei manchen Linuxkonfigurationen ist es nicht möglich, die Sichtbarkeitsgrenzen zu bestimmen. In diesem Fall gibt die visibleBounds-Eigenschaft denselben Wert zurück wie die screenBounds-Eigenschaft.

Implementierung
public function get visibleBounds():Rectangle

Beispiel ( Verwendung dieses Beispiels )

Das folgende Beispiel zeigt, wie die nutzbaren Begrenzungen eines Bildschirms abgerufen werden (in diesem Fall der primäre Anzeigebildschirm):

import flash.display.Screen;
import flash.geom.Rectangle;

var mainScreen:Screen = Screen.mainScreen;
var screenBounds:Rectangle = mainScreen.visibleBounds;

Methodendetails

getScreensForRectangle

()

Methode

public static function getScreensForRectangle(rect:Rectangle):Array

Sprachversion:

ActionScript 3.0

Laufzeitversionen:

AIR 1.0

Gibt den (möglicherweise leeren) Satz der Bildschirme zurück, die das angegebene Rechteck schneiden.

Parameter

rect:Rectangle — Ein Rechteck mit Koordinaten relativ zum Ursprung des virtuellen Desktops. Bei diesem Ursprung handelt es sich um die linke obere Ecke des primären Bildschirms.

Rückgabewerte

Array — Ein Array mit Screen-Objekten, die die Bildschirme enthalten, die einen beliebigen Teil des vom rect-Parameter definierten Bereichs enthalten.

Beispiel ( Verwendung dieses Beispiels )

Das folgende Beispiel zeigt, wie das Array der Bildschirme abgerufen wird, die mindestens einen Teil eines gegebenen Rechtecks enthalten:

import flash.display.Screen;
import flash.geom.Rectangle;

var rect:Rectangle = new Rectangle(-200, 100, 1000, 600);
var intersectedScreens:Array = Screen.getScreensForRectangle(rect);

Beispiele Verwendung dieses Beispiels

ScreenExample.as

Im folgenden Beispiel wird die DockingWindow-Klasse verwendet, um ein Fenster zu erstellen, das an den Bildschirmseiten angedockt wird. Dies wird in den folgenden Schritten erreicht:

Reaktion auf Tastaturereignisse, um zu bestimmen, an welcher Seite des Bildschirms das Fenster angedockt werden soll.
Zugriff auf die statische getScreensForRectangle()-Methode der Screen-Klasse, um das Screen-Objekt für den Bildschirm abzurufen, auf dem das Fenster derzeit angezeigt wird.
Zurücksetzen der Fenstergrenzen auf Grundlage der Bildschirmabmessungen.
Neuzeichnen des Fensterinhalts auf Grundlage der neuen Fensterabmessungen.

Hinweis: Diese Klasse ist als Stammklasse einer AIR-Anwendung mit den Einstellungen SystemChrome="none" und transparent="true" vorgesehen. Um diese Klasse bei einem Fenster mit Systemchrom zu verwenden, müssen Sie die Chromestärke und Mindestbreite des Fensters bei der Berechnung der Fensterposition und -größe berücksichtigen.


package
{
    import flash.display.Screen;
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.KeyboardEvent;
    import flash.geom.Rectangle;
    import flash.ui.Keyboard;

    public class DockingWindow extends Sprite
    {
        private const dockedWidth:uint = 80;
        private const dockedHeight:uint = 80;
        
        public function DockingWindow():void{
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.addEventListener(KeyboardEvent.KEY_DOWN,onKey);
            dockLeft();
        }
        
        private function onKey(event:KeyboardEvent):void{
            switch(event.keyCode){
                case Keyboard.LEFT :
                    dockLeft();
                    break;
                case Keyboard.RIGHT :
                    dockRight();
                    break;
                case Keyboard.UP :
                    dockTop();
                    break;
                case Keyboard.DOWN :
                    dockBottom();
                    break;
                case Keyboard.SPACE :
                    stage.nativeWindow.close();
            }    
        }
        
        public function dockLeft():void{
            var screen:Screen = getCurrentScreen();
            stage.nativeWindow.x = screen.visibleBounds.left;
            stage.nativeWindow.y = screen.visibleBounds.top;
            stage.nativeWindow.height = screen.visibleBounds.height;
            stage.stageWidth = dockedWidth;
            drawContent();
        }
        
        public function dockRight():void{
            var screen:Screen = getCurrentScreen();
            stage.nativeWindow.x = screen.visibleBounds.width - dockedWidth;            
            stage.nativeWindow.y = screen.visibleBounds.top;
            stage.stageWidth = dockedWidth;
            stage.nativeWindow.height = screen.visibleBounds.height;
            drawContent();
        }
        
        public function dockTop():void{
            var screen:Screen = getCurrentScreen();
            stage.nativeWindow.x = screen.visibleBounds.left;
            stage.nativeWindow.y = screen.visibleBounds.top;
            stage.nativeWindow.width = screen.visibleBounds.width;
            stage.stageHeight = dockedHeight;
            drawContent();
        }
        
        public function dockBottom():void{
            var screen:Screen = getCurrentScreen();
            stage.nativeWindow.x = screen.visibleBounds.left;
            stage.nativeWindow.y = screen.visibleBounds.height - dockedHeight;
            stage.nativeWindow.width = screen.visibleBounds.width;
            stage.stageHeight = dockedHeight;    
            drawContent();        
        }
        
        private function getCurrentScreen():Screen{
            return Screen.getScreensForRectangle(stage.nativeWindow.bounds)[0];
        }
        
        private function drawContent():void{
            const size:int = 60;
            const pad:int = 10;
            var numHSquares:int = Math.floor(stage.stageWidth/(size + pad));
            var numVSquares:int = Math.floor(stage.stageHeight/(size + pad));
            with (graphics){
                clear();
                lineStyle(1);
                beginFill(0x3462d5,.7);
                for(var i:int = 0; i < numHSquares; i++){
                    for(var j:int = 0; j < numVSquares; j++){                
                            drawRect((i * (size + pad)) + pad, (j * (size + pad)) + pad, size, size);
                    }
                }
                endFill();
            }
        }
    }
}

Rechtliche Hinweise | Onlinedatenschutzerklärung

Screen - AS3

Klassen x

bounds

colorDepth

mainScreen

mode

modes

screens

visibleBounds

getScreensForRectangle