FlowElementMouseEvent  - AS3

package flashx.textLayout.events.examples {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flashx.textLayout.container.ContainerController;
    import flashx.textLayout.elements.TextFlow;
    import flashx.textLayout.elements.ParagraphElement;
    import flashx.textLayout.elements.SpanElement;
    import flashx.textLayout.elements.LinkElement;
    import flashx.textLayout.events.FlowElementMouseEvent;
    import flashx.textLayout.formats.TextLayoutFormat;


    public class FlowElementMouseEvent_example extends Sprite
    {
        private var tf:TextFlow;
        
        public function FlowElementMouseEvent_example()
        {
            // define TextFlow
            tf = new TextFlow();
            
            // define link element
            var linkPar:ParagraphElement = new ParagraphElement();
            var linkEl:LinkElement = new LinkElement();
            linkEl.href = "http://www.adobe.com/go/flashplayer";
            linkEl.target = "_blank"; // when link is clicked, open a new browser window
            var span1:SpanElement = new SpanElement(); // for text associated with link
            span1.text = "Get Flash Player";
            linkEl.addChild(span1);
            
            // define paragraph element for name of events dispatched
            var textPar:ParagraphElement = new ParagraphElement();
            var span2:SpanElement = new SpanElement();
            span2.text ="Three most recent events:";
            
            // add span (text) and link elements to the TextFlow
            linkPar.addChild(linkEl);    // add LinkElement to first paragraph
            textPar.addChild(span2);     // add header text to second paragraph
            tf.addChild(linkPar);        // add paragraph with link to text flow 
            tf.addChild(textPar);        // add paragraph for events to text flow

            
            // add event listeners for all six FlowElementMouseEvent types
            linkEl.addEventListener(FlowElementMouseEvent.CLICK, linkHandler);
            linkEl.addEventListener(FlowElementMouseEvent.MOUSE_DOWN, linkHandler);
            linkEl.addEventListener(FlowElementMouseEvent.MOUSE_MOVE, linkHandler);
            linkEl.addEventListener(FlowElementMouseEvent.MOUSE_UP, linkHandler);
            linkEl.addEventListener(FlowElementMouseEvent.ROLL_OVER, linkHandler);
            linkEl.addEventListener(FlowElementMouseEvent.ROLL_OUT, linkHandler);
            
            // create text container for link and event listing text
            var linkContainer:Sprite = new Sprite();
            linkContainer.x = 10;
            linkContainer.y = 10;
            var linkController:ContainerController = new ContainerController(linkContainer,200,80);
            var linkControllerFormat:TextLayoutFormat = new TextLayoutFormat();
            linkControllerFormat.paddingTop = 3;
            linkController.format = linkControllerFormat;
            tf.flowComposer.addController(linkController);
            
            // Add linkContainer to Display List
            addChild(linkContainer);
            
            tf.flowComposer.updateAllControllers();   
        }
        
        // event handler function        
        private function linkHandler(ev:FlowElementMouseEvent):void {
            var par:ParagraphElement = new ParagraphElement();
            var span:SpanElement = new SpanElement();
            span.text = ev.type;
            par.addChild(span);
            tf.replaceChildren(2,2,par);
            if (tf.numChildren > 5) {
                tf.removeChildAt(5);
            }
            tf.flowComposer.updateAllControllers();  
        }

    }        
}