WorkerDomain  - AS3

当前正在其中运行代码的 WorkerDomain 实例。这是应用程序中的唯一 WorkerDomain。

指示当前运行时上下文是否支持将 WorkerDomain 和 Worker 对象用于并行代码执行。

如果并行可用，则此属性的值为 true。

基于某个 swf 的字节创建一个新的 Worker 实例。

每个 worker 都是基于独立的 swf 应用程序创建的并且作为独立的 swf 应用程序执行。要创建 Worker 实例，您需要获取 SWF 文件的字节以作为 ByteArray 实例，并将该实例传递给此方法。针对此目的，有三种常用方式可用来访问 swf 的字节：

• 使用 [Embed] 元标记将 .swf 文件作为 ByteArray 嵌入在应用程序中：

      // Embed the SWF file
      [Embed(source="../swfs/BgWorker.swf", mimeType="application/octet-stream")]
      private static var BgWorker_ByteClass:Class;
      
      private function createWorker():void
      {
        // create the background worker
        var workerBytes:ByteArray = new BgWorker_ByteClass();
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• 使用 URLLoader 加载外部 SWF 文件：

      // load the SWF file
      var workerLoader:URLLoader = new URLLoader();
      workerLoader.dataFormat = URLLoaderDataFormat.BINARY;
      workerLoader.addEventListener(Event.COMPLETE, loadComplete);
      workerLoader.load(new URLRequest("BgWorker.swf"));
      
      private function loadComplete(event:Event):void
      {
        // create the background worker
        var workerBytes:ByteArray = event.target.data as ByteArray;
        var bgWorker:Worker = WorkerDomain.current.createWorker(workerBytes);
        
        // listen for worker state changes to know when the worker is running
        bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
        
        // set up communication between workers using 
        // setSharedProperty(), createMessageChannel(), etc.
        // ... (not shown)
        
        bgWorker.start();
      }

• 将单个 swf 同时用作原始 worker 和后台 worker：

      // The primordial worker's main class constructor
      public function PrimordialWorkerClass()
      {
        init();
      }
      
      private function init():void
      {
        var swfBytes:ByteArray = this.loaderInfo.bytes;
        
        // Check to see if this is the primordial worker
        if (Worker.current.isPrimordial)    
        {
          // create a background worker
          var bgWorker:Worker = WorkerDomain.current.createWorker(swfBytes);
          
          // listen for worker state changes to know when the worker is running
          bgWorker.addEventListener(Event.WORKER_STATE, workerStateHandler);
          
          // set up communication between workers using 
          // setSharedProperty(), createMessageChannel(), etc.
          // ... (not shown)
          
          bgWorker.start();
        }
        else // entry point for the background worker
        {
          // set up communication between workers using getSharedProperty()
          // ... (not shown)
          
          // start the background work
        }

使用 createWorker() 创建一个 Worker 对象不会开始执行该 worker。要开始 worker 的代码执行，请调用 Worker 对象的 start() 方法。

Worker 非常有用，因为它们可以减少由于主渲染线程受其他代码阻止而使帧速率下降的可能。但是，worker 需要使用额外系统内存和 CPU，这可能使整体应用程序性能代价昂贵。由于每个 worker 均使用其自身的运行时虚拟机实例，因此即使不重要的 worker 开销也可能很大。当使用 worker 时，请在所有目标平台测试代码，以确保对系统的需求不是太大。Adobe 建议在典型情境下请勿使用超过一个或两个后台 worker。

参数

提供对 WorkerDomain 中当前正在运行的 worker（Worker 实例的 state 属性为 WorkerState.RUNNING）集的访问。